Unity Shader 玻璃效果

一個玻璃效果主要分爲兩個部分，一部分是折射效果的計算，另外一部分則是反射。下面分類進行討論：

折射：

1.利用Grass Pass對當前屏幕的渲染圖像進行採樣

2.獲得法線貼圖對摺射的影響

3.對採集的屏幕圖像進行關於法線方向上的扭曲和偏移，以模擬折射效果

反射：

主要利用環境貼圖產生反射的殘影，並和主貼圖採樣結果混合

 

獲得反射和折射的結果後，以一個插值變量控制最終效果（相似於玻璃的透光率）；

腳本以下：

  1 // Upgrade NOTE: replaced '_Object2World' with 'unity_ObjectToWorld'
  2 
  3 Shader "MyUnlit/GlassRefraction"
  4 {
  5     Properties
  6     {
  7         _MainTex ("Texture", 2D) = "white" {}
  8         //這裏的法線貼圖用於計算折射產生的扭曲
  9         _BumpMap("Normal Map",2D)="bump"{}
 10         //這裏的環境貼圖用於反射周圍環境的部分殘影
 11         _Cubemap("Environment Map",cube)="_Skybox"{}
 12         _Distortion("Distortion",range(0,100))=10
 13         //一個折射係數，用於控制折射和反射的佔比
 14         _RefractAmount("Refract Amount",range(0,1))=1
 15     }
 16     SubShader
 17     {
 18         //保證該物體渲染時，其餘不透明物體都已經渲染完成
 19         Tags { "RenderType"="Opaque" "Queue"="Transparent"}
 20         //抓取當前屏幕的渲染圖像並存入指定紋理
 21         GrabPass{"_RefractionTex"}
 22 
 23         Pass
 24         {
 25             CGPROGRAM
 26             #pragma vertex vert
 27             #pragma fragment frag
 28 
 29             #include "UnityCG.cginc"
 30 
 31             struct appdata
 32             {
 33                 float4 vertex : POSITION;
 34                 float2 uv : TEXCOORD0;
 35                 float3 normal:NORMAL;
 36                 float4 tangent:TANGENT;
 37             };
 38 
 39             struct v2f
 40             {
 41                 float4 uv : TEXCOORD0;
 42                 float4 pos : SV_POSITION;
 43                 float4 scrPos : TEXCOORD4;
 44                 float4 TtoW0:TEXCOORD1;
 45                 float4 TtoW1:TEXCOORD2;
 46                 float4 TtoW2:TEXCOORD3;
 47             };
 48 
 49             sampler2D _MainTex;
 50             float4 _MainTex_ST;
 51             sampler2D _BumpMap;
 52             float4 _BumpMap_ST;
 53             samplerCUBE _Cubemap;
 54             float _Distortion;
 55             fixed _RefractAmount;
 56             sampler2D _RefractionTex;
 57             float4 _RefractionTex_TexelSize;
 58 
 59             v2f vert (appdata v)
 60             {
 61                 v2f o;
 62 
 63                 o.pos = UnityObjectToClipPos(v.vertex);
 64 
 65                 o.uv.xy = TRANSFORM_TEX(v.uv, _MainTex);
 66                 o.uv.zw = TRANSFORM_TEX(v.uv, _BumpMap);
 67                 //獲得屏幕採樣座標
 68                 o.scrPos = ComputeGrabScreenPos(o.pos);
 69 
 70                 float3 worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
 71                 float3 worldNormal = UnityObjectToWorldNormal(v.normal);
 72                 float3 worldTangent = UnityObjectToWorldDir(v.tangent.xyz);
 73                 float3 worldBinormal = cross(worldTangent, worldNormal)*v.tangent.w;
 74 
 75                 o.TtoW0 = float4(worldTangent.x, worldBinormal.x, worldNormal.x, worldPos.x);
 76                 o.TtoW1 = float4(worldTangent.y, worldBinormal.y, worldNormal.y, worldPos.y);
 77                 o.TtoW2 = float4(worldTangent.z, worldBinormal.z, worldNormal.z, worldPos.z);
 78 
 79                 return o;
 80             }
 81 
 82             fixed4 frag (v2f i) : SV_Target
 83             {
 84                 float3 worldPos = float3(i.TtoW0.w,i.TtoW1.w,i.TtoW2.w);
 85                 float3x3 TtoW = float3x3(i.TtoW0.xyz, i.TtoW1.xyz, i.TtoW2.xyz);
 86 
 87                 fixed3 worldViewDir = normalize(UnityWorldSpaceViewDir(worldPos));
 88 
 89                 fixed3 tanNormal = UnpackNormal(tex2D(_BumpMap, i.uv.zw));
 90                 fixed3 worldNormal = mul(TtoW, tanNormal);
 91                 //對採集的屏幕圖像進行關於法線方向上的扭曲和偏移，也就是模擬折射的效果
 92                 float2 offset = tanNormal.xy*_Distortion*_RefractionTex_TexelSize.xy;
 93                 i.scrPos.xy += offset;
 94                 fixed3 refractCol = tex2D(_RefractionTex, i.scrPos.xy / i.scrPos.w).xyz;
 95                 //這一塊用來模擬反射的效果，反射越強，也就是透光度越低，越能看到主貼圖紋理以及周圍環境反射的殘影
 96                 fixed3 reflectDir = reflect(-worldViewDir, worldNormal);
 97                 fixed4 mainTexCol = tex2D(_MainTex, i.uv.xy);
 98                 fixed4 cubemapCol = texCUBE(_Cubemap, reflectDir);
 99                 fixed3 reflectCol = mainTexCol.rgb*cubemapCol.rgb;
100                 //最後將折射和反射進行一個綜合疊加，_RefractAmount能夠認爲是透光率，當它爲1時，就是全透過而沒有反射，爲0時就是全反射跟鏡子同樣
101                 fixed3 color = refractCol * _RefractAmount + reflectCol * (1 - _RefractAmount);
102                 return fixed4(color,1.0);
103             }
104             ENDCG
105         }
106     }
107     fallback "Diffuse"
108 }

效果以下：