bison

BSION
==Bison 語法文件內容的佈局==

Bison 工具將把 Bison 語法文件做爲輸入。語法文件的擴展名爲.y。Bison 語法文件內容的分佈以下（四個部分）：
%{
序言
%}
Bison 聲明
%%
語法規則
%%
結尾
序言部分可定義 actions 中的C代碼要用到的類型和變量，定義宏，用 #include 包含頭文件等等。要在此處聲明詞法分析器 yylex 和錯誤輸出器 yyerror 。還在此處定義其餘 actions 中使用到的全局標識符。

Bison聲明部分能夠聲明終結符和非終結符的名字，也能夠描述操做符的優先級，以及各類符號的值語義的數據類型。各類非單個字符的記號（節點）都必須在此聲明。

語法規則部分描述瞭如何用組件構造出一個非終結符。（這裏咱們用術語組件來表示一條規則中的各個組成部分。）

結尾部分能夠包含你但願使用的任何的代碼。一般在序言部分聲明的函數就在此處定義。在簡單程序中全部其他部分均可以在此處定義。

一個逆波蘭計算器的例子：                                                                                                                                                                                     
/* Reverse polish notation calculator. */

%{

#define YYSTYPE double

#include <stdio.h>

#include <stdlib.h>

#include <math.h>

int yylex (void);

void yyerror (char const *);

%}

%token NUM

%% /* Grammar rules and actions follow. */

input: /* empty */

| input line

;

line: '\n'

| exp '\n' { printf ("\t%.10g\n", $1); }

;

exp: NUM { $$ = $1; }

| exp exp '+' { $$ = $1 + $2; }

| exp exp '-' { $$ = $1 - $2; }

| exp exp '*' { $$ = $1 * $2; }

| exp exp '/' { $$ = $1 / $2; }

/* Exponentiation */

| exp exp '^' { $$ = pow($1, $2); }

/* Unary minus */

| exp 'n' { $$ = -$1; }

;

%%

/* The lexical analyzer returns a double floating point

number on the stack and the token NUM, or the numeric code

of the character read if not a number. It skips all blanks

and tabs, and returns 0 for end-of-input. */

#include <ctype.h>

int yylex (void)
{

    int c;

    /* Skip white space. */

    while ((c = getchar ()) == ' ' || c == '\t');

    /* Process numbers. */

    if (c == '.' || isdigit (c))
    {
    ungetc (c, stdin);
    scanf ("%lf", &yylval);
    return NUM;
    }

    /* Return end-of-input. */

    if (c == EOF)
        return 0;

    /* Return a single char. */

    return c;

}

int main (void)
{
    return yyparse ();
}

/* Called by yyparse on error. */

void yyerror(char const *s) {     fprintf (stderr, "%s\n", s); } /* 編譯方法 bison rpcalc.y cc -o rpcalc rpcalc.tab.c -lm */