Oracle存儲過程經常使用技巧

時間 2019-11-10

原文原文鏈接

存儲過程的結構是很是簡單的，咱們在這裏除了學習存儲過程的結構外，還會學習編寫存儲過程時相關的一些實用的知識。如：遊標的處理，異常的處理，集合的選擇等等java

1.存儲過程結構程序員

1.1第一個存儲過程sql

create or replace procedure proc1(   
  p_para1 varchar2,   
  p_para2 out varchar2,   
  p_para3 in out varchar2   
)as    
 v_name varchar2(20);   
begin   
  v_name := '素小暖';   
  p_para3 := v_name;   
  dbms_output.put_line('p_para3:'||p_para3);   
end;

上面就是一個最簡單的存儲過程，一個存儲過程大概分爲這麼幾個部分：數據庫

建立語句：create or replace procedure 存儲過程名編程

若是沒有or replace語句，則僅僅是新建一個存儲過程，若是系統存在該存儲過程，則會報錯。create or replace procedure若是系統中沒有此存儲過程就新建一個，若是系統中有此存儲過程則把原來刪除掉，從新建立一個存儲過程。數組

存儲過程名定義：包括存儲過程名和參數列表。參數名和參數類型。參數名不能重複，參數傳遞方式:IN, OUT, IN OUT 安全

IN 表示輸入參數，按值傳遞方式。 app

OUT 表示輸出參數，能夠理解爲按引用傳遞方式。能夠做爲存儲過程的輸出結果，供外部調用者使用。編程語言

IN OUT 便可做輸入參數，也可做輸出參數。函數

參數的數據類型只須要指明類型名便可，不須要指定寬度。

參數的寬度由外部調用者決定。

過程能夠有參數，也能夠沒有參數

變量聲明塊：緊跟着的as (is )關鍵字，能夠理解爲pl/sql的declare關鍵字，用於聲明變量。

變量聲明塊用於聲明該存儲過程須要用到的變量，它的做用域爲該存儲過程。另外這裏聲明的變量必須指定寬度。遵循PL/SQL的變量聲明規範。

過程語句塊：從begin 關鍵字開始爲過程的語句塊。存儲過程的具體邏輯在這裏來實現。
異常處理塊：關鍵字爲exception ，爲處理語句產生的異常。該部分爲可選
結束塊：由end關鍵字結果。

1.2 存儲過程的參數傳遞方式
存儲過程的參數傳遞有三種方式:IN,OUT,IN OUT .
IN 按值傳遞，而且它不容許在存儲過程當中被從新賦值。若是存儲過程的參數沒有指定存參數傳遞類型，默認爲IN

create or replace procedure proc1(   
  p_para1 varchar2,   
  p_para2 out varchar2,   
  p_para3 in out varchar2   
)as    
 v_name varchar2(20);   
begin   
  p_para1 :='aaa';   
  p_para2 :='bbb';   
  v_name := '素小暖';   
  p_para3 := v_name;   
  dbms_output.put_line('p_para3:'||p_para3);   
  null;   
end;

OUT 參數：做爲輸出參數，須要注意，當一個參數被指定爲OUT類型時，就算在調用存儲過程以前對該參數進行了賦值，在存儲過程當中該參數的值仍然是null.

INOUT 是真正的按引用傳遞參數。便可做爲傳入參數也能夠做爲傳出參數。

對於IN參數，其寬度是由外部決定。
對於OUT 和IN OUT 參數，其寬度是由存儲過程內部決定。

1.3 參數的默認值
存儲過程的參數能夠設置默認值

create or replace procedure procdefault(p1 varchar2,   
                                        p2 varchar2 default 'mark')   
as    
begin   
  dbms_output.put_line(p2);   
end;

能夠經過default 關鍵字爲存儲過程的參數指定默認值。在對存儲過程調用時，就能夠省略默認值。
須要注意的是：默認值僅僅支持IN傳輸類型的參數。OUT 和 IN OUT不能指定默認值

2. 存儲過程內部塊
2.1 內部塊
咱們知道了存儲過程的結構，語句塊由begin開始，以end結束。這些塊是能夠嵌套。在語句塊中能夠嵌套任何如下的塊。

Declare … begin … exception … end;   
create or replace procedure innerBlock(p1 varchar2)   
as    
  o1 varchar2(10) := 'out1';   
