幾種常見SQL分頁方式效率比較

 分頁很重要，面試會遇到。不妨再回顧總結一下：

 

一：建立測試環境，(插入100萬條數據大概耗時5分鐘)。

create database DBTest
use DBTest

 二：--建立測試表

create table pagetest
(
id int identity(1,1) not null,
col01 int null,
col02 nvarchar(50) null,
col03 datetime null
)

三 --1萬記錄集

declare @i int
set @i=0
while(@i<10000)
begin
    insert into pagetest select cast(floor(rand()*10000) as int),left(newid(),10),getdate()
    set @i=@i+1
end

 四：.幾種典型的分頁sql，下面例子是每頁50條，198*50=9900，取第199頁數據。

--寫法1，not in/top
select top 50 * from pagetest 
where id not in (select top 9900 id from pagetest order by id)
order by id




--寫法2，not exists
select top 50 * from pagetest 
where not exists 
(select 1 from (select top 9900 id from pagetest order by id)a  where a.id=pagetest.id)
order by id

--寫法3，max/top
select top 50 * from pagetest
where id>(select max(id) from (select top 9900 id from pagetest order by id)a)
order by id

--寫法4，row_number()
select top 50 * from 
(select row_number()over(order by id)rownumber,* from pagetest)a
where rownumber>9900

select * from 
(select row_number()over(order by id)rownumber,* from pagetest)a
where rownumber>9900 and rownumber<9951

select * from 
(select row_number()over(order by id)rownumber,* from pagetest)a
where rownumber between 9901 and 9950

--寫法5，在csdn上一帖子看到的，row_number() 變體，不基於已有字段產生記錄序號，先按條件篩選以及排好序，再在結果集上給一常量列用於產生記錄序號
select *
from (
    select row_number()over(order by tempColumn)rownumber,*
    from (select top 9950 tempColumn=0,* from pagetest where 1=1 order by id)a
)b
where rownumber>9900
 

 

四：分別在1萬，10萬(取1990頁)，100(取19900頁）記錄集下測試。

測試sql:

declare @begin_date datetime
declare @end_date datetime
select @begin_date = getdate()

<.....YOUR CODE.....>

select @end_date = getdate()
select datediff(ms,@begin_date,@end_date) as '毫秒'
 

 

1萬：基本感受不到差別。

10萬：

 

100萬：

 

五：結論：

1.max/top,ROW_NUMBER()都是比較不錯的分頁方法。相比ROW_NUMBER()只支持sql2005及以上版本，max/top有更好的可移植性，能同時適用於sql2000,access。

2.not exists感受是要比not in效率高一點點。

3.ROW_NUMBER()的3種不一樣寫法效率看起來差很少。

4.ROW_NUMBER() 的變體基於我這個測試效率實在很差。

 

PS.上面的分頁排序都是基於自增字段id。測試環境還提供了int,nvarchar,datetime類型字段，也能夠試試。不過對於非主鍵沒索引的大數據量排序效率應該是很不理想的。

六：簡單將ROWNUMBER,max/top的方式封裝到存儲過程。

ROWNUMBER():

create proc [dbo].[spSqlPageByRownumber]
@tbName varchar(255),        --表名
@tbFields varchar(1000),      --返回字段
@PageSize int,                --頁尺寸
@PageIndex int,                --頁碼
@strWhere varchar(1000),    --查詢條件
@StrOrder varchar(255),  --排序條件
@Total int output            --返回總記錄數
as
declare @strSql varchar(5000)    --主語句
declare @strSqlCount nvarchar(500)--查詢記錄總數主語句

--------------總記錄數---------------
if @strWhere !=''
begin
set @strSqlCount='Select @TotalCout=count(*) from  ' + @tbName + ' where '+ @strWhere
end
else
begin
set @strSqlCount='Select @TotalCout=count(*) from  ' + @tbName
end
--------------分頁------------
if @PageIndex <= 0
begin
  set @PageIndex = 1
end

set @strSql='Select * from (Select  row_number() over('+@strOrder+') rowId,'+ @tbFields
+' from ' + @tbName + ' where 1=1 ' + @strWhere+' ) tb where tb.rowId >'+str((@PageIndex-1)*@PageSize)
+' and tb.rowId <= ' +str(@PageIndex*@PageSize)

exec sp_executesql @strSqlCount,N'@TotalCout int output',@Total output
exec(@strSql)

 

Max/top:(簡單寫了下，須要知足主鍵字段名稱就是"id")

create proc [dbo].[spSqlPageByMaxTop]
@tbName varchar(255),        --表名
@tbFields varchar(1000),      --返回字段
@PageSize int,                --頁尺寸
@PageIndex int,                --頁碼
@strWhere varchar(1000),    --查詢條件
@StrOrder varchar(255),  --排序條件
@Total int output            --返回總記錄數
as
declare @strSql varchar(5000)    --主語句
declare @strSqlCount nvarchar(500)--查詢記錄總數主語句

--------------總記錄數---------------
if @strWhere !=''
begin
set @strSqlCount='Select @TotalCout=count(*) from  ' + @tbName + ' where '+ @strWhere
end
else
begin
set @strSqlCount='Select @TotalCout=count(*) from  ' + @tbName
end
--------------分頁------------
if @PageIndex <= 0
begin
  set @PageIndex = 1
end

set @strSql='select top '+str(@PageSize)+' * from ' + @tbName + '
where id>(select max(id) from (select top '+str((@PageIndex-1)*@PageSize)+' id from ' + @tbName + ''+@strOrder+')a)
'+@strOrder+''

exec sp_executesql @strSqlCount,N'@TotalCout int output',@Total output
exec(@strSql)

 

調用：

declare @count int
--exec [dbo].[spSqlPageByRownumber]'pagetest','*',50,20,'','order by id asc',@count output 
exec [dbo].[spSqlPageByMaxTop]'pagetest','*',50,20,'','order by id asc',@count output 
select @count