小強學渲染之Unity Shader邊緣描邊增強

　　項目開發遇到一個需求，就是當坦克的準心瞄準敵方（enemy tank 或 item box）時，要讓選中的對象的輪廓高亮起來，這其實是接下來要講解的實時渲染中輪廓線的渲染應用。實現方式有多種，下面逐一總結各自的原理和優缺點。

　　· 法線外拓的幾何輪廓線渲染

　　核心是使用兩個Pass渲染模型，在第一個Pass中，使用輪廓線顏色渲染整個背面的面片，並在視角空間下把模型頂點沿着法線方向向外擴張一段距離，目的讓背部輪廓線可見。

    viewPos = viewPos + viewNormal * _Outline;

　　第二個Pass再正常渲染正面的面片。

　　但有些狀況直接使用頂點法線進行擴展會帶來bug，如一些內凹的模型，這樣處理可能會發生背面面片遮擋正面面片的狀況。解決的辦法是，在擴張背面頂點以前，首先對頂點法線的z份量進行處理，使其等於一個定值，而後把法線歸一化後再對頂點進行擴張。 目的是使擴展後的背面更扁平化，下降遮擋正面面片的可能性。

　　viewNormal.z = -0.5;
　　viewNormal = normalize(viewNormal);
　　viewPos = viewPos + viewNormal * _Outline;

　　補充高光效果 - 「卡通高光」（即亮暗單一明顯）。此前使用的Blinn-Phong模型中，使用法線點乘光照方向以及視角方向和的一半，再和另外一參數進行指數操做獲得高光反射係數，

    float spec = pow(max(0, dot(normal, halfDir)), _Gloss);

　　爲實現卡通高光渲染，須要對點乘的結果和一閾值比較，小於該閾值高光反射係數爲0，反之爲1，

    float spec = dot(worldNormal, worldHalfDir);
    //step函數：第一個參數爲參考值，第二個參數爲待比較數值。第二個參數大於等於第一個參數則返回1，不然返回0
    spec = step(threshold, spec);

　　使用CG的step函數來比較大小算是GPU代碼的一個優化，由於用step()能代替大量的if else等條件語句。

　　引用馮樂樂的shader筆記內容，經過平滑函數可解決係數突變帶來的邊界鋸齒的問題。  到此上述的輪廓理論講解完畢，詳細開發流程以下：

　　a）在場景中建立模型對象，tag爲別爲e1，e2，

　　

　　b）完整的着色器代碼以下：

// Upgrade NOTE: replaced '_Object2World' with 'unity_ObjectToWorld'
// Upgrade NOTE: replaced 'mul(UNITY_MATRIX_MVP,*)' with 'UnityObjectToClipPos(*)'

Shader "Shaders/ToonBound"
{
    Properties
    {
        _Color ("Color Tint", Color) = (1, 1, 1, 1)
        _MainTex ("Main Tex", 2D) = "white" {}
        _Ramp ("Ramp Texture", 2D) = "white" {}                  //控制漫反射色調的漸變紋理
        _Outline ("Outline", Range(0, 1)) = 0.1                  //控制輪廓線寬度
        _OutlineColor ("Outline Color", Color) = (1, 0, 0, 1) //輪廓線顏色
        _Specular ("Specular", Color) = (1, 1, 1, 1)          //高光反色顏色
        _SpecularScale ("Specular Scale", Range(0, 0.1)) = 0.01 //高光反射係數閾值
    }
    SubShader
    {
        Tags { "RenderType"="Opaque" "Queue"="Geometry"}
        LOD 100

        Pass
        {
            //命名Pass塊，以便複用
            NAME "OUTLINE"
            //剔除正面
            Cull Front

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            // make fog work
            //#pragma multi_compile_fog
            
            #include "UnityCG.cginc"

            float _Outline;
            fixed4 _OutlineColor;

            struct a2v {
                float4 vertex : POSITION;
                float3 normal : NORMAL;
            }; 
            
            struct v2f {
                float4 pos : SV_POSITION;
            };

            v2f vert (a2v v) {
                v2f o;
                //讓描邊在觀察空間達到最好的效果
                float4 pos = mul(UNITY_MATRIX_MV, v.vertex); 
                float3 normal = mul((float3x3)UNITY_MATRIX_IT_MV, v.normal);  
                normal.z = -0.5;
                pos = pos + float4(normalize(normal), 0) * _Outline;
                //將頂點從視角空間變換到裁剪空間
                o.pos = mul(UNITY_MATRIX_P, pos);
                
                return o;
            }
            
            float4 frag(v2f i) : SV_Target { 
                //輪廓線顏色渲染整個背面
                return float4(_OutlineColor.rgb, 1);               
            }

            ENDCG
        }
        Pass 
        {
            Tags { "LightMode"="ForwardBase" }
            //渲染正面
            Cull Back
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #pragma multi_compile_fwdbase
        
            #include "UnityCG.cginc"
            #include "Lighting.cginc"
            #include "AutoLight.cginc"
            #include "UnityShaderVariables.cginc"

            fixed4 _Color;
            sampler2D _MainTex;
            float4 _MainTex_ST;
            sampler2D _Ramp;
            fixed4 _Specular;
            fixed _SpecularScale;
        
            struct a2v {
                float4 vertex : POSITION;
                float3 normal : NORMAL;
                float4 texcoord : TEXCOORD0;
                float4 tangent : TANGENT;
            }; 
        
            struct v2f {
                float4 pos : POSITION;
                float2 uv : TEXCOORD0;
                float3 worldNormal : TEXCOORD1;
                float3 worldPos : TEXCOORD2;
                SHADOW_COORDS(3)
            };

            v2f vert (a2v v) {
                v2f o;
                
                o.pos = UnityObjectToClipPos( v.vertex);
                o.uv = TRANSFORM_TEX (v.texcoord, _MainTex);
                o.worldNormal  = UnityObjectToWorldNormal(v.normal);
                o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
                
                TRANSFER_SHADOW(o);
                
                return o;
            }
            
            float4 frag(v2f i) : SV_Target { 
                fixed3 worldNormal = normalize(i.worldNormal);
                fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));
                fixed3 worldViewDir = normalize(UnityWorldSpaceViewDir(i.worldPos));
                fixed3 worldHalfDir = normalize(worldLightDir + worldViewDir);
                
                fixed4 c = tex2D (_MainTex, i.uv);
                fixed3 albedo = c.rgb * _Color.rgb; //計算材質反射率
                
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo; //計算環境光
                
                UNITY_LIGHT_ATTENUATION(atten, i, i.worldPos); //計算當前世界座標下的陰影值
                
                fixed diff =  dot(worldNormal, worldLightDir);
                //計算半蘭伯特漫反射係數
                diff = (diff * 0.5 + 0.5) * atten;
                //對漸變紋理_Ramp進行採樣
                fixed3 diffuse = _LightColor0.rgb * albedo * tex2D(_Ramp, float2(diff, diff)).rgb;
                
                fixed spec = dot(worldNormal, worldHalfDir);
                fixed w = fwidth(spec) * 2.0; //抗鋸齒處理
                fixed3 specular = _Specular.rgb * lerp(0, 1, smoothstep(-w, w, spec + _SpecularScale - 1)) * step(0.0001, _SpecularScale);
                
                return fixed4(ambient + diffuse + specular, 1.0);
            }
            ENDCG
        }
    }
    FallBack "Diffuse"
}

　　運行遊戲的效果以下：