begin   
  dbms_output.put_line(o1);   
  declare    
    inner1 varchar2(20);   
  begin   
    inner1 :='inner1';   
    dbms_output.put_line(inner1);   
  
    declare    
      inner2 varchar2(20);   
    begin   
      inner2 := 'inner2';   
      dbms_output.put_line(inner2);   
    end;   
  exception    
    when others then   
      null;   
  end;   
end;

須要注意變量的做用域。

3.存儲過程的經常使用技巧
3.1 哪一種集合?
咱們在使用存儲過程的時候常常須要處理記錄集，也就是多條數據記錄。分爲單列多行和多列多行，這些類型均可以稱爲集合類型。咱們在這裏進行比較這些集合類型，以便於在編程時作出正確的選擇。
索引表,也稱爲pl/sql表，不能存儲於數據庫中，元素的個數沒有限制,下標能夠爲負值。

type t_table is table of varchar2(20) index by binary_integer;   
 v_student t_table;

varchar2(20)表示存放元素的數據類型，binary_integer表示元素下標的數據類型。
嵌套表，索引表沒有 index by子句就是嵌套表，它能夠存放於數據中，元素個數無限，下標從1開始，而且須要初始化

type t_nestTable is table of varchar2(20);   
v_class t_nestTable ;

僅是這樣聲明是不能使用的，必須對嵌套表進行初始化，對嵌套表進行初始化可使用它的構造函數

v_class :=t_nestTable('a','b','c');

變長數組，變長數組與高級語言的數組類型很是類似，下標以1開始，元素個數有限。

type t_array is varray (20) of varchar2(20);

varray(20)就定義了變長數組的最大元素個數是20個
變長數組與嵌套表同樣，也能夠是數據表列的數據類型。
同時，變長數組的使用也須要事先初始化

因而可知，若是僅僅是在存儲過程當中看成集合變量使用，索引表是最好的選擇。

3.2 選用何種遊標?

顯示遊標分爲：普通遊標，參數化遊標和遊標變量三種。
下面以一個過程來進行說明

create or replace procedure proccursor(p varchar2)   
as    
v_rownum number(10) := 1;   
cursor c_postype is select pos_type from pos_type_tbl where rownum =1;   
cursor c_postype1 is select pos_type from pos_type_tbl where rownum = v_rownum;   
cursor c_postype2(p_rownum number) is select pos_type from pos_type_tbl where rownum = p_rownum;   
type t_postype is ref cursor ;   
c_postype3 t_postype;   
v_postype varchar2(20);   
begin   
  open c_postype;   
  fetch c_postype into v_postype;   
  dbms_output.put_line(v_postype);   
  close c_postype;   
  open c_postype1;   
  fetch c_postype1 into v_postype;   
  dbms_output.put_line(v_postype);   
  close c_postype1;   
  open c_postype2(1);   
  fetch c_postype2 into v_postype;   
  dbms_output.put_line(v_postype);   
  close c_postype2;   
  open c_postype3 for select pos_type from pos_type_tbl where rownum =1;   
  fetch c_postype3 into v_postype;   
  dbms_output.put_line(v_postype);   
  close c_postype3;   
end;

cursor c_postype is select pos_type from pos_type_tbl where rownum =1
這一句是定義了一個最普通的遊標，把整個查詢已經寫死,調用時不能夠做任何改變。

cursor c_postype1 is select pos_type from pos_type_tbl where rownum = v_rownum;
這一句並無寫死，查詢參數由變量v_rownum來決定。須要注意的是v_rownum必須在這個遊標定義以前聲明。

cursor c_postype2(p_rownum number) is select pos_type from pos_type_tbl where rownum = p_rownum;
這一條語句與第二條做用類似，都是能夠爲遊標實現動態的查詢。可是它進一步的縮小了參數的做用域範圍。可是可讀性下降了很多。

type t_postype is ref cursor ;
c_postype3 t_postype;
先定義了一個引用遊標類型，而後再聲明瞭一個遊標變量。
open c_postype3 for select pos_type from pos_type_tbl where rownum =1;
而後再用open for 來打開一個查詢。須要注意的是它能夠屢次使用,用來打開不一樣的查詢。
從動態性來講，遊標變量是最好用的，可是閱讀性也是最差的。
注意，遊標的定義只能用使關鍵字IS，它與AS不通用。

3.3 遊標循環最佳策略
咱們在進行PL/SQL編程時，常常須要循環讀取結果集的數據。進行逐行處理，這個過程就須要對遊標進行循環。對遊標進行循環的方法有多種，咱們在此一一分析。

