使用VBS腳本實現的Hosts文件一鍵配置

hosts文件存儲了IP地址與域名的映射。由於有的時候須要常常性地配置hosts文件，所以這段時間我琢磨了一套傻瓜化的hosts文件配置方案，記錄以下。

先說一下怎麼樣進入hosts文件，Windows環境（我用的是一個32位的Win7）下hosts文件在計算機中的位置，在目錄%windir%\System32\drivers\etc\，文件名爲hosts，沒有擴展名。不過相比每次都要點不少目錄才能找到hosts文件，咱們能夠經過執行下面這個bat腳本直接用記事本打開hosts文件：

@echo off 
if "%1" == "h" goto begin 
mshta vbscript:createobject("wscript.shell").run("%~nx0 h",0)(window.close)&&exit 
:begin 

notepad %SystemRoot%/System32/drivers/etc/hosts
exit

將這個bat腳本取名爲host.bat，放在C:\Windows\System32下，就能夠實如今命令行裏或是Win7的開始菜單中直接輸入host命令打開hosts文件了。

言歸正傳，下面我來講下如何自動向hosts文件後面插入記錄。

下面這個bat腳本，能夠知足最簡單的hosts配置，即在hosts文件的最後追加一條記錄：

@attrib -r "%windir%\System32\drivers\etc\hosts" 
@echo ###### Host配置 START >>"%windir%\System32\drivers\etc\hosts"   
@echo 127.0.0.1 www.tsybius2014.com >>"%windir%\System32\drivers\etc\hosts"   
@echo 127.0.0.1 www.tsybius2014.net >>"%windir%\System32\drivers\etc\hosts"  
@echo ###### Host配置 END >>"%windir%\System32\drivers\etc\hosts"   
::@attrib +r "%windir%\System32\drivers\etc\hosts"

配置效果以下：

這個方法很是簡單，可是使用這個方法也存在缺點，即存在映射記錄可能被反覆配置的狀況。

所以我又試着寫了下面這個能夠自動配置指定網址hosts的VBS腳本HostHelper.vbs，代碼以下：

''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
' HostHelper Hosts文件配置工具
' 做者：Tsybius2014
' 時間：2015年10月20日
' 描述：HostHelper 是一個Host文件配置工具，輸入爲Host文件地址、IP地址、域名
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''

'強制顯式聲明模塊中的全部變量
Option Explicit

'讀取參數
Dim strHostAddr 'Host文件地址
Dim strIpAddr   'IP地址
Dim strName     '主機名
Dim strOper     '操做類型 cover：寫入 append：追加
If WScript.Arguments.Count <> 4 Then
    WScript.Echo "參數錯誤"
    WScript.Quit
Else 
    '讀入參數
    strHostAddr = WScript.Arguments(0) '參數1：Host文件地址
    strIpAddr = WScript.Arguments(1)   '參數2：IP地址
    strName = WScript.Arguments(2)     '參數3：主機名
    strOper = WScript.Arguments(3)     '參數4：寫入策略 cover：覆蓋 append：追加
    '覆蓋：排他性加入
    '追加：在文件末尾添加IP地址與主機名對應關係
    '判斷寫入策略
    Dim strOperName
    If strOper = "cover" Then 
        strOperName = "覆蓋"
    ElseIf strOper = "append" Then
        strOperName = "追加"
    Else
        WScript.Echo "非法的寫入策略！"
        WScript.Quit
    End If
    '展現輸入信息
    WScript.Echo "Host文件地址：" & strHostAddr
    WScript.Echo "IP地址：" & strIpAddr
    WScript.Echo "主機名：" & strName
    WScript.Echo "寫入策略：" & strOperName
    WScript.Echo ""
End If

Dim FSO
Set FSO = CreateObject("Scripting.FileSystemObject")
Const ForReading = 1, ForWriting = 2, ForAppending = 8

