sql server使用公用表表達式CTE經過遞歸方式編寫通用函數自動生成連續數字和日期

問題：
在數據庫腳本開發中，有時須要生成一堆連續數字或者日期，例如yearly report就須要連續數字作年份，例如daily report就須要生成必定時間範圍內的每一天日期。
而自帶的系統表master..spt_values存在必定的侷限性，只是從0到2047（驗證腳本：select * from master..spt_values b where b.type = 'P'），也不能直接生成連續日期。
可能大部分人會想到一個笨辦法，經過while循環去逐條插入數據到臨時表，每次數字加1或者日期加1天，但這樣和數據庫服務器的交互就太頻繁了。若是生成1W個連續數字，那就要跟數據庫服務器交互1W次，可怕！若是是有1000個客戶端都須要調用這個while循環，那就是1000W次！可怕！

解決方案：
能夠使用公用表表達式CTE經過遞歸方式實現，並編寫爲一個通用表值函數方便調用，封裝起來簡化使用，返回表格式數據。
CTE是在內存中準備好數據，而不是每次一條往返服務器和客戶端一次。若是須要再插入到臨時表的話就是所有數據一次性插入。
若是傳入參數爲數字，則生成連續數字；若是傳入參數爲日期，則生成連續日期。
是否是以爲很方便呢？

函數腳本：

if object_id('dbo.fun_ConcatStringsToTable') is not null drop function dbo.fun_ConcatStringsToTable
go
/*
    功能：連續字符串（數字或日期）以table形式返回
    做者：zhang502219048 2018-12-10
    腳原本源：https://www.cnblogs.com/zhang502219048/p/11108991.html 
-- 示例1（數字）：
   select * from dbo.fun_ConcatStringsToTable(1, 10000)
-- 示例2（數字文本）：
   select * from dbo.fun_ConcatStringsToTable('1', '10000')
-- 示例3（日期）：
   declare @dateBegin datetime = '2009-1-1', @dateEnd datetime = '2018-12-31'
   select * from dbo.fun_ConcatStringsToTable(@dateBegin, @dateEnd)
-- 示例4（日期文本）：
   select * from dbo.fun_ConcatStringsToTable('2009-1-1', '2018-12-31')
**/
create function [dbo].[fun_ConcatStringsToTable]
(
    @strBegin as nvarchar(100),
    @strEnd as nvarchar(100)
)
returns @tempResult table (vid nvarchar(100))
as
begin
    --數字
    if isnumeric(@strBegin) = 1 and isnumeric(@strEnd) = 1
    begin
        --使用CTE遞歸批量插入數字數據
        ;with cte_table(id) as
        (
            select cast(@strBegin as int)
            union all
            select id + 1
            from cte_table
            where id < @strEnd
        )
        insert into @tempResult
        select cast(id as nvarchar(100))
        from cte_table 
        option (maxrecursion 0)
    end
    --日期
    else if isdate(@strBegin) = 1 and isdate(@strEnd) = 1
    begin
        --使用CTE遞歸批量插入日期數據
        ;with cte_table(CreatedDate) as
        (
            select cast(@strBegin as datetime)
            union all
            select dateadd(day, 1, CreatedDate)
            from cte_table
            where CreatedDate < @strEnd
        )
        insert into @tempResult
        select convert(varchar(10), CreatedDate, 120)
        from cte_table
        option (maxrecursion 0)
    end

    return;
end
go

調用函數示例：

-- 示例1（數字）：
   select * from dbo.fun_ConcatStringsToTable(1, 10000)
-- 示例2（數字文本）：
   select * from dbo.fun_ConcatStringsToTable('1', '10000')
-- 示例3（日期）：
   declare @dateBegin datetime = '2009-1-1', @dateEnd datetime = '2018-12-31'
   select * from dbo.fun_ConcatStringsToTable(@dateBegin, @dateEnd)
-- 示例4（日期文本）：
   select * from dbo.fun_ConcatStringsToTable('2009-1-1', '2018-12-31')

腳本運行結果：

     

結論：
從上面幾個圖能夠看到，經過簡單調用fun_ConcatStringsToTable這個自定義表值函數，指定起止數字或日期，就達到了生成連續數字和日期的目的。
擴展：
若是想生成連續月份呢？博主在這裏也幫你們寫了一下腳本，若是須要能夠在此基礎上再自行作成表值函數：

with cte_table(CreatedDate) as
(
    select cast('2017-12-1' as datetime)
    union all
    select dateadd(month, 1, CreatedDate)
    from cte_table
    where CreatedDate < '2018-04-01'
)
select convert(varchar(7), CreatedDate, 120) as YearMonth
from cte_table
option (maxrecursion 0)

【轉載請註明博文來源：http://www.javashuo.com/article/p-vfznufft-hs.html】