[轉]：Delphi XE中泛型數組的使用範例

Delphi XE中泛型數組的使用範例，下面的範例簡單的使用了泛型字符串數組，如用 TArray 代替 array of Word, 還可使用 TArray 類提供的算法(就是少了點). 

uses Generics.Collections, Generics.Defaults;

{測試 TArray 的 Sort 方法}
procedure TForm1.Button1Click(Sender: TObject);
var
  arr: TArray<string>; //同 array of string
  s: string;
begin
  SetLength(arr, 5);
  arr[0] := 'aaa';
  arr[1] := 'AAA';
  arr[2] := '111';
  arr[3] := '333';
  arr[4] := '222';

  TArray.Sort<string>(arr);
  Memo1.Clear;
  for s in arr do Memo1.Lines.Add(s); //111 222 333 AAA aaa
end;

{測試 TArray 的 BinarySearch 方法}
procedure TForm1.Button2Click(Sender: TObject);
var
  arr: TArray<Integer>; //同 array of Integer
  i,n: Integer;
begin
  SetLength(arr, 5);
  for i := 0 to Length(arr) - 1 do arr[i] := Integer(Sqr(i));
  Memo1.Clear;
  for i := Low(arr) to High(arr) do Memo1.Lines.Add(IntToStr(arr[i]));

  if TArray.BinarySearch<Integer>(arr, 4, n) then ShowMessage(IntToStr(n)); //2, 也就是第三個

  if TArray.BinarySearch<Integer>(arr, 5, n) then ShowMessage(IntToStr(n)); //找不到時, 不能根據 n 的值判斷
end;

{自定義排序器}
procedure TForm1.Button3Click(Sender: TObject);
var
  arr: TArray<Integer>;
  num: Integer;
begin
  SetLength(arr, 5);
  arr[0] := 2;
  arr[1] := 4;
  arr[2] := 3;
  arr[3] := 1;
  arr[4] := 5;

  TArray.Sort<Integer>(arr, TComparer<Integer>.Construct(
    function (const a,b: Integer): Integer
    begin
      Result := b - a;
    end
  ));
  Memo1.Clear;
  for num in arr do Memo1.Lines.Add(IntToStr(num)); //5 4 3 2 1
end;
//該代碼片斷來自於: http://www.sharejs.com/codes/delphi/9000