【轉載】Restarting an analysis in ANSYS

原文地址：http://blog.sina.com.cn/s/blog_4b764640010168ru.html

 

這是本身最近作的一個例子,一是爲了感謝okok論壇給與個人很大的幫助,二是起到拋磚引玉的做用.由於我以爲這個技術是頗有用的,特別是對於計算時間特別長的模型,能夠分紅幾段計算,這能夠避免因爲意外中斷等緣由重複之前的計算工做.下面時個人命令流(通過驗證與沒有使用重啓動分析結果徹底一致):
finish
/clear,nostart  !
/config,nres,2000
/CWD,'E:\graduate design\FEM\beam\transient\seismic\restart'
/filnam,restart,1
/title,restart
/PREP7
ET,1,BEAM3
R,1,1,0.83333e-1,1, , , ,
MP,EX,1,200e9
MP,DENS,1,7.8e3
N,1
N,201,200
FILL
E,1,2
EGEN,200,1,1
D,1,UX,,,,,Uy
D,201,Uy
finish
  
/SOLU! Enter SOLUTION
ANTYPE,TRANS! Transient analysis
TRNOPT,FULL! Full method
rescontrol,define,50,last!將第50載荷步的最後一個子載荷步寫入.Rnnn文件
rescontrol,define,100,last!將第100載荷步的最後一個子載荷步寫入.Rnnn文件
!另外默認的還會將最後一個載荷步的最後一個子載荷步寫入.Rnnn文件
!
!從文件中讀取地震波付給數組
*dim,tjwe,,1000,1
*dim,tjns,,1000,1
*dim,tjud,,1000,1
  
*CREATE,ansuitmp
*VREAD,tjwe,'tjwe1D','txt',' ',1, , , , , ,  
(F7.4)
*END
/INPUT,ansuitmp
!*
*CREATE,ansuitmp
*VREAD,tjns,'tjns1D','txt',' ',1, , , , , ,  
(F7.4)
*END
/INPUT,ansuitmp  
!*
*CREATE,ansuitmp
*VREAD,tjud,'tjud1D','txt',' ',1, , , , , ,  
(F7.4)
*END
/INPUT,ansuitmp  
deltt=0.01!測量時間間隔.01s
betad,0.1462
KBC,0
outres,basic,all
parsave,all,parameter!保存參數，這對下面的重分析是必須的，由於這些參數是沒有存入.RDB文件的
*status!列出APDL信息
*do,i,1,500,1
acel,tjwe(i),tjns(i),tjud(i)
time,i*deltt
nsubst,1
solve
*enddo
rescontrol,file_summary
finish
!重啓動分析
/solu
antype,,restart,500,1
parres,,parameter!從新載入參數
*status
rescontrol,define,700,last!將第700載荷步的最後一個子載荷步寫入.Rnnn文件
rescontrol,define,800,last!將第800載荷步的最後一個子載荷步寫入.Rnnn文件
  
*do,i,501,1000,1
acel,tjwe(i),tjns(i),tjud(i)
time,i*deltt
nsubst,1
solve
*enddo
rescontrol,file_summary
finish
  
/post26
NSOL,2,101,U,Y,UY_2
XVAR,1
PLVAR,2
/gropts,view,1!可使圖形可以用鼠標進行縮放

 

ANSYS10的help文檔裏面3.9節「3.9. Restarting an Analysis」講述了大量重啓動的問題，而且還附有大量狀況的lgw，結合LZ的lgw或許能幫讀者解決些實際問題吧