iOS H2緩存層替換方案 ---- LevelDB落地實踐

爲何要重構？

h2這邊的緩存層問題詬病不少。很早以前就想總體規劃一下。

目前的主要問題有如下幾點：

1. 主要存儲使用plist文件存儲
   1. 存儲和讀取的相應速度都慢
   2. 若是沒有文件，須要提早建立文件，徒增性能消耗
   3. 存儲數據容易破解。plist能夠直接打開
   4. 存儲數據沒有任何壓縮，徒增緩存文件大小
2. 輕量級存儲主要使用了NSUserDefaults
   1. 實質也是plist文件
   2. 若是須要實時存儲數據，須要手動調用同步
   3. 都存在於一個文件中，存的越多，讀取更新寫入的成本越大
   4. 容易濫用，形成沒必要要的浪費
3. 還有以前前輩封裝的基於sqlite的數據庫

結合H2主要的業務。幾乎都是輕量級存儲，只有個別的計劃詳情，課程詳情，首頁數據相對多一些，而且存的場景多一下。因此一直想利用一個NoSQL，替換現有方案。在再三斟酌以後，決定使用LevelDB。

相比於以前的方案，LevelDB主要優勢有如下幾個方面：

1. 高可靠。避免數據存儲失敗的狀況
2. 順序寫。寫速度大大提升
3. k-v存儲。API簡單方便
4. 數據壓縮。減少存儲量，減少APP的數據大小
5. 比文件存儲方式，數據相對不可見
6. 刪除操做再也不是文件式的覆蓋寫入，或者刪除文件自己，而是直接處理數據，提高性能

總而言之，總體性能提升了100倍左右。對於卡頓，使用內存，啓動耗時都有相應的提高。

層級劃分

而我在接入的過程當中，使用了兩層結構，即一層業務數據格式化，一層數據庫操做。主要緣由以下：

1. 方便替換以前的plist存儲
2. 方便後續替換底層數據庫，固定上層的業務API
3. 存儲在LevelDB是NSData，上層業務能夠傳入NSDictionary，NSArray，NSString，NSNumber的基礎數據，而不能直接傳入一個對象，目的是提升數據格式化的效率。因此在上層進行數據格式化。

具體實現

首先，咱們來看一下LevelDB的封裝。

LevelDB.h

#import <Foundation/Foundation.h>

@interface LevelDB : NSObject

+ (instancetype)share;

- (void)set:(NSString *)key value:(id)value;
- (id)get:(NSString *)key;
- (void)del:(NSString *)key;

@end
複製代碼

對上層提供增/改，刪，查的基礎API。

LevelDB.m

#import "LevelDB.h"

#include "db.h"
#include "status.h"
#include "options.h"
#include "slice.h"

#define SliceFromString(_string_) (Slice((char *)[_string_ UTF8String], [_string_ lengthOfBytesUsingEncoding:NSUTF8StringEncoding]))
#define StringFromSlice(_slice_) ([[NSString alloc] initWithBytes:_slice_.data() length:_slice_.size() encoding:NSUTF8StringEncoding])

static leveldb::DB *db;
static leveldb::Options options;

using namespace leveldb;
static Slice SliceFromObject(id object) {
    NSData *data = nil;
    if ([object isKindOfClass:[NSArray class]]
        || [object isKindOfClass:[NSDictionary class]]) {
        @try {
            NSError *error;
            data = [NSJSONSerialization dataWithJSONObject:object options:NSJSONWritingPrettyPrinted error:&error];
        } @catch(NSException * exception) {
            NSLog(@"%@", exception);
        }
    } else if ([object isKindOfClass:[NSString class]]) {
        data = [object dataUsingEncoding:NSUTF8StringEncoding];
    } else if ([object isKindOfClass:[NSNumber class]]) {
        data = [[NSString stringWithFormat:@"%@", object] dataUsingEncoding:NSUTF8StringEncoding];
    }
    return Slice((const char *)[data bytes], (size_t)[data length]);
}

static id ObjectFromSlice(Slice v) {
    NSData *data = [NSData dataWithBytes:v.data() length:v.size()];
    NSError *error;
    id object = [NSJSONSerialization JSONObjectWithData:data options:NSJSONReadingAllowFragments error:&error];
    if (!object) {
        object = [[NSString alloc]initWithData:data encoding:NSUTF8StringEncoding];
    }
    return object;
}

