Unity Shader之使用Cubemap實現反射效果

時間 2019-11-09

標籤 unity shader 使用 cubemap 實現反射效果简体版

原文原文鏈接

一、Cubemap是啥

Cubemap，即立方體紋理，包含6張圖像，每張圖像對應立方體的一個面，跟二維紋理不一樣，咱們使用三維座標去對這種紋理進行採樣，在unity中，可使用Cubemap來實現天空盒子以及環境映射，環境映射能夠模擬出場景中周圍的環境，使用了環境映射材質的物體能夠反射出周圍的環境，就像反光鏡或者反光金屬同樣。

二、製做Cubemap

一般，製做Cubemap的方法大概有三種，第一種是提供一種具備特殊佈局的紋理，相似全景圖，而後將該紋理的Texture Shape設置爲Cube；第二種方法是在Project面板建立一個Cubemap，而後提供6張紋理分別拖拽到它的屬性面板中；前兩種方法都須要咱們提供立方體紋理的圖片，咱們這裏使用第三種方案，用腳原本建立，把下面腳本放在editor文件夾中：

using UnityEngine;
using UnityEditor;
using System.Collections;

public class RenderCubeMap : ScriptableWizard
{
    public Transform renderPosition;
    public Cubemap cubemap;

    void OnWizardUpdate()
    {
        isValid = (renderPosition != null) && (cubemap != null);
    }

    void OnWizardCreate()
    {
        // 建立一個用來渲染的相機
        GameObject go = new GameObject("CubemapCam");
        go.AddComponent<Camera>();
        go.transform.position = renderPosition.position;
        // 將相機觀察到的圖像渲染到cubemap        
        go.GetComponent<Camera>().RenderToCubemap(cubemap);
        // 銷燬相機
        DestroyImmediate(go);
    }

    [MenuItem("GameObject/RenderCubemap")]
    static void RenderCubemap()
    {
        ScriptableWizard.DisplayWizard<RenderCubemapWizard>(
            "RenderCubemap", "當即渲染");
    }
}

在場景中建立一個空GameObj，並設置好合適的位置，在Project面板新建一個cubemap，並勾選Readable,而後點擊菜單欄GameObject-RenderCubemap,將空gameObj以及新建的cubemap拖拽上去，點擊當即渲染，就將6張圖像渲染到了該cubemap中。

三、編寫shader實現反射

Shader "yzpShader/Reflecte" {
    Properties {
        _Color ("Color Tint", Color) = (1, 1, 1, 1)
        _ReflectColor ("Reflection Color", Color) = (1, 1, 1, 1)
        _ReflectAmount ("Reflect Amount", Range(0, 1)) = 1
        _Cubemap ("Reflection Cubemap", Cube) = "_Skybox" {}
    }
    SubShader {
        Tags { "RenderType"="Opaque" "Queue"="Geometry"}
        
        Pass { 
            Tags { "LightMode"="ForwardBase" }
            
            CGPROGRAM
            
            #pragma multi_compile_fwdbase
            
            #pragma vertex vert
            #pragma fragment frag
            
            #include "Lighting.cginc"
            #include "AutoLight.cginc"
            
            fixed4 _Color;
            fixed4 _ReflectColor;
            fixed _ReflectAmount;
            samplerCUBE _Cubemap;
            
            struct a2v {
                float4 vertex : POSITION;
                float3 normal : NORMAL;
            };
            
            struct v2f {
                float4 pos : SV_POSITION;
                float3 worldPos : TEXCOORD0;
                fixed3 worldNormal : TEXCOORD1;
                fixed3 worldViewDir : TEXCOORD2;
                fixed3 worldRefl : TEXCOORD3;
                SHADOW_COORDS(4)
            };
            
            v2f vert(a2v v) {
                v2f o;
                
                o.pos = UnityObjectToClipPos(v.vertex);
                
                o.worldNormal = UnityObjectToWorldNormal(v.normal);
                
                o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
                
                o.worldViewDir = UnityWorldSpaceViewDir(o.worldPos);
                
                // 計算世界座標空間下的反射方向
                o.worldRefl = reflect(-o.worldViewDir, o.worldNormal);
                
                TRANSFER_SHADOW(o);
                
                return o;
            }
            
            fixed4 frag(v2f i) : SV_Target {
                           //歸一化
                fixed3 worldNormal = normalize(i.worldNormal);
                fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));        
                fixed3 worldViewDir = normalize(i.worldViewDir);        
                //環境光
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
                //漫反射
                fixed3 diffuse = _LightColor0.rgb * _Color.rgb * max(0, dot(worldNormal, worldLightDir));
                
                //使用世界空間下的反射方向對cubemap採樣
                fixed3 reflection = texCUBE(_Cubemap, i.worldRefl).rgb * _ReflectColor.rgb;
                
                UNITY_LIGHT_ATTENUATION(atten, i, i.worldPos);
                
                //混合獲得最終顏色 
                fixed3 color = ambient + lerp(diffuse, reflection, _ReflectAmount) * atten;
                
                return fixed4(color, 1.0);
            }
            
            ENDCG
        }
    }
    FallBack "Reflective/VertexLit"
}