發佈一鍵式打包腳本工具

只需在項目文件中 包含一段代碼便可在編譯完成時 自動打包程序的依賴庫。(文末源碼地址)

使用方法

• 方法一：複製本腳本代碼到你的項目文件(.pro)中。
• 方法二：在項目文件pro中包含腳本文件便可。

原理實現

• 根據qmake的QT變量獲取對應模塊，在打包時候將會有選擇地打包。
• 打包前將會掃描本地的qml文件，找出須要打包的依賴庫(插件)。
• 經過qmake獲取Qt官方提供的打包工具所在路徑並調用實現程序的打包工做。
• 因爲qmake中獲取Qt官方打包工具所在路徑很方便，不用手動設置路徑，使用上會更方便。
• 經過qmake的參數判斷還能夠設置打包工具(windeployqt.exe)的參數命令。

附加功能

  有關功能使用在腳本工具中有詳細描述。

• 因爲QtCreator原始附帶多個debug與release配置變量，這樣會致使qmake很慢，本腳本工具能夠優化qmake運行速度，但默認不開啓，由於它是實驗性功能。
• 調試輸出宏，默認不開啓。
• 打包完成後自動打開目標目錄，默認開啓。

後續更新

• 目前僅支持windows平臺，後續將會支持更多的平臺。
• 針對第三方庫打包的功能。
• 優化模塊有選擇地打包的功能。
• 優化QML打包的功能。
• 優化打包缺庫的問題。

部分源碼

# 獲取從QMake執行文件的所在目錄得出Qt的bin路徑
QT_BIN_DIR = $$replace(QMAKE_QMAKE, ^(\S*/)\S+$, \1)
# 獲取Qt開發環境路徑
QT_DIR = $${QT_BIN_DIR}../

# Qt打包工具參數配置集合
DEPLOY_OPTIONS += --force

# 可用的Qt模塊
QT_AVAILABLE_LIBRARY_LIST = \
    bluetooth concurrent core declarative designer designercomponents enginio \
    gamepad gui qthelp multimedia multimediawidgets multimediaquick network nfc \
    opengl positioning printsupport qml qmltooling quick quickparticles quickwidgets \
    script scripttools sensors serialport sql svg test webkit webkitwidgets \
    websockets widgets winextras xml xmlpatterns webenginecore webengine \
    webenginewidgets 3dcore 3drenderer 3dquick 3dquickrenderer 3dinput 3danimation \
    3dextras geoservices webchannel texttospeech serialbus webview

# 掃描QT變量用於打包模塊的參數配置
for (LIBRARY_MODULE, QT_AVAILABLE_LIBRARY_LIST) {
    if (contains(QT, $$LIBRARY_MODULE)) {
        DEPLOY_OPTIONS += --$$LIBRARY_MODULE
    }
    else {
        DEPLOY_OPTIONS += --no-$$LIBRARY_MODULE
    }
}

# 針對Qml模塊配置打包參數
if (contains(QT, quick)) {
    DEPLOY_OPTIONS -= --no-qml
    DEPLOY_OPTIONS += --qml

    DEPLOY_OPTIONS -= --no-network
    DEPLOY_OPTIONS += --network

    DEPLOY_OPTIONS += --qmldir $${QT_DIR}qml/
}

if (!isEmpty(DESTDIR)) {
    # 若有設置目標輸出路徑則定向於該路徑
    TARGET_OUT_DIR = $$OUT_PWD/$$DESTDIR/
}
else {
    # 判斷是debug版本仍是release版本
    CONFIG(debug, debug|release) {
        TARGET_OUT_DIR = $${OUT_PWD}/debug/
        DEPLOY_OPTIONS += --debug
    }
    else {
        TARGET_OUT_DIR = $${OUT_PWD}/release/
        DEPLOY_OPTIONS += --release
    }
}

# 實驗性功能
!isEmpty(EXPERIMENTAL) {
    # 該功能(用於優化qmake調試輸出)是否開放還需待定，由於會致使其餘未知的問題。
    CONFIG = $$remove_extra_config_parameter($$CONFIG)
}

# 調試輸出
!isEmpty(DEBUG_LOGGER) {
    message(TARGET_OUT_DIR: $$TARGET_OUT_DIR) # 生成文件的輸出目錄
    message(QMAKE_POST_LINK: $$QMAKE_POST_LINK) # 打印命令
}

win32 {
    # 拼接Qt部署程序的文件(windows平臺下爲windeployqt.exe)
    WIN_DEPLOY_BIN = $${QT_BIN_DIR}windeployqt.exe

    # 編譯完成後執行打包命令
    QMAKE_POST_LINK += $$WIN_DEPLOY_BIN $$DEPLOY_OPTIONS $$TARGET_OUT_DIR$${TARGET}.exe

    # 掃描Qml依賴庫，並在編譯完成後自動複製qml依賴庫到目標目錄
    QMAKE_POST_LINK += $$get_copy_qml_library_cmd_line($$QT_DIR, $$QT_BIN_DIR, $$TARGET_OUT_DIR, $$RESOURCES)

    !isEmpty(DEPLOY_COMPLETE_AUTO_OPEN_EXPLORER) {
        # 打包完成後自動打開目標路徑
        QMAKE_POST_LINK += && start $$TARGET_OUT_DIR
    }
}

源碼地址

  歡迎你們一塊兒協做完善。
https://github.com/aeagean/De...