SVN每日定時備份腳本

SVN每日定時備份腳本：

 

@ECHO off
REM SVN安裝目錄
SET SVN_HOME="D:\Program Files\VisualSVNServer"
REM 版本庫根目錄
SET REPOSITORY_ROOT=D:\Repositories
REM 備份根目錄
SET BACK_HOME=E:\svnbak
REM 備份目錄
SET BACK_DIRECTORY=%BACK_HOME%\%DATE:~0,10%
SET BACK_LOG=%BACK_HOME%\backup.log

 

set DaysAgo=2
call :DateToDays %date:~0,4% %date:~5,2% %date:~8,2% PassDays
set /a PassDays-=%DaysAgo%
call :DaysToDate %PassDays% DstYear DstMonth DstDay
set DstDate=%DstYear%-%DstMonth%-%DstDay%

SET DEL_BACK_DIRECTORY=%BACK_HOME%\%DstDate%

 

IF EXIST %BACK_DIRECTORY% (
ECHO "備份目錄%BACK_DIRECTORY%已存在！請清空。"
GOTO END 
)

ECHO "刪除備份目錄%DEL_BACK_DIRECTORY%"

RD /q /s %DEL_BACK_DIRECTORY%"

ECHO "建立備份目錄%BACK_DIRECTORY%" >> %BACK_LOG%
MD %BACK_DIRECTORY%
REM 遍歷版本庫目錄，備份每一個倉庫
FOR /R %REPOSITORY_ROOT% %%I IN (.) DO (
　　IF EXIST "%%I\conf\svnserve.conf" (
　　　　ECHO "正在備份版本庫%%~fI"
%SVN_HOME%\BIN\SVNADMIN hotcopy "%%~fI" %BACK_DIRECTORY%\%%~nI
　　　　ECHO "版本庫%%~fI已備份到%BACK_DIRECTORY%\%%~nI"
)
)
GOTO END

 

 

:DateToDays %yy% %mm% %dd% days
setlocal ENABLEEXTENSIONS
set yy=%1 & set mm=%2 & set dd=%3
if 1%yy% LSS 200 if 1%yy% LSS 170 (set yy=20%yy%) else (set yy=19%yy%)
set /a dd=100%dd%%%100,mm=100%mm%%%100
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2
set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633
endlocal & set %4=%j% & goto :EOF

:DaysToDate %days% yy mm dd
setlocal ENABLEEXTENSIONS
set /a a=%1+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a
set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5
set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10
(if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%)
endlocal & set %2=%yy%& set %3=%mm%&set %4=%dd%& goto :EOF


:END

pause

EXIT