使用觸發器實現記錄oracle用戶登陸失敗信息到alert.log日誌文件

前面咱們說了用oracle自帶的審計功能能夠實現記錄用戶登陸失敗日誌到數據表中（連接：http://www.54ok.cn/6778.html）。今天咱們來分享一下如何把用戶登陸失敗信息記錄到alert.log日誌文件中。

 

使用sys帳號登陸數據庫，而後建立觸發器。

 

CREATE OR REPLACE TRIGGER logon_denied_to_alert
  AFTER servererror ON DATABASE
DECLARE
  message   VARCHAR2(168);
  ip        VARCHAR2(15);
  v_os_user VARCHAR2(80);
  v_module  VARCHAR2(50);
  v_action  VARCHAR2(50);
  v_pid     VARCHAR2(10);
  v_sid     NUMBER;
  v_program VARCHAR2(48);
BEGIN
  IF (ora_is_servererror(1017)) THEN

    -- get ip FOR remote connections :
    IF upper(sys_context('userenv', 'network_protocol')) = 'TCP' THEN
      ip := sys_context('userenv', 'ip_address');
    END IF;

    SELECT sid INTO v_sid FROM sys.v_$mystat WHERE rownum < 2;
    SELECT p.spid, v.program
      INTO v_pid, v_program
      FROM v$process p, v$session v
     WHERE p.addr = v.paddr
       AND v.sid = v_sid;

    v_os_user := sys_context('userenv', 'os_user');
    dbms_application_info.read_module(v_module, v_action);

    message := to_char(SYSDATE, 'YYYYMMDD HH24MISS') ||
               ' logon denied from ' || nvl(ip, 'localhost') || ' ' ||
               v_pid || ' ' || v_os_user || ' with ' || v_program || ' – ' ||
               v_module || ' ' || v_action;

    sys.dbms_system.ksdwrt(2, message);

  END IF;
END;

 

嘗試使用錯誤的帳號密碼登陸數據庫，而後在alert.log日誌中就能夠查到信息，可是這個日誌信息比較簡單，只記錄了時間，ip和使用的客戶端工具，並無記錄登陸的帳號是多少。所以對比起審計功能來講稍微差點。