PowerDesigner輔助導入導出excel文件

時間 2019-11-17

標籤 powerdesigner 輔助導入導出 excel 文件欄目 Power Designer 简体版

原文原文鏈接

在數據庫建模中會用到Powerdesigner軟件進行表結構的設計，有時候咱們須要將Excel裏面的表結構導入到Powerdesigner中生成模型文件，或者將Powerdesigner中已有的模型導出生成Excel文檔；咱們能夠經過Powerdesigner的腳本定製功能，來實現Excel的導入導出。javascript

　　Excel導入Powerdesigner生成模型的vbscript腳本：html

'******************************************************************************
'開始
Option Explicit
Dim tab_name,tab_code,tab_comment
Dim b_r, e_r, s_r, j, m, n
Dim mdl ' the current model
dim count
Dim HaveExcel
Dim RQ
Dim file_name,WScript
Set mdl = ActiveModel
If (mdl Is Nothing) Then
   MsgBox "There is no Active Model"
End If
RQ = vbYes 'MsgBox("Is Excel Installed on your machine ?", vbYesNo + vbInformation, "Confirmation")
If RQ = vbYes Then
   HaveExcel = True
   ' Open & Create Excel Document
Else
   HaveExcel = False
End If
file_name = selectFile() 
if file_name <> "" then
   Dim x1  '
   Set x1 = CreateObject("Excel.Application")
   x1.Workbooks.Open file_name    '指定excel文檔路徑
   x1.Workbooks(1).Worksheets("表結構").Activate   '指定要打開的sheet名稱
j = 1
do while n < 11
if x1.Workbooks(1).Worksheets("表結構").cells(j,1).value <> "" then
call a(x1, mdl, j, getRow(x1, j))
'msgbox j & "--" & getRow(x1, j)
count = count + 1
j = getRow(x1, j)
n = 0
end if
j = j + 1
n = n + 1
loop
'MsgBox "生成數據表結構共計 " + CStr(count), vbOK + vbInformation, "表 導入完畢!"
MsgBox "生成數據表結構共計 " & CStr(count) & " 表導入完畢!"
x1.Workbooks(1).close
x1.quit
else
msgbox "沒有選擇文件!"
end if

sub a(x1, mdl, r_0,r_9)
dim rwIndex   
dim tableName
dim colname
dim table
dim col

tab_name = ucase(x1.Workbooks(1).Worksheets("表結構").cells(r_0,1).value)    '指定表名，若是在Excel文檔裏有，也能夠 .Cells(rwIndex, 3).Value 這樣指定
tab_code = ucase(x1.Workbooks(1).Worksheets("表結構").cells(r_0,2).value)  '指定表名
tab_comment = ucase(x1.Workbooks(1).Worksheets("表結構").cells(r_0,3).value)

on error Resume Next
set table = mdl.Tables.CreateNew '建立一個表實體
table.Name = tab_name
table.Code = tab_code
table.Comment = tab_comment

For rwIndex = r_0 + 2 To r_9   '指定要遍歷的Excel行標  因爲第1行是表頭，從第2行開始
        With x1.Workbooks(1).Worksheets("表結構")
            If .Cells(rwIndex, 2).Value = "" Then
               Exit For
            End If
               set col = table.Columns.CreateNew   '建立一列/字段
               'MsgBox .Cells(rwIndex, 1).Value, vbOK + vbInformation, "列"
               If .Cells(rwIndex, 1).Value = "" Then
                  col.Name = ucase(.Cells(rwIndex, 2).Value)   '指定列名
               Else 
                  col.Name = ucase(.Cells(rwIndex, 1).Value)
               End If
               'MsgBox col.Name, vbOK + vbInformation, "列"
               col.Code = ucase(.Cells(rwIndex, 2).Value)   '指定列名
               
               col.DataType = ucase(.Cells(rwIndex, 3).Value)   '指定列數據類型
               
               col.Comment = ucase(.Cells(rwIndex, 4).Value)  '指定列說明
               
               If ucase(.Cells(rwIndex, 5).Value) = "Y" Then
                   col.Primary = true    '指定主鍵
                   col.defaultvalue = ucase(.Cells(rwIndex,7).value)
               End If 
               If ucase(.Cells(rwIndex,6).value) = "Y" then
                   col.defaultvalue = ucase(.Cells(rwIndex,7).value)
                   col.Mandatory = true                
               End If
               
        End With
Next
End sub

