開機bat自動運行多程序

• 先描述業務需求

建一個批處理文件，在打開電腦時啓動所需的三個軟件，每一個程序間隔5S啓動

• 上代碼~~

@echo off 
color 2a

title 多任務工具 BY The Lostman

set firstName=軟件狗
set secondName=APIDC
set thirdName=收銀系統
set file=c:\base.ini

if exist c:\base.ini (
 echo 文件已存在
 goto main
) else (goto init)

:init
echo 執行初始化...
echo 建立文件
echo.>c:\base.ini
pause
goto main


:Main
cls
::if exist c:\base.ini (echo 文件已存在) else (echo 文件不存在)

for /f "tokens=1,* delims==" %%a in (
 'type %file% ^|findstr /i "dirPath"'
) do (
 set dirPath=%%b
)

if defined dirPath (
    echo 已獲取文件保存路徑 %dirPath%
	echo dirPath=%dirPath%>%file%
	goto setPath
) else echo 文件保存路徑不能爲空請從新輸入...
set /p "dirPath=請輸入文件保存路徑，而後按回車..."
pause
goto Main

:setPath
if exist %dirPath%\appPath.ini (goto setValue) else (
 
 echo.
 echo.	===開始設置路徑信息===
 echo.
 goto getPath
)
	
	
:getPath
::獲取程序路徑 
set /p sorftDog=  請將%firstName% 拖入此框獲取路徑 
set /p apidc=  請將%secondName% 拖入此框獲取路徑 
set /p c3=  請將%thirdName% 拖入此框獲取路徑 

echo sorftDog=%sorftDog%>%dirPath%\appPath.ini 
echo apidc=%apidc%>>%dirPath%\appPath.ini 
echo c3=%c3%>>%dirPath%\appPath.ini 
echo.
echo.	====路徑信息已保存====
echo.
start "" %dirPath%\appPath.ini
pause

:setValue
::設置值
setlocal ENABLEDELAYEDEXPANSION
for /f "tokens=1,* delims==" %%a in (
 'type %dirPath%\appPath.ini ^|findstr /i "sorftDog"'
) do (
 set appdog=%%b
)

for /f "tokens=1,* delims==" %%a in (
 'type %dirPath%\appPath.ini ^|findstr /i "apidc"'
) do (
 set appdc=%%b
)

for /f "tokens=1,* delims==" %%a in (
 'type %dirPath%\appPath.ini ^|findstr /i "c3"'
) do (
 set appc3=%%b
)

echo %firstName%路徑是 %appdog%
echo %secondName%路徑是 %appdc%
echo %thirdName%路徑是 %appc3%

::運行
timeout /T 5 /nobreak
echo 啓動%firstName%...
start "" %appdog%

timeout /T 5 /nobreak
echo 啓動%secondName%...
start "" %appdc%

timeout /T 5 /nobreak
echo 啓動%thirdName%...
start "" %appc3%
::退出
timeout /T 3 /nobreak
goto end

:end

分析一下思路：

由於是啓動就要運行軟件，因此我要將三個軟件的路徑記錄在appPath.ini文件裏面調用，只有在第一次運行的時候配置一下便可。可是在調用appPath.ini 時，須要指定文件的絕對路徑，因此有了開頭輸入文件保存路徑的配置。三個軟件的路徑就保存在改路徑下的appPath.ini文件中。

注意：

1. 在xp系統下直接拖拽快捷方式是運行不起來的
2. 若是手動輸入，則須要輸入軟件的絕對路徑並用引號引發來（c:\Progames File\...  這種路徑由於有空格，因此須要引號引發來）推薦你們在xp系統下用下圖的方法直接獲取路徑：
3. 依然是在xp系統下，timeout是不能用的，替換成ping localhost -n 5 便可

 

如何創建開機就執行這個bat呢，不管是window 7 仍是 xp 只要將bat文件拷貝至開始-->全部程序-->啓動 目錄下面便可，快點試試吧

轉載請標明出處：http://my.oschina.net/superzhu/blog/680496