@implementation LevelDB

+ (instancetype)share {
    static LevelDB *dbManger = nil;
    static dispatch_once_t onceToken;
    dispatch_once(&onceToken, ^{
        dbManger = [[LevelDB alloc]init];
        NSArray *directoryPaths = NSSearchPathForDirectoriesInDomains(NSDocumentDirectory, NSUserDomainMask, YES);
        NSString *documentDirectory = [directoryPaths objectAtIndex:0];
        NSString *file = [documentDirectory stringByAppendingPathComponent:@"storage.ldb"];
        options.create_if_missing = true;
        leveldb::Status status = leveldb::DB::Open(options, [file UTF8String], &db);
        if (!status.ok()) {
        }
        NSLog(@"Problem creating LevelDB database: %s", status.ToString().c_str());
    });
    return dbManger;
}

- (void)set:(NSString *)key value:(id)value {
    if (!value) {
        [self del:key];
        return;
    }
    leveldb::Status status = db->Put(leveldb::WriteOptions(), SliceFromString(key), SliceFromObject(value));
    if (!status.ok()) {
        NSString *errorMessage = [NSString stringWithCString:(status.ToString().c_str()) encoding:[NSString defaultCStringEncoding]];
        NSLog(@"levelDB存儲失敗:%@\nreson:%@\n", key, errorMessage);
    }
}

- (id)get:(NSString *)key {
    std::string strValue;
    leveldb::Status status = db->Get(leveldb::ReadOptions(), SliceFromString(key), &strValue);

    if (!(status.ok())) {
        NSString *errorMessage = [NSString stringWithCString:(status.ToString().c_str()) encoding:[NSString defaultCStringEncoding]];
        NSLog(@"levelDB獲取失敗:%@\nreson:%@\n",key,errorMessage);
        return nil;
    }
    return ObjectFromSlice(strValue);
}

- (void)del:(NSString *)key {
    std::string strValue;
    leveldb::Status status = db->Delete(leveldb::WriteOptions(), SliceFromString(key));
    if (!status.ok()) {
        NSString *errorMessage = [NSString stringWithCString:(status.ToString().c_str()) encoding:[NSString defaultCStringEncoding]];
        NSLog(@"levelDB刪除失敗:%@\nreson:%@\n",key,errorMessage);
    }
}

@end

複製代碼

其中，SliceFromObject方法和ObjectFromSlice，能夠將OC數據和LevelDB須要的存儲數據互相轉化。

以前，嘗試過 解檔歸檔 的方式來格式化數據，好處是能夠傳入任意對象來進行存儲，可是問題在於，效率過低，數據量增大的狀況下，甚至比文件存儲的效率更低，瓶頸主要在 歸檔 這裏。

因此，最後肯定爲只進行NSString，NSNumber，NSArray，NSDictionary的基礎數據處理，使用Json進行數據轉化，效率明顯提高。不過，我想，這部分還有更多的優化控件，還在思考中。

YGCacheHandler提供業務方封裝。這裏提供一個例子，其餘再也不贅述：

+ (YGUser *)user {
    NSDictionary *userInfo = [[LevelDB share]get:@"YGUser"];
    if (!userInfo) {
        NSString *path = [[YGCacheHandler rootDirectoryPath] stringByAppendingPathComponent:@"YGUser.plist"];
        userInfo = [NSDictionary dictionaryWithContentsOfFile:path];
        if (!userInfo || 0 == userInfo.allKeys.count) {
            return nil;
        }
    }
    YGUser *user = [YGUser yy_modelWithDictionary:userInfo];
    return user;
}

+ (void)updateUser:(YGUser *)user {
    NSDictionary *userInfo = [user yy_modelToJSONObject];
    [[LevelDB share]set:@"YGUser" value:userInfo];
}
複製代碼

其中，讀取方法，須要注意要兼容以前版本plist文件存儲的數據。

而，寫入方法中，須要將YGUser的model轉爲基礎數據，再直接寫入到LevelDB。

能夠看出，代碼量少了不少，更加清爽簡單。

最後，祝你們玩得開心啦！