create or replace procedure proccycle(p varchar2)   
as    
cursor c_postype is select pos_type, description from pos_type_tbl where rownum < 6;   
v_postype varchar2(20);   
v_description varchar2(50);   
begin   
open c_postype;   
  if c_postype%found then   
    dbms_output.put_line('found true');   
  elsif c_postype%found = false then   
    dbms_output.put_line('found false');   
  else  
    dbms_output.put_line('found null');   
  end if;   
  loop   
   fetch c_postype into v_postype,v_description ;   
   exit when c_postype%notfound;   
   dbms_output.put_line('postype:'||v_postype||',description:'||v_description);   
  end loop;   
  close c_postype;   
dbms_output.put_line('---loop end---');   
  open c_postype;   
    fetch c_postype into v_postype,v_description;   
    while c_postype%found loop   
      dbms_output.put_line('postype:'||v_postype||',description:'||v_description);   
      fetch c_postype into v_postype,v_description ;   
    end loop;   
  
  close c_postype;   
dbms_output.put_line('---while end---');   
  for v_pos in c_postype loop   
    v_postype := v_pos.pos_type;   
    v_description := v_pos.description;   
    dbms_output.put_line('postype:'||v_postype||',description:'||v_description);   
  end loop;   
  dbms_output.put_line('---for end---');   
end;

使用遊標以前須要開打遊標,open cursor，循環完後再關閉遊標close cursor.
這是使用遊標應該慎記於心的法則。
上面的過程演示了遊標循環的三種方法。
在討論循環方法以前，咱們先看看%found和%notfound這些遊標的屬性。

open c_postype;   
 if c_postype%found then   
   dbms_output.put_line('found true');   
 elsif c_postype%found = false then   
   dbms_output.put_line('found false');   
 else  
   dbms_output.put_line('found null');   
 end if;

在打開一個遊標以後，立刻檢查它的%found或%notfound屬性，它獲得的結果即不是true也不是false.而是null.必須執行一條fetch語句後，這些屬性纔有值。

第一種使用loop 循環

loop   
   fetch c_postype into v_postype,v_description ;   
   exit when c_postype%notfound;   
   ……   
end loop

這裏須要注意，exit when語句必定要緊跟在fetch以後。必避免多餘的數據處理。
處理邏輯須要跟在exit when以後。這一點須要多加當心。
循環結束後要記得關閉遊標。

第二種使用while循環。

fetch c_postype into v_postype,v_description;   
while c_postype%found loop   
   ……   
      fetch c_postype into v_postype,v_description ;   
end loop;

咱們知道了一個遊標打開後，必須執行一次fetch語句，遊標的屬性纔會起做用。因此使用while 循環時，就須要在循環以前進行一次fetch動做。
並且數據處理動做必須放在循環體內的fetch方法以前。循環體內的fetch方法要放在最後。不然就會多處理一次。這一點也要很是的當心。
總之，使用while來循環處理遊標是最複雜的方法。

第三種 for循環

for v_pos in c_postype loop   
   v_postype := v_pos.pos_type;   
   v_description := v_pos.description;   
   …   
 end loop;

可見for循環是比較簡單實用的方法。
首先，它會自動open和close遊標。解決了你忘記打開或關閉遊標的煩惱。
其它,自動定義了一個記錄類型及聲明該類型的變量，並自動fetch數據到這個變量中。
咱們須要注意v_pos 這個變量無須要在循環外進行聲明，無須要爲其指定數據類型。
它應該是一個記錄類型，具體的結構是由遊標決定的。
這個變量的做用域僅僅是在循環體內。
把v_pos看做一個記錄變量就能夠了，若是要得到某一個值就像調用記錄同樣就能夠了。
如v_pos.pos_type
因而可知，for循環是用來循環遊標的最好方法。高效，簡潔，安全。
但遺憾的是，經常見到的倒是第一種方法。因此從今以後得改變這個習慣了。
3.4 select into不可乎視的問題

咱們知道在pl/sql中要想從數據表中向變量賦值，須要使用select into 子句。
可是它會帶動來一些問題，若是查詢沒有記錄時，會拋出no_data_found異常。
若是有多條記錄時，會拋出too_many_rows異常。
這個是比較糟糕的。一旦拋出了異常，就會讓過程當中斷。特別是no_data_found這種異常，沒有嚴重到要讓程序中斷的地步，能夠徹底交給由程序進行處理。

