帶法線貼圖的高光着色

<1>效果

<2>代碼

//blinn高光 帶法線細節
//思路:使用切線空間下面的法線貼圖(效率雖然低點,可是通用性好)
//頂點函數計算切線空間轉世界空間矩陣
//片元函數採樣法線貼圖 而且反隱射 再計算光照
Shader "Tang/617/BlinnTexNormal"{
	Properties{
		_Color("Tin Color",Color) = (1,1,1,1)
		_MainTex("漫反射貼圖",2D) = "white" { }
		_BumpTex("法線貼圖",2D) = "bump" { }
		_BumpScale("BumpScale",Range(1,8)) = 2
		_Specular("Specular",Color) = (1,1,1,1)
		_Gloss("Gloss",Range(1,64)) = 8
	}

	SubShader{
		Pass{
			Tags {"LightMode" = "ForwardBase"}
			CGPROGRAM
			#pragma vertex vert 
			#pragma fragment frag 
			#include "Lighting.cginc"

			struct a2v{
				float4 vertex:POSITION;
				float3 normal:NORMAL;
				float4 tangent:TANGENT;
				float4 texcoord:TEXCOORD0;
			};
			struct v2f{
				float4 pos:SV_POSITION;
				float4 uv:TEXCOORD0;
				//切線空間轉世界空間矩陣
				float4 TtoW0:TEXCOORD1;
				float4 TtoW1:TEXCOORD2;
				float4 TtoW2:TEXCOORD3;
			};

			fixed4 _Color;
			fixed4 _Specular;
			fixed _Gloss;
			sampler2D _MainTex;float4 _MainTex_ST;
			sampler2D _BumpTex;float4 _BumpTex_ST;
			fixed _BumpScale;

			v2f vert(a2v v){
                v2f o;
				o.pos = UnityObjectToClipPos(v.vertex);
				fixed3 worldNormal = UnityObjectToWorldNormal(v.normal);
				fixed3 worldPos = mul(unity_ObjectToWorld,v.vertex).xyz;
				fixed3 worldTangent = UnityObjectToWorldDir(v.tangent.xyz);
				fixed3 worldBinormal = cross(worldNormal,worldTangent)*v.tangent.w;//保證副法線的方向正確*v.tangent.w？
				//uv
				o.uv.xy = TRANSFORM_TEX(v.texcoord,_MainTex);
				o.uv.zw = TRANSFORM_TEX(v.texcoord,_BumpTex);
				//切線到世界空間的矩陣
				o.TtoW0 = float4(worldTangent.x,worldBinormal.x,worldNormal.x,worldPos.x);
				o.TtoW1 = float4(worldTangent.y,worldBinormal.y,worldNormal.y,worldPos.y);
				o.TtoW2 = float4(worldTangent.z,worldBinormal.z,worldNormal.z,worldPos.z);

				return o;
			}

			fixed4 frag(v2f i):SV_Target{
				//世界座標
				fixed3 worldPos = fixed3(i.TtoW0.w,i.TtoW1.w,i.TtoW2.w);
				//世界光線方向
				fixed3 lightDir = UnityWorldSpaceLightDir(worldPos);
				//世界觀察方向
				fixed3 viewDir = UnityWorldSpaceViewDir(worldPos);
				//採樣法線貼圖 並反隱射到-1,1(像素只能是0-1 因此須要反隱射)
				fixed3 bump = UnpackNormal(tex2D(_BumpTex,i.uv.zw));
				bump.xy *= _BumpScale;
				bump.z = sqrt(1-saturate(dot(bump.xy,bump.xy)));
				bump = normalize(half3(dot(i.TtoW0.xyz,bump),dot(i.TtoW1.xyz,bump),dot(i.TtoW2.xyz,bump)));
				//下面使用法線進行光照計算
                fixed3 albedo = tex2D(_MainTex,i.uv.xy)*_Color.rgb;
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz*albedo;
				fixed3 diffuse = _LightColor0.rgb*albedo* saturate(dot(bump,lightDir));								
				//blinn
				fixed3 h = normalize(lightDir+viewDir);
				fixed3 specular = _LightColor0.rgb*_Specular.rgb* pow(saturate(dot(h,bump)),_Gloss);
				return fixed4(ambient+diffuse+specular,1);
			}

			ENDCG
		}
	}

	FallBack "Diffuse"
}

　　

<3>最主要的是法線轉到世界空間

咱們用的法線貼圖的切線空間下的，因此須要切線空間轉世界空間矩陣Mc->p 

那麼問題來了,這個作空間變換的矩陣是怎麼推導出來的

假如：Oc爲子空間原點在父空間的座標,X、Y、Z是子空間三條軸在父空間的表示

如今子空間有1點p(a,b,c)，求點p在父空間下的座標

Ap = Oc + aXc + bYc + cZc

推導結果(過程Shader入門精要70頁)

              [Xcx,Ycx,Zcx]

Mc->p = [Xcy,Ycy,Zcy]

              [Xcz,Ycz,Zcz]

--切線空間轉世界空間矩陣

--切線空間下的法線貼圖 X軸是頂點切線 Z軸是頂點法線 Y軸是切線與法線的組成面的法線

--須要知道切線空間的三條軸在世界空間的表示

v2f vert(){

    fixed3 worldNormal = UnityObjectToWorldNormal(v.normal);

    fixed3 worldPos = mul(unity_ObjectToWorld,v.vertex).xyz;

    fixed3 worldTangent = UnityObjectToWorldDir(v.tangent);

    fixed3 worldBinormal = cross(worldNormal,worldTangent)*v.tangent.w;

}

TtoW0[worldTangent.x , worldBinormal.x , worldNormal.x][bump.x]

TtoW1[worldTangent.y , worldBinormal.y , worldNormal.y][bump.y]

TtoW2[worldTangent.z , worldBinormal.z , worldNormal.z][bump.z]

--矩陣相乘

worldTangent.x*bump.x + worldBinormal.x*bump.y + worldNormal.x*bump.z

worldTangent.y*bump.x + worldBinormal.y*bump.y + worldNormal.y*bump.z

worldTangent.z*bump.x + worldBinormal.z*bump.y + worldNormal.z*bump.z

即爲

x: dot(TtoW0.xyz,bump)

y: dot(TtoW1.xyz,bump)

z: dot(TtoW2.xyz,bump)

 

最後，修改下片元函數

                //切線空間轉世界空間
                //bump = normalize(half3(dot(i.TtoW0.xyz,bump),dot(i.TtoW1.xyz,bump),dot(i.TtoW2.xyz,bump)));
                //用矩陣乘 其實跟上面是同樣
                fixed3x3 TtoW = fixed3x3(i.TtoW0.xyz,i.TtoW1.xyz,i.TtoW2.xyz);
                bump = normalize( mul(TtoW,bump).xyz );