Delphi中使用ISuperObject解析Json數據

　　Java、Php等語言中都有成熟的框架來解析Json數據，能夠讓咱們使用不多的代碼就把格式化好的json數據轉換成程序可識別的對象或者屬性，同時delphi中也有這樣的組件來實現此功能，即IsuperObject。若是尚未這個組件的請在網上搜索下載或者在下面留言處留下你的郵箱向本人索取。

　　下面先說一下ISuperObject中幾個經常使用的函數

• function SO(const s: SOString = ‘{}’): ISuperObject; overload; 此函數傳入json數據字符串，並返回一個ISuperObject對象，這通常是咱們解析json時使用的第一個函數，如jObj := SO(jsonstr)。
• property O[const path: SOString]: ISuperObject read GetO write PutO; default; 如：jobj.O[‘username’]，此函數被一個ISuperObject對象調用，方括號內的字符串爲json中的字段名稱，返回一個ISuperObject對象。
• property S[const path: SOString]: SOString read GetS write PutS; 此函數被一個ISuperObject對象調用，和O[‘username’]不一樣的是，它返回的是一個SoString，即一個字符串，使用方法 str := jObj.S[‘username’]; 同理的還有其餘幾個相似的函數，如I[‘age’]返回整數，B[‘isenable’]返回布爾型，A[‘users’]返回一個TSuperArray數組
• AsString, AsBoolean, AsInteger,AsArray，ISuperObject的函數，用來把ISuperObject轉換成相應的數據類型。

　　下面咱們看一個演示代碼，json數據以下

 

{
    "retcode": "1", 
    "datafrom": "server",
    "users": "[{\"id\":1, \"username\": \"liuderu\", \"website\": \"bcoder.com\"},{\"id\":2, \"username\": \"Jeoe\", \"website\": \"baidu.com\"}]"
}

Delphi版本2010，代碼以下：

unit uFmMain;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ComCtrls, Buttons, superobject;

type
  TFmMain = class(TForm)
    Memo1: TMemo;
    ListView1: TListView;
    BitBtn1: TBitBtn;
    Label1: TLabel;
    procedure BitBtn1Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  FmMain: TFmMain;

implementation

{$R *.dfm}

procedure TFmMain.BitBtn1Click(Sender: TObject);
var
  jRet, jUsers: ISuperObject;
  aryUsers: TSuperArray;
  retCode: integer;
  strUsers: string;
  i: integer;
begin
  jRet := SO(Memo1.Text);
  if (jRet.O['retcode'] <> nil) then begin
    retCode := jRet.O['retcode'].AsInteger;
    Label1.Caption := '返回值：' + IntToStr(retCode) + ';  數據來源：' + jRet.O['datafrom'].AsString;

    if(jRet.O['retcode'].AsInteger = 1) then begin
      strUsers := jRet.O['users'].AsString;
      jUsers := SO(strUsers);
      aryUsers := jUsers.AsArray;
      for I := 0 to aryUsers.Length - 1 do begin
        with  ListView1.Items.Add do begin
          Caption := aryUsers[i].O['id'].AsString;
          SubItems.Add(aryUsers[i].O['username'].AsString);
          SubItems.Add(aryUsers[i].O['website'].AsString);
        end;
      end;
    end;
  end;
end;

end.

 

原文地址： http://bcoder.com/delphi/parse-json-data-in-delphi-by-using-isuperobject