create or replace procedure procexception(p varchar2)   
as    
  v_postype varchar2(20);   
begin   
   select pos_type into v_postype from pos_type_tbl where 1=0;   
    dbms_output.put_line(v_postype);   
end;

執行這個過程

SQL> exec procexception('a');   
報錯   
ORA-01403: no data found   
ORA-06512: at "LIFEMAN.PROCEXCEPTION", line 6  
ORA-06512: at line 1

處理這個有三個辦法
1．直接加上異常處理。

create or replace procedure procexception(p varchar2)   
as    
  v_postype varchar2(20);   
     
begin   
   select pos_type into v_postype from pos_type_tbl where 1=0;   
    dbms_output.put_line(v_postype);   
exception    
  when no_data_found then   
    dbms_output.put_line('沒找到數據');   
end;

這樣作換湯不換藥，程序仍然被中斷。可能這樣不是咱們所想要的。
2. select into作爲一個獨立的塊，在這個塊中進行異常處理

create or replace procedure procexception(p varchar2)   
as    
  v_postype varchar2(20);   
     
begin   
  begin   
   select pos_type into v_postype from pos_type_tbl where 1=0;   
    dbms_output.put_line(v_postype);   
 exception    
  when no_data_found then   
    v_postype := '';   
  end;   
  dbms_output.put_line(v_postype);   
end;

這是一種比較好的處理方式了。不會由於這個異常而引發程序中斷。

3.使用遊標

create or replace procedure procexception(p varchar2)   
as    
  v_postype varchar2(20);   
  cursor c_postype is select pos_type  from pos_type_tbl where 1=0;   
begin   
  open c_postype;   
    fetch c_postype into v_postype;   
  close c_postype;   
  dbms_output.put_line(v_postype);   
end;

這樣就徹底的避免了no_data_found異常。徹底交由程序員來進行控制了。

第二種狀況是too_many_rows 異常的問題。
Too_many_rows 這個問題比起no_data_found要複雜一些。
給一個變量賦值時，可是查詢結果有多個記錄。
處理這種問題也有兩種狀況：

1．多條數據是能夠接受的，也就是說從結果集中隨便取一個值就行。這種狀況應該很極端了吧，若是出現這種狀況，也說明了程序的嚴謹性存在問題。
2．多條數據是不能夠被接受的，在這種狀況確定是程序的邏輯出了問題，也說是說原來根本就不會想到它會產生多條記錄。
對於第一種狀況，就必須採用遊標來處理，而對於第二種狀況就必須使用內部塊來處理，從新拋出異常。
多條數據能夠接受,隨便取一條，這個跟no_data_found的處理方式同樣，使用遊標。
我這裏僅說第二種狀況，不可接受多條數據，可是不要忘了處理no_data_found哦。這就不能使用遊標了，必須使用內部塊。

create or replace procedure procexception2(p varchar2)   
as    
  v_postype varchar2(20);   
    
begin   
  begin   
    select pos_type into v_postype from pos_type_tbl where rownum < 5;   
  exception   
    when no_data_found then   
      v_postype :=null;   
    when too_many_rows then   
      raise_application_error(-20000,'對v_postype賦值時，找到多條數據');   
  end;   
 dbms_output.put_line(v_postype);   
end;

須要注意的是必定要加上對no_data_found的處理，對出現多條記錄的狀況則繼續拋出異常，讓上一層來處理。
總之對於select into的語句須要注意這兩種狀況了。須要穩當處理啊。

3.5 在存儲過程當中返回結果集
咱們使用存儲過程都是返回值都是單一的，有時咱們須要從過程當中返回一個集合。即多條數據。這有幾種解決方案。比較簡單的作法是寫臨時表，可是這種作法不靈活。並且維護麻煩。咱們可使用嵌套表來實現.沒有一個集合類型可以與java的jdbc類型匹配。這就是對象與關係數據庫的阻抗吧。數據庫的對象並不可以徹底轉換爲編程語言的對象，還必須使用關係數據庫的處理方式。

create or replace package procpkg is   
   type refcursor is ref cursor;   
   procedure procrefcursor(p varchar2, p_ref_postypeList  out refcursor);   
end procpkg;   
  
