SQL Server 在多個數據庫中建立同一個存儲過程（Create Same Stored Procedure in All Databases）

時間  2019-11-06
標籤 sql server 多個 數據庫 建立 同一個 存儲 過程 create stored procedure databases 欄目 SQL 简体版
原文   原文鏈接

一.本文所涉及的內容（Contents）

  1. 本文所涉及的內容（Contents）
  2. 背景（Contexts）
  3. 遇到的問題（Problems）
  4. 實現代碼（SQL Codes）
    1. 方法一：拼接SQL；
    2. 方法二：調用模板存儲過程建立存儲過程；
    3. 總結
    4. 擴展閱讀
  5. 參考文獻（References）

二.背景（Contexts）

　　在個人數據庫服務器上，同一個實例下面掛載着許多相同結構的數據庫，他們爲不一樣公司提供着服務，在許多時候我須要同時建立、修改、刪除一些對象，存儲過程就是其中一個，可是想要批量建立存儲，這有些特殊，下面就教你如何實如今多個數據庫中建立同一個存儲過程（Create Same Stored Procedure in All Databases）。html

三.遇到的問題（Problems）

　　在以前的文章中屢次談到使用遊標的方式處理的各類問題：sql

　　若是使用遊標來批量建立存儲過程，可能你會遇到下面的一些問題，假設咱們須要在多個數據庫（固然能夠過濾掉部分數據庫）中建立一樣一個存儲過程sp_GetId，存儲過程的腳本以下Script1所示：數據庫

-- Script1：
-- 須要被批量建立的存儲過程
USE [master]
GO
Create PROCEDURE [dbo].[sp_GetId]
AS
BEGIN
    DECLARE @database_id INT
    SET @database_id = 0
    SELECT TOP 1 @database_id = [database_id] FROM sys.[databases]

END

　　根據前面提到使用遊標方式，咱們可能會寫出相似下面的代碼，錯誤代碼Script2示例：服務器

-- Script2：
-- =============================================
-- Author:      <聽風吹雨>
-- Blog:        <http://gaizai.cnblogs.com/>
-- Create date: <2014/05/03>
-- Description: <批量建立存儲過程，錯誤代碼示例>
-- =============================================
DECLARE @databaseName VARCHAR(100)
DECLARE @SQL NVARCHAR(MAX)
DECLARE @itemCur CURSOR

SET @itemCur = CURSOR FOR
    SELECT '['+[name]+']' FROM sys.databases WHERE database_id > 4

OPEN @itemCur
FETCH NEXT FROM @itemCur INTO @databaseName
WHILE @@FETCH_STATUS=0
BEGIN
    --邏輯處理
    PRINT @databaseName
    
    SET @SQL = '
    USE '+@databaseName+'
    GO
    CREATE PROCEDURE [dbo].[sp_GetId]
AS
BEGIN
    DECLARE @database_id INT
    SET @database_id = 0
    SELECT TOP 1 @database_id = [database_id] FROM sys.[databases]

END'
    PRINT(@SQL);
    EXEC(@SQL);
    
    FETCH NEXT FROM @itemCur INTO @databaseName
END 

CLOSE @itemCur
DEALLOCATE @itemCur

執行上面的代碼你會遇到這樣的錯誤信息：post

wps_clip_image-14323

（Figure1：錯誤信息1）spa

根據錯誤信息修改上面的SQL代碼，把」GO」改爲「;」但仍是會出現下圖Figure2的錯誤信息：code

wps_clip_image-8651

（Figure2：錯誤信息2）htm

既然這樣行不通，也許你還會嘗試在[dbo].[sp_GetId]前面加上數據庫名的變量，可是卻出現下圖Figure3的錯誤信息：對象

wps_clip_image-17048

（Figure3：錯誤信息3）blog

四.實現代碼（SQL Codes）

　　上面的3個錯誤讓咱們陷入了困境，也許你想過放棄了，可是通過努力，我經過2種方式實現了在多個數據庫中建立同一個存儲過程（你們可認爲是批量建立存儲過程），下面是實現的2種方式概述：

　　1. 經過修改過的系統存儲過程[dbo].[sp_MSforeachdb_Filter]和拼接SQL；

