編譯return語句

Common Lisp中有一個叫作return的宏，它的做用和日常在C、Java，或者Node.js裏面見到的return關鍵字徹底不同。Common Lisp中的return用於從一個塊（block）中返的，而不是從一個函數中返回。用return能夠寫出下面這樣的代碼，符號YOU-WILL-NOT-SEE-ME永遠不會被打印

(defun foo ()
  (block nil
    (return 123)
    (print 'you-will-not-see-me)))

求值return，就將123做爲block的返回值從中返回了，後面的print並無機會執行——在SBCL中編譯上面這段defun的時候，編譯器甚至已經給出了提醒

return是一個宏，它能夠展開爲一個return-from，並帶有一個名爲NIL的塊名。用return-from能夠直接從函數foo中返回而不須要多一層block，示例代碼以下

(defun foo2 ()
  (return-from foo2 123)
  (print 'you-will-not-see-me))

除了要多寫一個函數的名稱以外，return-from跟C、Java，或者Node.js中的return語句是差很少的——沒錯，只是差很少而已。實際上，return-from也是從一個block中返回的，上面的代碼之因此有效，是由於defun會隱式地定義一個跟函數同名的塊。

這一次要在jjcc2中支持的return，比起Common Lisp，更接近於C語言中的return語句——是用來直接從函數調用中返回的。

編譯return其實很簡單。在目前的inside-out中，return會落入到最後的分支，所以它的惟一一個參數會被翻出來先編譯，而且其結果是放入到%EAX寄存器中的。因此，編譯return只須要生成一道簡單的RET指令就足夠了。修改後的jjcc2以下

(defun jjcc2 (expr globals)
  "支持兩個數的四則運算的編譯器"
  (check-type globals hash-table)
  (cond ((eq (first expr) '+)
         `((movl ,(get-operand expr 0) %eax)
           (movl ,(get-operand expr 1) %ebx)
           (addl %ebx %eax)))
        ((eq (first expr) '-)
         `((movl ,(get-operand expr 0) %eax)
           (movl ,(get-operand expr 1) %ebx)
           (subl %ebx %eax)))
        ((eq (first expr) '*)
         ;; 將兩個數字相乘的結果放到第二個操做數所在的寄存器中
         ;; 由於約定了用EAX寄存器做爲存放最終結果給continuation用的寄存器，因此第二個操做數應當爲EAX
         `((movl ,(get-operand expr 0) %eax)
           (movl ,(get-operand expr 1) %ebx)
           (imull %ebx %eax)))
        ((eq (first expr) '/)
         `((movl ,(get-operand expr 0) %eax)
           (cltd)
           (movl ,(get-operand expr 1) %ebx)
           (idivl %ebx)))
        ((eq (first expr) 'progn)
         (let ((result '()))
           (dolist (expr (rest expr))
             (setf result (append result (jjcc2 expr globals))))
           result))
        ((eq (first expr) 'setq)
         ;; 編譯賦值語句的方式比較簡單，就是將被賦值的符號視爲一個全局變量，而後將eax寄存器中的內容移動到這裏面去
         ;; TODO: 這裏expr的second的結果必須是一個符號才行
         ;; FIXME: 不知道應該賦值什麼比較好，先隨便寫個0吧
         (setf (gethash (second expr) globals) 0)
         (values (append (jjcc2 (third expr) globals)
                         ;; 爲了方便stringify函數的實現，這裏直接構造出RIP-relative形式的字符串
                         `((movl %eax ,(get-operand expr 0))))
                 globals))
        ;; ((eq (first expr) '_exit)
        ;;  ;; 由於知道_exit只須要一個參數，因此將它的第一個操做數塞到EDI寄存器裏面就能夠了
        ;;  ;; TODO: 更好的寫法，應該是有一個單獨的函數來處理這種參數傳遞的事情（以符合calling convention的方式）
        ;;  `((movl ,(get-operand expr 0) %edi)
        ;;    (movl #x2000001 %eax)
        ;;    (syscall)))
        ((eq (first expr) '>)
         ;; 爲了能夠把比較以後的結果放入到EAX寄存器中，以我目前不完整的彙編語言知識，能夠想到的方法以下
         (let ((label-greater-than (intern (symbol-name (gensym)) :keyword))
               (label-end (intern (symbol-name (gensym)) :keyword)))
           ;; 根據這篇文章（https://en.wikibooks.org/wiki/X86_Assembly/Control_Flow#Comparison_Instructions）中的說法，大於號左邊的數字應該放在CMP指令的第二個操做數中，右邊的放在第一個操做數中
           `((movl ,(get-operand expr 0) %eax)
             (movl ,(get-operand expr 1) %ebx)
             (cmpl %ebx %eax)
             (jg ,label-greater-than)
             (movl $0 %eax)
             (jmp ,label-end)
             ,label-greater-than
             (movl $1 %eax)
             ,label-end)))
        ((eq (first expr) 'if)
         ;; 假定if語句的測試表達式的結果也是放在%eax寄存器中的，因此只須要拿%eax寄存器中的值跟0作比較便可（相似於C語言）
         (let ((label-else (intern (symbol-name (gensym)) :keyword))
               (label-end (intern (symbol-name (gensym)) :keyword)))
           (append (jjcc2 (second expr) globals)
                   `((cmpl $0 %eax)
                     (je ,label-else))
                   (jjcc2 (third expr) globals)
                   `((jmp ,label-end)
                     ,label-else)
                   (jjcc2 (fourth expr) globals)
                   `(,label-end))))
        ((member (first expr) '(_exit exit))
         ;; 暫時以硬編碼的方式識別一個函數是否來自於C語言的標準庫
         `((movl ,(get-operand expr 0) %edi)
           ;; 據這篇回答（https://stackoverflow.com/questions/12678230/how-to-print-argv0-in-nasm）所說，在macOS上調用C語言函數，須要將棧對齊到16位
           ;; 僞裝要對齊的是棧頂地址。由於棧頂地址是往低地址增加的，因此只須要將地址的低16位抹掉就能夠了
           (and ,(format nil "$0x~X" #XFFFFFFFFFFFFFFF0) %rsp)
           (call :|_exit|)))
        ((eq (first expr) 'return)
         ;; 因爲通過inside-out的處理以後，return的參數就是一個「原子」了，所以再也不須要調用jjcc2來處理一遍
         `((movl ,(get-operand expr 0) %eax)
           (ret)))
        (t
         ;; 按照這裏（https://www3.nd.edu/~dthain/courses/cse40243/fall2015/intel-intro.html）所給的函數調用約定來傳遞參數
         (let ((instructions '())
               (registers '(%rdi %rsi %rdx %rcx %r8 %r9)))
           (dotimes (i (length (rest expr)))
             (if (nth i registers)
                 (push `(movq ,(get-operand expr i) ,(nth i registers)) instructions)
                 (push `(pushq ,(get-operand expr i)) instructions)))
           ;; 通過一番嘗試後，我發現必須在完成函數調用後恢復RSP寄存器纔不會致使段錯誤
           `(,@(nreverse instructions)
             (pushq %rsp)
             (and ,(format nil "$0x~X" #XFFFFFFFFFFFFFFF0) %rsp)
             (call ,(first expr))
             (popq %rsp))))))

如今，就不須要老是依靠exit函數來退出了。下列的代碼可使用RET指令從_main函數中返回

(fb '(return (+ 1 2)))

生成的彙編代碼以下

.data
G565: .long 0
        .section __TEXT,__text,regular,pure_instructions
        .globl _main
_main:
        MOVL $1, %EAX
        MOVL $2, %EBX
        ADDL %EBX, %EAX
        MOVL %EAX, G565(%RIP)
        MOVL G565(%RIP), %EAX
        RET

全文完。

閱讀原文