create or replace package body procpkg is   
  procedure procrefcursor(p varchar2, p_ref_postypeList out  refcursor)   
  is   
    v_posTypeList PosTypeTable;   
  begin   
    v_posTypeList :=PosTypeTable();--初始化嵌套表   
    v_posTypeList.extend;   
    v_posTypeList(1) := PosType('A001','客戶資料變動');   
    v_posTypeList.extend;   
    v_posTypeList(2) := PosType('A002','團體資料變動');   
    v_posTypeList.extend;   
    v_posTypeList(3) := PosType('A003','受益人變動');   
    v_posTypeList.extend;   
    v_posTypeList(4) := PosType('A004','續期交費方式變動');   
    open p_ref_postypeList for  select * from table(cast (v_posTypeList as PosTypeTable));   
  end;   
end procpkg;

在包頭中定義了一個遊標變量,並把它做爲存儲過程的參數類型。
在存儲過程當中定義了一個嵌套表變量，對數據寫進嵌套表中，而後把嵌套表進行類型轉換爲table,遊標變量從這個嵌套表中進行查詢。外部程序調用這個遊標。
因此這個過程須要定義兩個類型。

create or replace type PosType as Object (   
  posType varchar2(20),   
  description varchar2(50)   
);

create or replace type PosTypeTable is table of PosType;
須要注意，這兩個類型不能定義在包頭中，必須單獨定義，這樣java層才能使用。

在外部經過pl/sql來調用這個過程很是簡單。

set serveroutput on;   
declare    
  type refcursor is refcursor;   
  v_ref_postype ref cursor;   
  v_postype varchar2(20);   
  v_desc varchar2(50);   
begin   
  procpkg.procrefcursor('a',v_ref_postype);   
  loop   
    fetch  v_ref_postype into v_postype,v_desc;   
    exit when v_ref_postype%notfound;   
    dbms_output.put_line('posType:'|| v_postype || ';description:' || v_desc);   
  end loop;   
end;

注意：對於遊標變量，不能使用for循環來處理。由於for循環會隱式的執行open動做。而經過open for來打開的遊標%isopen是爲true的。也就是默認打開的。Open一個已經open的遊標是錯誤的。因此不能使用for循環來處理遊標變量。

create or replace package procpkg is   
   type refcursor is ref cursor;   
   procedure procrefcursor(p varchar2, p_ref_postypeList  out refcursor);   
   function procpostype(p varchar2) return PosTypeTable;    
end procpkg;   
  
create or replace package body procpkg is   
  procedure procrefcursor(p varchar2, p_ref_postypeList out  refcursor)   
  is   
    v_posTypeList PosTypeTable;   
  begin   
    v_posTypeList :=PosTypeTable();--初始化嵌套表   
    v_posTypeList.extend;   
    v_posTypeList(1) := PosType('A001','客戶資料變動');   
    v_posTypeList.extend;   
    v_posTypeList(2) := PosType('A002','團體資料變動');   
    v_posTypeList.extend;   
    v_posTypeList(3) := PosType('A003','受益人變動');   
    v_posTypeList.extend;   
    v_posTypeList(4) := PosType('A004','續期交費方式變動');   
    open p_ref_postypeList for  select * from table(cast (v_posTypeList as PosTypeTable));   
  end;   
  
  function procpostype(p varchar2) return PosTypeTable   
  as   
   v_posTypeList PosTypeTable;   
  begin   
      v_posTypeList :=PosTypeTable();--初始化嵌套表   
    v_posTypeList.extend;   
    v_posTypeList(1) := PosType('A001','客戶資料變動');   
    v_posTypeList.extend;   
    v_posTypeList(2) := PosType('A002','團體資料變動');   
    v_posTypeList.extend;   
    v_posTypeList(3) := PosType('A003','受益人變動');   
    v_posTypeList.extend;   
    v_posTypeList(4) := PosType('A004','續期交費方式變動');   
    return  v_posTypeList;   
  end;   
end procpkg;

咱們主要討論的是如何經過jdbc調用來處理這個輸出參數。

conn = this.getDataSource().getConnection();   
CallableStatement call = conn.prepareCall("{call procpkg.procrefcursor(?,?)}");   
call.setString(1, null);   
call.registerOutParameter(2, OracleTypes.CURSOR);   
call.execute();   
ResultSet rsResult = (ResultSet) call.getObject(2);   
while (rsResult.next()) {   
  String posType = rsResult.getString("posType");   
  String description = rsResult.getString("description");   
  ......   
}

這就是jdbc的處理方法。

Ibatis處理方法：
1.參數配置