　　2. 經過建立一個模板存儲過程，由系統存儲過程sp_MSForEachDB循環調用另一個建立存儲過程的存儲來建立模板存儲過程（這也許聽起來很拗口，看後面的實現腳本Script7，你就會理解了）。

 

(一) 實現方式1：經過修改過的系統存儲過程[dbo].[sp_MSforeachdb_Filter]和拼接SQL；

　　1) 首先咱們須要在master數據庫中建立一個存儲過程[dbo].[sp_MSforeachdb_Filter]，這是經過修改系統存儲過程sp_MSforeachdb得來的，作的改進主要是能夠過濾數據庫，建立的SQL代碼以下Script3所示：

-- Script3：
-- =============================================
-- Author:      <聽風吹雨>
-- Blog:        <http://gaizai.cnblogs.com/>
-- Create date: <2013.05.06>
-- Description: <擴展sp_MSforeachdb，增長@whereand參數>
-- =============================================
USE [master]
GO
SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER OFF
GO

create proc [dbo].[sp_MSforeachdb_Filter]
    @command1 nvarchar(2000), @replacechar nchar(1) = N'?', @command2 nvarchar(2000) = null, @command3 nvarchar(2000) = null,
    @whereand nvarchar(2000) = null,@precommand nvarchar(2000) = null, @postcommand nvarchar(2000) = null
as
    set deadlock_priority low
    
    /* This proc returns one or more rows for each accessible db, with each db defaulting to its own result set */
    /* @precommand and @postcommand may be used to force a single result set via a temp table. */

    /* Preprocessor won't replace within quotes so have to use str(). */
    declare @inaccessible nvarchar(12), @invalidlogin nvarchar(12), @dbinaccessible nvarchar(12)
    select @inaccessible = ltrim(str(convert(int, 0x03e0), 11))
    select @invalidlogin = ltrim(str(convert(int, 0x40000000), 11))
    select @dbinaccessible = N'0x80000000'        /* SQLDMODbUserProf_InaccessibleDb; the negative number doesn't work in convert() */

    if (@precommand is not null)
        exec(@precommand)

    declare @origdb nvarchar(128)
    select @origdb = db_name()

    /* If it's a single user db and there's an entry for it in sysprocesses who isn't us, we can't use it. */
   /* Create the select */
    exec(N'declare hCForEachDatabase cursor global for select name from master.dbo.sysdatabases d ' +
            N' where (d.status & ' + @inaccessible + N' = 0)' +
            N' and (DATABASEPROPERTY(d.name, ''issingleuser'') = 0 and (has_dbaccess(d.name) = 1))' + @whereand)

    declare @retval int
    select @retval = @@error
    if (@retval = 0)
        exec @retval = sys.sp_MSforeach_worker @command1, @replacechar, @command2, @command3, 1

    if (@retval = 0 and @postcommand is not null)
        exec(@postcommand)

   declare @tempdb nvarchar(258)
   SELECT @tempdb = REPLACE(@origdb, N']', N']]')
   exec (N'use ' + N'[' + @tempdb + N']')

    return @retval

　　2) 接着在master數據庫中執行下面的SQL在多個數據庫中建立同一個存儲過程，實際上是把須要建立的存儲過程經過拼接保存在@SQL變量中，使用[sp_MSforeachdb_Filter]來過濾數據庫，並在符合條件的每一個數據庫中執行@SQL中的語句，SQL代碼以下Script4所示：

-- Script4：
--批量建立存儲過程
USE [master]
GO
DECLARE @SQL NVARCHAR(MAX)
SELECT @SQL = COALESCE(@SQL,'') + ' USE [?]; EXEC(''
CREATE PROCEDURE [dbo].[sp_GetId]
AS
BEGIN
    DECLARE @database_id INT
    SET @database_id = 0
    SELECT TOP 1 @database_id = [database_id] FROM sys.[databases]

END'')'

PRINT @SQL

--過濾數據庫
EXEC [sp_MSforeachdb_Filter] @command1=@SQL,
@whereand=" and [name] not in('tempdb','master','model','msdb') "

　　3) 執行上面的SQL腳本以後，除了('tempdb','master','model','msdb')4個數據庫以外的數據庫都會建立了存儲過程sp_GetId，爲了快速驗證，可使用下面的SQL腳本進行驗證：