'遍歷Host文件，判斷是否已有指定的Host值
Dim file
Set file = FSO.OpenTextFile(strHostAddr)
Dim strLine
Dim bHostAlreadyExist
bHostAlreadyExist = False
Do While file.AtEndOfStream <> True
    strLine = LTrim(file.ReadLine)
    If Not Left(strLine, 1) = "#" Then
        Dim Array
        Array = Split(strLine, " ", -1, 1)
        If UBound(Array) >= 1 Then
            'IP同樣且域名同樣，則認爲要配置的Host已存在
            If Array(0) = strIpAddr And Array(1) = strName Then
                bHostAlreadyExist = True
                Exit Do
            End If
        Else 
        End If 
        'WScript.Echo strLine
    Else 
    End If
Loop
file.Close

If bHostAlreadyExist Then
    WScript.Echo "您要配置的Host已存在！"
    WScript.Quit
End If 

'將IP地址與域名的對應關係寫入到Host
If strOper = "cover" Then

    '寫入策略：覆蓋
    Dim fileRead
    Set fileRead = FSO.OpenTextFile(strHostAddr)
    Dim strContent
    strContent = fileRead.ReadAll()
    fileRead.Close
    Dim ArrayLine
    ArrayLine = Split(strContent, vbCrlf, -1, 1)
    Dim i
    Dim strArrayEachLine
    For i = 0 To UBound(ArrayLine)
        ArrayLine(i) = Trim(ArrayLine(i))
        If Not Left(ArrayLine(i), 1) = "#" Then
            strArrayEachLine = Split(ArrayLine(i), " ", -1, 1)
            If UBound(strArrayEachLine) >= 1 Then
                If strArrayEachLine(1) = strName Then
                    ArrayLine(i) = "#" & ArrayLine(i)
                End If
            End If
        End If
    Next
    strContent = Join(ArrayLine, vbCrlf)
    strContent = strContent & vbCrlf & strIpAddr & " " & strName
    Dim fileCover
    Set fileCover = FSO.OpenTextFile(strHostAddr, ForWriting, False)
    fileCover.Write strContent
    fileCover.Close
    WScript.Echo "覆蓋完畢"
    
ElseIf strOper = "append" Then

    '寫入策略：追加
    Dim fileAppend
    Set fileAppend = FSO.OpenTextFile(strHostAddr, ForAppending, False)
    fileAppend.WriteLine
    fileAppend.WriteLine strIpAddr & " " & strName
    WScript.Echo "追加完畢"
    fileAppend.Close

End If

這個VBS腳本的功能，是傳入hosts文件地址、IP地址、主機名，並指定寫入策略（包括覆蓋、追加），執行該腳本後會自動配置hosts文件。

爲了更好地運行這個VBS腳本，我寫了一個bat批處理命令行來執行它，代碼以下：

@echo Tsybius 2015/10/20

set hostIPAddr=127.0.0.1
set hostName=www.tsybius2014.com
set vbsAddr=HostHelper.vbs
set hostAddr=%windir%\System32\drivers\etc\hosts

if not exist %hostAddr% echo "Host Not Found"
if not exist %hostAddr% exit
if exist %cd%\hosts.bak del %cd%\hosts.bak
copy %hostAddr% %cd%\hosts.bak

@attrib -r %hostAddr%
cscript %vbsaddr% %hostAddr% hostIPAddr hostName append
::@attrib +r %hostAddr%

@pause

這個腳本試圖向hosts文件的最後追加一條記錄，域名爲www.tsybius2014.com，IP爲127.0.0.1，寫入策略爲追加，而且在寫入前先對hosts文件進行了備份。

這個腳本的執行效果以下：

進入hosts文件，能夠看到映射已被寫入在hosts.txt的最後

說明：因爲本文中的代碼只進行了簡單的測試，所以部分代碼可能存在健壯性不夠的問題，實際使用時應謹慎使用。

END