<parameterMap id="PosTypeMAP" class="java.util.Map">    
 <parameter property="p" jdbcType="VARCHAR" javaType="java.lang.String" />    
 <parameter property="p_ref_postypeList" jdbcType="ORACLECURSOR" javaType="java.sql.ResultSet" mode="OUT" typeHandler="com.palic.elis.pos.dayprocset.integration.dao.impl.CursorHandlerCallBack" />    
</parameterMap>   
  
2.調用過程   
  <procedure id ="procrefcursor" parameterMap ="PosTypeMAP">   
      {call procpkg.procrefcursor(?,?)}   
  </procedure>   
  
3.定義本身的處理器   
  public class CursorHandlerCallBack implements TypeHandler{   
    public Object getResult(CallableStatement cs, int index) throws SQLException {   
        ResultSet rs = (ResultSet)cs.getObject(index);   
        List result = new ArrayList();   
        while(rs.next()) {   
            String postype =rs.getString(1);   
            String description = rs.getString(2);   
            CodeTableItemDTO posTypeItem = new CodeTableItemDTO();   
            posTypeItem.setCode(postype);   
            posTypeItem.setDescription(description);   
            result.add(posTypeItem);   
        }   
        return result;   
    }   
  
  
  
4. dao方法   
    public List procPostype() {   
        String p = "";   
        Map para = new HashMap();   
        para.put("p",p);   
        para.put("p_ref_postypeList",null);   
         this.getSqlMapClientTemplate().queryForList("pos_dayprocset.procrefcursor",  para);   
         return (List)para.get("p_ref_postypeList");   
    }

這個跟jdbc的方式很是的類似.
咱們使用的是ibatis的2.0版本，比較麻煩。
若是是使用2.2以上版本就很是簡單的。
由於能夠在parameterMap中定義一個resultMap.這樣就無須要本身定義處理器了。
能夠從分析2.0和2.0的dtd文件知道。
上面的兩種方式都是很是的複雜，若是僅僅是須要返回一個結果集，那就徹底可使用函數來實現了。

create or replace package procpkg is   
   type refcursor is ref cursor;   
   procedure procrefcursor(p varchar2, p_ref_postypeList  out refcursor);   
   function procpostype(p varchar2) return PosTypeTable;    
end procpkg;   
  
create or replace package body procpkg is   
  procedure procrefcursor(p varchar2, p_ref_postypeList out  refcursor)   
  is   
    v_posTypeList PosTypeTable;   
  begin   
    v_posTypeList :=PosTypeTable();--初始化嵌套表   
    v_posTypeList.extend;   
    v_posTypeList(1) := PosType('A001','客戶資料變動');   
    v_posTypeList.extend;   
    v_posTypeList(2) := PosType('A002','團體資料變動');   
    v_posTypeList.extend;   
    v_posTypeList(3) := PosType('A003','受益人變動');   
    v_posTypeList.extend;   
    v_posTypeList(4) := PosType('A004','續期交費方式變動');   
    open p_ref_postypeList for  select * from table(cast (v_posTypeList as PosTypeTable));   
  end;   
  
  function procpostype(p varchar2) return PosTypeTable   
  as   
   v_posTypeList PosTypeTable;   
  begin   
      v_posTypeList :=PosTypeTable();--初始化嵌套表   
    v_posTypeList.extend;   
    v_posTypeList(1) := PosType('A001','客戶資料變動');   
    v_posTypeList.extend;   
    v_posTypeList(2) := PosType('A002','團體資料變動');   
    v_posTypeList.extend;   
    v_posTypeList(3) := PosType('A003','受益人變動');   
    v_posTypeList.extend;   
    v_posTypeList(4) := PosType('A004','續期交費方式變動');   
    return  v_posTypeList;   
  end;   
end procpkg;

ibatis配置

<resultMap id="posTypeResultMap" class="com.palic.elis.pos.common.dto.CodeTableItemDTO">   
   <result property="code" column="posType"/>   
   <result property="description" column="description"/>   
 </resultMap>   
  
  <select id="procPostype" resultMap="posTypeResultMap">   
    select * from table(cast (procpkg.procpostype(#value#) as PosTypeTable))   
  </select>

Dao的寫法跟普通查詢同樣

public List queryPostype() {   
  return this.getSqlMapClientTemplate().queryForList("pos_dayprocset.procPostype", null);   
}

有幾點須要注意，這裏不能使用索引表，而是嵌套表。另外就是把嵌套表強制轉換爲普通表。

相關標籤/搜索

每日一句

每一个你不满意的现在，都有一个你没有努力的曾经。