-- Script5：
-- 返回全部數據庫sp_GetId存儲過程列表
IF NOT EXISTS (SELECT * FROM [master].sys.objects 
    WHERE object_id = OBJECT_ID(N'[master].[dbo].[SPList]') AND type in (N'U'))
BEGIN
CREATE TABLE [master].[dbo].[SPList](
    [db_name] [sysname] NULL,
    [sp_name] [sysname] NULL,
) ON [PRIMARY]
END
ELSE
    TRUNCATE TABLE [master].[dbo].[SPList]

EXEC [sp_MSforeachdb_Filter] @command1='
    INSERT INTO [master].[dbo].[SPList]([sp_name])
        SELECT [name] FROM [?].sys.[sysobjects] WHERE TYPE = ''P'' AND [name] = ''sp_GetId''
    UPDATE [master].[dbo].[SPList] SET [db_name] = ''?'' WHERE [db_name] IS NULL
'

SELECT * FROM [master].[dbo].[SPList]

執行上面的SQL腳本的結果以下圖Figure4所示：

wps_clip_image-6113

（Figure4：建立了sp_GetId存儲過程的數據庫列表）

 

(二) 實現方式2：經過建立一個模板存儲過程，由系統存儲過程sp_MSForEachDB循環調用另一個建立存儲過程的存儲來建立模板存儲過程；

　　1) 爲了能看到方式2的實際效果，咱們須要把存在sp_GetId存儲過程的數據庫中批量刪除這個存儲過程，經過下面的腳本Script6來實現：

-- Script6：
-- 批量刪除存儲過程
USE [master]
GO
DECLARE @SQL NVARCHAR(MAX)
SELECT @SQL = COALESCE(@SQL,'') + ' USE [?]; EXEC(''
IF  EXISTS (SELECT * FROM sys.[objects] 
    WHERE object_id = OBJECT_ID(N''''[dbo].[sp_GetId]'''') 
    AND type in (N''''P'''', N''''PC''''))
DROP PROCEDURE [dbo].[sp_GetId] '')'

PRINT @SQL

--過濾數據庫
EXEC [sp_MSforeachdb_Filter] @command1=@SQL,
@whereand=" and [name] not in('tempdb','master','model','msdb') "

　　2) 經過Script5確認全部數據庫都不存在sp_GetId存儲過程；

　　3) 接着在master數據庫中建立模板存儲過程sp_GetId，建立腳本如Script1所示，這裏不作重複；

　　4) 再接着建立一個存儲過程CreateProcedure，這個存儲過程的做用就是建立存儲過程，在這個存儲過程CreateProcedure利用系統表返回sp_GetId存儲過程的內容，保存在變量@proc_text中，查詢出以下所示：

-- Script7：
--建立存儲過程的存儲過程
USE [master]
GO
-- =============================================
-- Author:      <聽風吹雨>
-- Blog:        <http://gaizai.cnblogs.com/>
-- Create date: <2014.05.06>
-- Description: <建立存儲過程的存儲過程>
-- =============================================
CREATE PROC CreateProcedure
(
    @dbname SYSNAME,
    @spname SYSNAME
)
AS
BEGIN
    SELECT @dbname = REPLACE(REPLACE(@dbname,'[',''),']','')

    IF @dbname <> 'master'
    BEGIN
        DECLARE @proc_text NVARCHAR(MAX)
        SELECT @proc_text = REPLACE([text],'''','''''')
            FROM [sysobjects] o
            INNER JOIN [syscomments] c
            ON c.id = o.id
        WHERE
            o.type = 'P' AND
            o.name = @spname

        DECLARE @sql NVARCHAR(MAX)
        SET @sql = 'USE [' + @dbname + ']; EXEC ('' ' + @proc_text + ''');'

        EXEC SP_EXECUTESQL @sql
    END
END
GO

　　5) 準備完上面的步驟，只須要下面的一條SQL語句就能批量建立存儲過程sp_GetId：

-- Script8：
-- 批量建立存儲過程
USE [master]
GO

--過濾數據庫
EXEC [sp_MSforeachdb_Filter] @command1='CreateProcedure ''[?]'', ''sp_GetId''',
@whereand=" and [name] not in('tempdb','master','model','msdb') "

