工控隨筆_21_西門子_WinCC的VBS腳本_10_對象_01

　　最近有點小忙，各類事情，心情也不是很好，煩心事特別多，所以最近更新的比較慢。

不敢再鬆懈了，今天正好有點時間，就繼續看了一下VBScript中關於對象的一些內容。

 

1、對象

　　OOP是編程規模發展到必定程度後纔出現的，由於不但操做系統的程序規模愈來愈大，並且應用

程序的規模也是日益增加。

　　代碼重用在OOP出現後又是進一步提高。

　　什麼是對象呢？  按照之前Unix的套路：一切皆文件。  在這裏也能夠說一切皆對象。計算機自己

也能夠看作一個對象。

　　對象具備特徵和功能，特徵表現爲屬性，功能表現爲方法。

　　具體不囉嗦，能夠看看計算機概論一類的書。

 

2、代碼

　　

'對象


'對象的特色
'從本質上來講對象是內存中的一塊內存區域，這塊區域和變量同樣
'可是對象和變量又存在差距。對象必須利用專門的語句進行關聯後才
'能引用，且在使用完畢後必須用專門的語句進行銷燬才能保證佔用的
'內存被回收，不然就會形成「內存泄露」

Option Explicit

'建立對象
Dim objDict
'一、經過CreateObject函數建立對象，這個函數須要傳遞一個必須的參數
'   這個參數指定要建立的對象的類型。 這個參數在系統中叫作
'   progID,  以下面的"Scripting.Dictionary"就是ProgID
'二、經過CreateObject函數建立的對象，只是存儲在內存中，咱們還不能直
'   接進行操做，這個函數會返回一個對象的引用，若是不將這個返回的引用
'   與某個變量聯繫起來就沒法訪問對象。
'三、經過set語句將建立的對象與變量聯繫起來，這個過程也叫實例化對象。
'   以下所示
Set objDict = CreateObject("Scripting.Dictionary")
MsgBox objDict.Count

'四、若是對象使用完畢，那麼必須對其進行撤銷，不然對象佔用的內存就不會
'   回收，這樣就會形成內存泄露，所以必須進行撤銷。經過下面的語句
'   撤銷對象。 固然若是腳本小那麼在腳本結束運行的時候，系統會自動撤銷
'   對象。 這個意思是說對象在超出做用域的範圍後會自動撤銷。
Set objDict =Nothing

If objDict Is Nothing Then 
    MsgBox "對象objDict已經撤銷"
End If


'腳本運行時對象
'腳本運行時對象必須經過其餘對象建立才能訪問。最典型的就是文件系統對象
Dim objFSO
Set objFSO = CreateObject("Scripting.FileSystemObject")

Dim objFolder 
'下面的語句必須已經建立了文件夾：D:\01_vbs， 不然會出錯
Set objFolder = objFSO.GetFolder("D:\01_vbs")

'對象的訪問
'對象具備屬性和方法， 屬性表示對象的一些特徵
'方法用來改變屬性的特徵, 對象的屬性和方法經過下面的語法格式進行訪問
'   對象.屬性
'   對象.方法
MsgBox objFolder.Drive   '訪問建立的objfolder對象的驅動器屬性
MsgBox objFolder.Name    '訪問建立的objfolder對象的名稱屬性
MsgBox objFolder.Path    '訪問建立的objfolder對象的路徑屬性

'訪問對象的方法，經過文件夾對象的CreateTextFile方法建立文件
objFolder.CreateTextFile "對象新建的文件.txt",True,False

'咱們能夠查看文件夾對象下的文件，這個須要經過集合來訪問
'文件夾對象下有一個文件集合，咱們經過傳遞集合下的元素的名稱來訪問集合
'一樣文件也是一個對象，所以也須要進行實例化
'以下所示
Dim objFile 
Set objFile = objFolder.Files("對象新建的文件.txt")

'一樣經過下面的方法訪問對象屬性
MsgBox objFile.Name & "建立的時間爲：" & objFile.DateCreated


'訪問對象的特殊語句 With語句
'由於對象的屬性和方法均具備一個共同的特色：歸屬於同一個對象
'所以爲方便，vbs提供了一種簡便的訪問方法就是
With objFile 
    MsgBox  "Drive is：" & .Drive & vbNewLine &_
            "Path is：" & .Path & vbNewLine 
End With

 

3、WinCC中的對象模型

　　要理解WinCC中的VBS腳本，大致有前面幾篇隨筆的內容和本篇隨筆的內容基本夠用了，須要

補充的是屬於WinCC特有的VBS對象模型。這裏暫時很少說，只用一張圖

　　WinCC中VBS的對象模型。

 

4、小結

　　對於WinCC的VBS腳本，大致須要的關於VBS的基本知識已經描述完畢，其餘的高級功能須要

進一步學習的能夠參考微軟的出版物《vbs腳本參考》

　　從我自己這些年的WinCC的使用經驗來看，前面描述的基本夠用，通常不會用到太複雜的功能。

後面在描述一些關於文件系統對象的知識後就全面的描述WinCC的相關內容。

 

--------------------------------------------------------------分割線---------------------------------------------------------------

一、文章均爲我的原創，歡迎轉載，轉載請保留出處：https://www.cnblogs.com/volcanol/

二、獲取工控PLC、變頻器、HMI、計算機、Windows、Linux、嵌入式資料點擊：獲取資料

三、若是您以爲文章對您有幫助可轉至頁面上半部分打賞，或移步：打賞 

四、或者在頁面右下角點推薦喲！！！

--------------------------------------------------------------分割線---------------------------------------------------------------