IDEA鏈接數據庫生成實體類方法與定製Groovy生成腳本

時間  2020-05-30
標籤 idea 鏈接 數據庫 生成 實體 方法 定製 groovy 腳本 欄目 Eclipse 简体版
原文   原文鏈接

導語: 現在已2019年, 有許許多多的插件或者編輯器都支持根據數據表自動生成數據實體類了, 好比IDEA, 各類MyBatis的代碼生成工具, 等等. 本篇介紹一下如何使用IDEA的groovy腳本文件生成帶JPA註解的實體類java

參考連接: Intellij IDEA 經過數據庫表生成帶註解的實體類詳細步驟-悲涼的秋風mysql

一, 使用IDEA鏈接數據庫

  • 需注意:
    1. 正式版IDEA纔有此功能, 社區版木有
    2. 演示圖片使用的IDEA版本爲2018.3, 不一樣版本界面可能有細小差異
  1. 建立新的數據鏈接
    • (1)若是沒有, 能夠上方菜單欄: 視圖-工具窗口-Database打開
    • 新建Oracle數據庫也是相同操做

  1. 配置數據鏈接
    1. 填寫一個鏈接名，隨便填什麼都行
    2. 不用選擇，默認就行
    3. 填寫數據庫鏈接的 IP地址，好比本地數據庫能夠填寫：localhost或者127.0.0.1
    4. 填寫數據庫開放的端口號，通常沒設置的話默認都是3306
    5. 填寫你須要鏈接的數據庫名
    6. 填寫數據庫的用戶名
    7. 填寫數據庫密碼
    8. 這裏會有一個驅動須要點擊下載，圖中是已經下載好了
    9. 填寫本身的數據庫鏈接url，而後能夠點擊9所在按鈕進行測試鏈接，本地鏈接失敗檢查是否開啓了mysql服務

二, IDEA自帶的兩種建立實體類的方法

(1)若是隻是建立簡單的, 只有屬性, getter, setter的實體類, 而不須要JPA/Hibernate的實體類註解

1. 單擊打開剛剛建立的數據鏈接
2. 打開schemas, 找到本身須要建立實體類的表(可使用ctrl或shift多選)
3. 右鍵: Scripted Extensions - Generate POJOs.groovy
4. 選擇生成路徑就OK了
+ **需注意**
    + 生成的包名可能有問題, 默認是`package com.sample`, 須要本身手動修改

(2)使用了Hibernate/Jpa框架, 須要的是有註解的實體類, Idea也提供了相應的方法

  • -1-添加JPA模塊
    1. 打開項目結構
    2. 打開模塊, 點擊+號添加模塊
    3. 選擇JPA
    4. 點擊右下角肯定後, 關閉項目結構

  • -2-使用Persistence工具生成帶註解的實體類-1sql

    1. 若是上一步沒問題的話, IDEA左下角側邊欄會出現Persistence工具欄
    2. 打開Persistence工具欄, 右鍵項目: Generate Persistence Mapping - By Database Schema

  • -3-使用Persistence工具生成帶註解的實體類-2數據庫

    1. 選擇數據庫鏈接
    2. 選擇生成類所在包
    3. 選擇要生成的表
    4. 選擇要生成的字段(選擇表後字段默認除了外鍵全選)
    5. 修改要生成的屬性名
    6. 修改要生成的屬性類型
    7. 勾上即爲生成帶註解的實體類

    生成的類實例以下 api

三, 更進一步, 使用本身的Groovy生成帶註解的實體類

  1. 上面介紹了兩個使用IDEA生成實體類的方法, 各有優缺點 +生成不帶註解的實體類簡單高效, 但缺點就是若是使用的是Jpa/Hibernate框架就不適合 +生成帶註解的實體類能生成註解實體類, 但缺點就是生成的實體類的註解可能不太符合咱們的註解, 只能生成到當前項目包下, 面對一些複雜的數據庫如Oracle會顯示不少系統表並且表空間切換不太方便
  2. 咱們知道Idea生成不帶註解的實體類是經過Groovy腳本文件生成的, 咱們也能找到這個文件, 那咱們能不能修改這個文件, 讓它生成帶註解的實體類呢?

(1)使用本身的Groovy生成帶註解的實體類的好處

  1. 在Database工具欄裏, 操做簡單方便
  2. 能夠本身對腳本進行一些編輯, 使生成的實體類達到本身的定製需求
  3. 對Oracle這樣的數據庫生成實體類時, 避免了系統表的影響, 能夠本身選擇表空間進行操做
  4. 能夠生成在電腦上的任何位置, 不受限制

