經過組策略自動給客戶機添加網絡打印機

原創做品，容許轉載，轉載時請務必以超連接形式標明文章 原始出處 、做者信息和本聲明。不然將追究法律責任。 http://coldmail.blog.51cto.com/37442/117880

 

我想每一位IT人士都面臨過這樣的問題，公司新添置了一臺網絡打印機，也就是帶網卡的打印機，客戶機經過安裝驅動便可使用，而無需經過其餘機器共享打印機的限制。若是你面臨着大約100臺左右的客戶機，而須要一臺一臺的安裝怎麼辦，我想這也是一個棘手的問題。下面我教你們一個經過組策略加上VBS腳原本實現客戶機自動添加打印機的方法。

首先介紹一下環境：

1.       公司網絡必須是域環境。

2.       完整的打印機驅動，並拷貝到網絡任意共享的文件夾下，客戶機能夠訪問獲得。

下面咱們一步一步的進行：

第1、   咱們看一下腳本，自動添加打印機的腳本能夠從微軟的網站上找到，這裏我給你們列舉我本身仿照微軟的腳本根據實際狀況而進行修改的文件，而後我着重介紹一下我修改的地方。新建一個.vbs的文件我就不用說了，相比你們都已經熟知。

 

'Install printer port

Set objWMIService = GetObject("winmgmts:")

Set objNewPort = objWMIService.Get _

("Win32_TCPIPPrinterPort").SpawnInstance_

objNewPort.Name = "IP_10.86.229.11"

objNewPort.Protocol = 1

objNewPort.HostAddress = "10.86.229.11"

objNewPort.PortNumber = "9100"

objNewPort.SNMPEnabled = False

objNewPort.Put_

'install printer driver

strComputer = "."

Set objWMIService = GetObject("winmgmts:" & _

"{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")

Set objDriver = objWMIService.Get("Win32_PrinterDriver")

objDriver.Name = "Lexmark T642"

objDriver.SupportedPlatform = "Windows NT x86"

objDriver.Version = "3"

objDriver.FilePath="\\tsnserver\Software、(E)\Drivers\printer\lexmark\644\driver\Drivers\Print\Win_2kXP"

objDriver.InfName="\\tsnserver\Software (E)\Drivers\printer\lexmark\644\driver\Drivers\Print\Win_2kXP\LMAAT2DA.INF"

intResult = objDriver.AddPrinterDriver(objDriver)

'WScript.Echo intResult

'Config printer

strComputer = "."

Set objWMIService = GetObject("winmgmts:" _

& "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")

Set objPrinter = objWMIService.Get("Win32_Printer").SpawnInstance_

objPrinter.DriverName = "Lexmark T642"

objPrinter.PortName = "IP_10.86.229.11"

objPrinter.DeviceID = "TSNLAN11"

objPrinter.Location = "TSNLAN11"

objPrinter.Network = TRUE

objPrinter.Shared = False

objPrinter.ShareName = " "

objPrinter.Put_

'set default printer

strComputer = "."

Set objWMIService = GetObject("winmgmts:" _

    & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")

Set colInstalledPrinters =  objWMIService.ExecQuery _

    ("Select * from Win32_Printer Where Name = 'TSNLAN11'")

For Each objPrinter in colInstalledPrinters

    objPrinter.SetDefaultPrinter()

Next

注意：

1.       標註紅色下劃線的位置是根據咱們的環境進行修改的，如打印機的地址、型號、打印機名字、打印機驅動文件、打印機驅動文件所在的目錄。

2.       帶有‘標註的基本上是註釋部分，不用管它，

3.       其餘語句，若是有興趣能夠研究一下具體的意思！

第2、   將咱們改好的文件保存一下，固然是保存成.vbs的文件，存放在網絡共享盤上面（所欲的域用戶均可以訪問）

第3、   接下來咱們要對服務器進行操做了，首先若是安裝了組策略編輯工具那樣更好，若沒有安裝也不要緊咱們只要找到相應的OU而後右鍵直接對該OU進行組策略編輯，

a)         咱們在組策略編輯器——計算機策略——Windows 設置——開機——開機腳本

b)        點 擊增長，而後輸入咱們須要共享的腳本，這裏建議你們用手輸入的方法，並且使用網絡路徑，由於我曾試過用他裏面提供的增長功能，直接指向個人共享文件夾裏面 的腳本文件，但是都不生效，也試過把共享的腳本文件放在那個特別長的文件夾下面，我所指的是默認提供的路徑，後來客戶端發現沒有訪問權限，因而我就手動輸 入個人網絡路徑，也就是用\\這種方式，後來就能夠了，不知道怎麼回事，若是知道的朋友也能夠告訴我一聲，很是感謝。

第4、   最後就是去客戶端執行gpupdate /force，這是刷新完組策略提示從新啓動，這樣估計下次開機的時候就可使用了，是否是很方便呢？

備 注：因爲時間的緣由，文章寫的很粗略，我想對於組策略你們應該都很是熟悉了，我就很少羅嗦了，腳本部分你們可能有疑問：添加完了，是否是客戶端要更改默認 打印機呢？不用，由於安裝完已是默認的了，最後幾條語句就是設置默認打印機，是否是？好了，就寫到這了，有什麼問題你們給我留言！

本文出自 「點滴成就非凡」 博客，請務必保留此出處http://coldmail.blog.51cto.com/37442/117880