SQL Server 進制轉換函數

1、背景

　　前段時間羣裏的朋友問了一個問題：「在查詢時增長一個遞增序列，如：0x00000001，即每個都是36進位(0—9，A--Z)，0x0000000Z後面將是0x00000010，生成一個像下面的映射表「：

（Figure1：效果圖）

 

2、十進制轉換爲十六進制

在網上有不少資料關於使用SQL語句把十進制轉換爲十六進制的資料，好比：

--方式1
SELECT CONVERT(VARBINARY(50), 23785)

　　執行返回值爲0x00005CE9，可是須要注意的是，這本應該返回二進制的，可是二進制估計是閱讀起來太麻煩，因此SQL Server 返回了十六進制，若是你想要保存爲字符串並非簡單把這直接使用CONVERT，相似下面的SQL是不會有返回值的：

SELECT CONVERT(VARCHAR,CONVERT(VARBINARY(50), 23785))

因此網上出現了以下的函數來轉換爲十六進制的字符串：

--方式2
CREATE FUNCTION Binary2HexStr(@bin VARBINARY(8000))
RETURNS VARCHAR(8000)
AS
BEGIN
    DECLARE @re VARCHAR(8000),@i INT
    SELECT @re='',@i=datalength(@bin)
    WHILE @i>0
        SELECT @re=substring('0123456789ABCDEF',substring(@bin,@i,1)/16+1,1)
                +substring('0123456789ABCDEF',substring(@bin,@i,1)%16+1,1)
                +@re
            ,@i=@i-1
    RETURN('0x'+@re)
END
GO

--測試
SELECT dbo.Binary2HexStr(23785)

　　上面的SQL一樣返回0x00005CE9，可是此次返回的是字符串了，貌似問題都得以解決了，可是，只要你INT值不超過2147483648，這個問題就會出現了，執行下面的SQL返回的結果如Figure2所示：

SELECT dbo.Binary2HexStr(2147483647)
SELECT dbo.Binary2HexStr(2147483648)

（Figure2：數據對比）

從進制的轉換運算出發，改進了宋沄劍寫了的SQL腳本，修改參數爲BIGINT類型：

--方式3
CREATE FUNCTION BigInt2HexStr(@value BIGINT)
RETURNS VARCHAR(50)
AS
BEGIN
    DECLARE @seq CHAR(16)
    DECLARE @result VARCHAR(50)
    DECLARE @digit CHAR(1)
    
    SET @seq = '0123456789ABCDEF'
    --求十進制的@value除以的餘數,找到餘數對應十六進制的值
    SET @result = SUBSTRING(@seq, (@value%16)+1, 1)

    WHILE @value > 0
    BEGIN
        SET @digit = SUBSTRING(@seq, ((@value/16)%16)+1, 1)
        SET @value = @value/16
        IF @value <> 0
            SET @result = @digit + @result
    END

    RETURN @result
END
GO

--測試
SELECT dbo.BigInt2HexStr(2147483647)
SELECT dbo.BigInt2HexStr(2147483648)

執行上面的SQL，返回的十六進制如Figure3所示：

（Figure3：數據對比）

　　要想理解上面的函數，你須要理解十進制轉換爲十六進制的運算規則，假如十進制數23785轉爲十六進制，計算的公式的步驟爲：

1. 23785/16=1486餘9，十進制的9對應十六進制的9；
2. 1486/16=92餘14，十進制的14對應十六進制的E；
3. 92/16=5餘12，十進制的12對應十六進制的C；
4. 5/16=0餘5，十進制的5對應十六進制的5；

將餘數對應的十六進制倒寫，即5CE9，因此十進制23785 = 十六進制0x5CE9

 

3、十進制轉換爲三十六進制

　　經過上面的例子修改下就能支持十進制到三十六進制的轉換了：

--十進制轉換爲十六進制
CREATE FUNCTION BigIntTo36HexStr(@value BIGINT)
RETURNS VARCHAR(50)
AS
BEGIN
    DECLARE @seq CHAR(36)
    DECLARE @result VARCHAR(50)
    DECLARE @digit CHAR(1)
    
    SET @seq = '0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZ'
    SET @result = SUBSTRING(@seq, (@value%36)+1, 1)

    WHILE @value > 0
    BEGIN
        SET @digit = SUBSTRING(@seq, ((@value/36)%36)+1, 1)
        SET @value = @value/36
        IF @value <> 0 
            SET @result = @digit + @result
    END 

    RETURN @result
END
GO

--測試
SELECT dbo.BigIntTo36HexStr(35)

執行上面的測試SQL，返回0xZ，測試成功；

 

4、補充說明

　　其實編寫Binary2HexStr函數是沒有必要的，由於SQL Server提供系統的函數支持轉換master.dbo.fn_varbintohexstr或者master.dbo.fn_varbintohexsubstring，例如：

SELECT master.dbo.fn_varbintohexstr(2147483647)
SELECT master.dbo.fn_varbintohexsubstring(1,2147483647,1,0)

不過他們同樣存在對十進制數據的轉換不能超過2147483648的限制。

 

5、參考文獻

SqlServer中varbinary轉換成字符串

關於遞增序列的問題

進制轉換

SQL之36進制轉換成10進制數據

SQL Server 中，實現 varbinary 與 varchar 類型之間的數據轉換

SQL Server: convert varbinary to varchar