(2)使用本身的Groovy生成帶註解的實體類的不足

  1. @author 做者名須要本身修改腳本
  2. @Table(Schema="") 的表空間名不能讀取, 須要本身修改腳本, 設定表空間名(mysql能夠直接刪除這個屬性的定義)(IDEA的Persistence工具能夠讀取(Schema=""屬性並生成, 但咱們不知道它是怎麼獲取的)
  3. @Id的主鍵生成方式不可知, 須要生成後本身肯定(mysql用戶能夠直接修改腳本設定主鍵生成方式, 但Oracle用戶須要生成實體類後再逐個確認)

(3)使用本身的Groovy生成帶註解的實體類能夠繼續完善的地方

1, 若是須要hashcode()和equals()方法, 也修改腳本, 使其自動生成app

(4)新建一個Groovy腳本文件

  1. Database工具欄裏, 右鍵右鍵: Scripted Extensions - Go to Scripts Directory
  2. 在目錄下新建一個Generate MyPOJOs.groovy

  1. 添加里面的內容
    1. //1. 修改idea爲本身名字 的地方能夠修改做者名字爲本身的
    2. //2. schema = \"後面添加本身的表空間名稱(mysql能夠不添加, 不用這個schema屬性也行) 這裏能夠根據提示修改
import com.intellij.database.model.DasTable
import com.intellij.database.model.ObjectKind
import com.intellij.database.util.Case
import com.intellij.database.util.DasUtil

import java.text.SimpleDateFormat

/*
 * Available context bindings:
 *   SELECTION   Iterable<DasObject>
 *   PROJECT     project
 *   FILES       files helper
 */
packageName = ""
typeMapping = [
        (~/(?i)tinyint|smallint|mediumint/)      : "Integer",
        (~/(?i)int/)                             : "Long",
        (~/(?i)bool|bit/)                        : "Boolean",
        (~/(?i)float|double|decimal|real/)       : "Double",
        (~/(?i)datetime|timestamp|date|time/)    : "Date",
        (~/(?i)blob|binary|bfile|clob|raw|image/): "InputStream",
        (~/(?i)/)                                : "String"
]


FILES.chooseDirectoryAndSave("Choose directory", "Choose where to store generated files") { dir ->
    SELECTION.filter { it instanceof DasTable && it.getKind() == ObjectKind.TABLE }.each { generate(it, dir) }
}

def generate(table, dir) {
    def className = javaName(table.getName(), true)
    def fields = calcFields(table)
    packageName = getPackageName(dir)
    PrintWriter printWriter = new PrintWriter(new OutputStreamWriter(new FileOutputStream(new File(dir, className + ".java")), "UTF-8"))
    printWriter.withPrintWriter { out -> generate(out, className, fields, table) }

//    new File(dir, className + ".java").withPrintWriter { out -> generate(out, className, fields,table) }
}

// 獲取包所在文件夾路徑
def getPackageName(dir) {
    return dir.toString().replaceAll("\\\\", ".").replaceAll("/", ".").replaceAll("^.*src(\\.main\\.java\\.)?", "") + ";"
}

def generate(out, className, fields, table) {
    out.println "package $packageName"
    out.println ""
    out.println "import javax.persistence.Column;"
    out.println "import javax.persistence.Entity;"
    out.println "import javax.persistence.Table;"
    out.println "import javax.persistence.Id;"
    out.println "import javax.persistence.GeneratedValue;"
    out.println "import java.io.Serializable;"
    Set types = new HashSet()

    fields.each() {
        types.add(it.type)
    }

    if (types.contains("Date")) {
        out.println "import java.util.Date;"
    }

    if (types.contains("InputStream")) {
        out.println "import java.io.InputStream;"
    }
    out.println ""
    out.println "/**\n" +
            " * @Description  \n" +
            " * @Author  idea\n" + //1. 修改idea爲本身名字
            " * @Date " + new SimpleDateFormat("yyyy-MM-dd").format(new Date()) + " \n" +
            " */"
    out.println ""
    out.println "@Entity"
    out.println "@Table ( name =\"" + table.getName() + "\" , schema = \"\")" //2. schema = \"後面添加本身的表空間名稱(mysql能夠不添加, 不用這個schema屬性也行)
    out.println "public class $className  implements Serializable {"
    out.println ""
    out.println genSerialID()
    fields.each() {
        out.println ""
        // 輸出註釋
        if (isNotEmpty(it.commoent)) {
            out.println "\t/**"
            out.println "\t * ${it.commoent.toString()}"
            out.println "\t */"
        }

        if ((it.annos+"").indexOf("[@Id]") >= 0) out.println "\t@Id"

        if (it.annos != "") out.println "   ${it.annos.replace("[@Id]", "")}"


        // 輸出成員變量
        out.println "\tprivate ${it.type} ${it.name};"
    }

    // 輸出get/set方法
    fields.each() {
        out.println ""
        out.println "\tpublic ${it.type} get${it.name.capitalize()}() {"
        out.println "\t\treturn this.${it.name};"
        out.println "\t}"
        out.println ""

        out.println "\tpublic void set${it.name.capitalize()}(${it.type} ${it.name}) {"
        out.println "\t\tthis.${it.name} = ${it.name};"
        out.println "\t}"
    }

    // 輸出toString方法
    out.println ""
    out.println "\t@Override"
    out.println "\tpublic String toString() {"
    out.println "\t\treturn \"TpApiConfig{\" +"
    fields.each() {
        out.println "\t\t\t\t\"${it.name}='\" + ${it.name} + '\\'' +"
    }
    out.println "\t\t\t\t'}';"
    out.println "\t}"

    out.println ""
    out.println "}"
}

def calcFields(table) {
    DasUtil.getColumns(table).reduce([]) { fields, col ->
        def spec = Case.LOWER.apply(col.getDataType().getSpecification())

        def typeStr = typeMapping.find { p, t -> p.matcher(spec).find() }.value
        def comm = [
                colName : col.getName(),
                name    : javaName(col.getName(), false),
                type    : typeStr,
                commoent: col.getComment(),
                annos   : "\t@Column(name = \"" + col.getName() + "\" )"]
        if ("id".equals(Case.LOWER.apply(col.getName())))
            comm.annos += ["@Id"]
        fields += [comm]
    }
}

// 已經修改成使用javaName, 若是有須要能夠在def className = javaName(table.getName(), true)中修改成javaClassName
// 處理類名（這裏是由於個人表都是以t_命名的，因此須要處理去掉生成類名時的開頭的T，
// 若是你不須要那麼請查找用到了 javaClassName這個方法的地方修改成 javaName 便可）
def javaClassName(str, capitalize) {
    def s = com.intellij.psi.codeStyle.NameUtil.splitNameIntoWords(str)
            .collect { Case.LOWER.apply(it).capitalize() }
            .join("")
            .replaceAll(/[^\p{javaJavaIdentifierPart}[_]]/, "_")
    // 去除開頭的T  http://developer.51cto.com/art/200906/129168.htm
    s = s[1..s.size() - 1]
    capitalize || s.length() == 1 ? s : Case.LOWER.apply(s[0]) + s[1..-1]
}

def javaName(str, capitalize) {
//    def s = str.split(/(?<=[^\p{IsLetter}])/).collect { Case.LOWER.apply(it).capitalize() }
//            .join("").replaceAll(/[^\p{javaJavaIdentifierPart}]/, "_")
//    capitalize || s.length() == 1? s : Case.LOWER.apply(s[0]) + s[1..-1]
    def s = com.intellij.psi.codeStyle.NameUtil.splitNameIntoWords(str)
            .collect { Case.LOWER.apply(it).capitalize() }
            .join("")
            .replaceAll(/[^\p{javaJavaIdentifierPart}[_]]/, "_")
    capitalize || s.length() == 1 ? s : Case.LOWER.apply(s[0]) + s[1..-1]
}

def isNotEmpty(content) {
    return content != null && content.toString().trim().length() > 0
}

static String changeStyle(String str, boolean toCamel) {
    if (!str || str.size() <= 1)
        return str

    if (toCamel) {
        String r = str.toLowerCase().split('_').collect { cc -> Case.LOWER.apply(cc).capitalize() }.join('')
        return r[0].toLowerCase() + r[1..-1]
    } else {
        str = str[0].toLowerCase() + str[1..-1]
        return str.collect { cc -> ((char) cc).isUpperCase() ? '_' + cc.toLowerCase() : cc }.join('')
    }
}

static String genSerialID() {
    return "\tprivate static final long serialVersionUID =  " + Math.abs(new Random().nextLong()) + "L;"
}
  1. 表上右鍵, 選擇本身寫的腳本生成實體類 效果以下:

相關文章
相關標籤/搜索
每日一句
    每一个你不满意的现在，都有一个你没有努力的曾经。
本站公眾號
   歡迎關注本站公眾號,獲取更多信息
聯繫我們 最近搜索 最新文章 沪ICP备13005482号-10 MyBatis教程 SQL 教程 MySQL教程 Java 教程 Thymeleaf 教程 Hibernate教程 Spring教程 Redis教程