Function getRow(x1, s_r)
dim i, k
k = s_r
do while x1.Workbooks(1).Worksheets("表結構").cells(k,1).value <> ""
k = k + 1
if x1.Workbooks(1).Worksheets("表結構").cells(k,1).value = "" then
getRow = k - 1
exit function
end if
loop
End Function
Function SelectFile()
    Dim shell : Set shell = CreateObject("WScript.Shell")
    Dim fso : Set fso = CreateObject("Scripting.FileSystemObject")
    Dim tempFolder : Set tempFolder = fso.GetSpecialFolder(2)
    Dim tempName : tempName = fso.GetTempName()
    Dim tempFile : Set tempFile = tempFolder.CreateTextFile(tempName & ".hta")
    tempFile.Write _
    "<html>" & _
    "<head>" & _
    "<title>Browse</title>" & _
    "</head>" & _
    "<body>" & _
    "<input type='file' id='f' />" & _
    "<script type='text/javascript'>" & _
    "var f = document.getElementById('f');" & _
    "f.click();" & _
    "var shell = new ActiveXObject('WScript.Shell');" & _
    "shell.RegWrite('HKEY_CURRENT_USER\\Volatile Environment\\MsgResp', f.value);" & _
    "window.close();" & _
    "</script>" & _
    "</body>" & _
    "</html>"
    tempFile.Close
    shell.Run tempFolder & "\" & tempName & ".hta", 0, True
    SelectFile = shell.RegRead("HKEY_CURRENT_USER\Volatile Environment\MsgResp")
    shell.RegDelete "HKEY_CURRENT_USER\Volatile Environment\MsgResp"
End Function

Powerdesigner模型生成Excel文檔的vbscript腳本：java

'******************************************************************************
Option Explicit
   Dim rowsNum
   rowsNum = 0
'-----------------------------------------------------------------------------
' Main function
'-----------------------------------------------------------------------------
' Get the current active model
    Dim Model
    Set Model = ActiveModel
    If (Model Is Nothing) Or (Not Model.IsKindOf(PdPDM.cls_Model)) Then
       MsgBox "The current model is not an PDM model."
    Else
      ' Get the tables collection
      '建立EXCEL APP
      dim beginrow
      DIM EXCEL, SHEET, SHEETLIST
      set EXCEL = CREATEOBJECT("Excel.Application")
      EXCEL.workbooks.add(-4167)'添加工做表
      EXCEL.workbooks(1).sheets(1).name ="表結構"
      set SHEET = EXCEL.workbooks(1).sheets("表結構")
      
      EXCEL.workbooks(1).sheets.add
      EXCEL.workbooks(1).sheets(1).name ="目錄"
      set SHEETLIST = EXCEL.workbooks(1).sheets("目錄")
      ShowTableList Model,SHEETLIST

      ShowProperties Model, SHEET,SHEETLIST
      
      
      EXCEL.workbooks(1).Sheets(2).Select
      EXCEL.visible = true
      '設置列寬和自動換行
      sheet.Columns(1).ColumnWidth = 20 
      sheet.Columns(2).ColumnWidth = 20 
      sheet.Columns(3).ColumnWidth = 20 
      sheet.Columns(4).ColumnWidth = 40 
      sheet.Columns(5).ColumnWidth = 10 
      sheet.Columns(6).ColumnWidth = 10 
      sheet.Columns(1).WrapText =true
      sheet.Columns(2).WrapText =true
      sheet.Columns(4).WrapText =true
      '不顯示網格線
      EXCEL.ActiveWindow.DisplayGridlines = False
      
      
 End If
'-----------------------------------------------------------------------------
' Show properties of tables
'-----------------------------------------------------------------------------
Sub ShowProperties(mdl, sheet,SheetList)
   ' Show tables of the current model/package
   rowsNum=0
   beginrow = rowsNum+1
   Dim rowIndex 
   rowIndex=3
   ' For each table
   output "begin"
   Dim tab
   For Each tab In mdl.tables
      ShowTable tab,sheet,rowIndex,sheetList
      rowIndex = rowIndex +1
   Next
   if mdl.tables.count > 0 then
        sheet.Range("A" & beginrow + 1 & ":A" & rowsNum).Rows.Group
   end if
   output "end"