執行上面的SQL腳本的結果以下圖Figure5所示，與Figure4的區別就是在master數據庫中多了一個模板存儲過程sp_GetId。

wps_clip_image-14563

（Figure5：建立了sp_GetId存儲過程的數據庫列表）

(三) 總結

　　上面已經經過兩種方式實現了在多個數據庫中建立同一個存儲過程，若是存儲過程sp_GetId屬於比較簡單的，使用方式1實現會比較快捷，若是sp_GetId比較複雜了，好比存儲過程裏面還包含單引號或者代碼比較多的狀況下，建議使用方式2，雖然方式2的步驟會多一點，可是隻要建立好模板存儲過程，其它的根本不會由於存儲過程sp_GetId而變得複雜；

(四) 擴展閱讀

　　在實際運用中，不少時候你須要的並不僅僅是在多個數據庫中建立同一個存儲過程，可能還須要修改同一個存儲過程，經過上面的閱讀你也許猜到修改存儲過程，能夠先刪除，再建立，對的，這是沒有問題的，不過也能夠直接修改，下面提供SQL代碼：

　　1) 首先修改下master數據庫的模板存儲過程sp_GetId，在存儲過程裏面中加入一個變量@id：

-- Script10：
-- 須要被批量建立的存儲過程
USE [master]
GO
Create PROCEDURE [dbo].[sp_GetId]
AS
BEGIN
    DECLARE @database_id INT
    --修改部分,增長了一個變量
    DECLARE @id INT
    SET @database_id = 0
    SELECT TOP 1 @database_id = [database_id] FROM sys.[databases]

END

　　2) 接着建立一個修改存儲過程的存儲過程AlterProcedure，只須要把變量@proc_text裏面的「CREATE PROC」替換成「ALTER PROC」就能夠了：

-- Script10：
--修改存儲過程的存儲過程
USE [master]
GO
-- =============================================
-- Author:      <聽風吹雨>
-- Blog:        <http://gaizai.cnblogs.com/>
-- Create date: <2014.05.06>
-- Description: <修改存儲過程的存儲過程>
-- =============================================
CREATE PROC AlterProcedure
(
    @dbname SYSNAME,
    @spname SYSNAME
)
AS
BEGIN
    SELECT @dbname = REPLACE(REPLACE(@dbname,'[',''),']','')

    IF @dbname <> 'master'
    BEGIN
        DECLARE @proc_text NVARCHAR(MAX)
        SELECT @proc_text = REPLACE([text],'''','''''')
            FROM [sysobjects] o
            INNER JOIN [syscomments] c
            ON c.id = o.id
        WHERE
            o.type = 'P' AND
            o.name = @spname

        DECLARE @sql NVARCHAR(MAX)
        SET @proc_text = REPLACE(@proc_text,'CREATE PROC','ALTER PROC')
        SET @sql = 'USE [' + @dbname + ']; EXEC ('' ' + @proc_text + ''');'

        EXEC SP_EXECUTESQL @sql
    END
END
GO

　　3) 準備完上面的步驟，再把Script8的腳本中調用存儲過程CreateProcedure改爲調用存儲過程AlterProcedure，經過下面的一條SQL語句批量修改存儲過程sp_GetId：

-- Script11：
-- 批量修改存儲過程
USE [master]
GO

--過濾數據庫
EXEC [sp_MSforeachdb_Filter] @command1='AlterProcedure ''[?]'', ''sp_GetId''',
@whereand=" and [name] not in('tempdb','master','model','msdb') "

　　4) 建立完成後，剩下的就是驗證下數據庫中存儲過程sp_GetId的內容了；

五.參考文獻（References）

Create Same Stored Procedure on All Databases using sp_MSForEachDB T-SQL Example

相關文章
相關標籤/搜索
每日一句
    每一个你不满意的现在，都有一个你没有努力的曾经。
本站公眾號
   歡迎關注本站公眾號,獲取更多信息
聯繫我們 最近搜索 最新文章 沪ICP备13005482号-10 MyBatis教程 SQL 教程 MySQL教程 Java 教程 Thymeleaf 教程 Hibernate教程 Spring教程 Redis教程