End Sub
'-----------------------------------------------------------------------------
' Show table properties
'-----------------------------------------------------------------------------
Sub ShowTable(tab, sheet,rowIndex,sheetList)
   If IsObject(tab) Then
     Dim rangFlag
     rowsNum = rowsNum + 1
      ' Show properties
      Output "================================"
      sheet.cells(rowsNum, 1) =tab.name
      sheet.cells(rowsNum, 1).HorizontalAlignment=3
      sheet.cells(rowsNum, 2) = tab.code
      'sheet.cells(rowsNum, 5).HorizontalAlignment=3
      'sheet.cells(rowsNum, 6) = ""
      'sheet.cells(rowsNum, 7) = "表說明"
      sheet.cells(rowsNum, 3) = tab.comment
      'sheet.cells(rowsNum, 8).HorizontalAlignment=3
      sheet.Range(sheet.cells(rowsNum, 3),sheet.cells(rowsNum, 7)).Merge
      '設置超連接，從目錄點擊表名去查看錶結構
      '字段中文名    字段英文名    字段類型    註釋    是否主鍵    是否非空    默認值
      sheetList.Hyperlinks.Add sheetList.cells(rowIndex,2), "","表結構"&"!B"&rowsNum
      rowsNum = rowsNum + 1
      sheet.cells(rowsNum, 1) = "字段中文名"
      sheet.cells(rowsNum, 2) = "字段英文名"
      sheet.cells(rowsNum, 3) = "字段類型"
      sheet.cells(rowsNum, 4) = "註釋"
      sheet.cells(rowsNum, 5) = "是否主鍵"
      sheet.cells(rowsNum, 6) = "是否非空"
      sheet.cells(rowsNum, 7) = "默認值"
      '設置邊框
      sheet.Range(sheet.cells(rowsNum-1, 1),sheet.cells(rowsNum, 7)).Borders.LineStyle = "1"
      'sheet.Range(sheet.cells(rowsNum-1, 4),sheet.cells(rowsNum, 9)).Borders.LineStyle = "1"
      '字體爲10號
      sheet.Range(sheet.cells(rowsNum-1, 1),sheet.cells(rowsNum, 7)).Font.Size=10
            Dim col ' running column
            Dim colsNum
            colsNum = 0
      for each col in tab.columns
        rowsNum = rowsNum + 1
        colsNum = colsNum + 1
          sheet.cells(rowsNum, 1) = col.name
        'sheet.cells(rowsNum, 3) = ""
          'sheet.cells(rowsNum, 4) = col.name
          sheet.cells(rowsNum, 2) = col.code
          sheet.cells(rowsNum, 3) = col.datatype
        sheet.cells(rowsNum, 4) = col.comment
          If col.Primary = true Then
        sheet.cells(rowsNum, 5) = "Y" 
        Else
        sheet.cells(rowsNum, 5) = " " 
        End If
        If col.Mandatory = true Then
        sheet.cells(rowsNum, 6) = "Y" 
        Else
        sheet.cells(rowsNum, 6) = " " 
        End If
        sheet.cells(rowsNum, 7) =  col.defaultvalue
      next
      sheet.Range(sheet.cells(rowsNum-colsNum+1,1),sheet.cells(rowsNum,7)).Borders.LineStyle = "3"       
      'sheet.Range(sheet.cells(rowsNum-colsNum+1,4),sheet.cells(rowsNum,9)).Borders.LineStyle = "3"
      sheet.Range(sheet.cells(rowsNum-colsNum+1,1),sheet.cells(rowsNum,7)).Font.Size = 10
      rowsNum = rowsNum + 2
      
      Output "FullDescription: "       + tab.Name
   End If
   
End Sub
'-----------------------------------------------------------------------------
' Show List Of Table
'-----------------------------------------------------------------------------
Sub ShowTableList(mdl, SheetList)
   ' Show tables of the current model/package
   Dim rowsNo
   rowsNo=1
   ' For each table
   output "begin"
   SheetList.cells(rowsNo, 1) = "主題"
   SheetList.cells(rowsNo, 2) = "表中文名"
   SheetList.cells(rowsNo, 3) = "表英文名"
   SheetList.cells(rowsNo, 4) = "表說明"
   rowsNo = rowsNo + 1
   SheetList.cells(rowsNo, 1) = mdl.name
   Dim tab
   For Each tab In mdl.tables
     If IsObject(tab) Then
         rowsNo = rowsNo + 1
      SheetList.cells(rowsNo, 1) = ""
      SheetList.cells(rowsNo, 2) = tab.name
      SheetList.cells(rowsNo, 3) = tab.code
      SheetList.cells(rowsNo, 4) = tab.comment
     End If
   Next
    SheetList.Columns(1).ColumnWidth = 20 
      SheetList.Columns(2).ColumnWidth = 20 
      SheetList.Columns(3).ColumnWidth = 30 
     SheetList.Columns(4).ColumnWidth = 60 
   output "end"
End Sub

使用方式：shell

　　以上兩個腳本分別之後綴名稱爲「.vbs」的方式保存；數據庫