如何開發建立ERC20以太坊代幣

看這篇文章須要對以太坊,代幣,ERC20,智能合約等編程開發概念有基本瞭解。

什麼是ERC20

能夠把ERC20簡單理解成以太坊上的代幣協議，全部基於以太坊開發的代幣合約都遵照這個協議。遵照這些協議的代幣咱們能夠認爲是標準化的代幣，而標準化帶來的好處是兼容性好。這些標準化的代幣能夠被各類以太坊錢包支持，用於不一樣的平臺和項目。說白了，你要是想在以太坊上發行代幣融資，必需要遵照ERC20標準。

ERC20的標準接口是這樣的:

contract ERC20 {
      function name() constant returns (string name)
      function symbol() constant returns (string symbol)
      function decimals() constant returns (uint8 decimals)
      function totalSupply() constant returns (uint totalSupply);
      function balanceOf(address _owner) constant returns (uint balance);
      function transfer(address _to, uint _value) returns (bool success);
      function transferFrom(address _from, address _to, uint _value) returns (bool success);
      function approve(address _spender, uint _value) returns (bool success);
      function allowance(address _owner, address _spender) constant returns (uint remaining);
      event Transfer(address indexed _from, address indexed _to, uint _value);
      event Approval(address indexed _owner, address indexed _spender, uint _value);
    }

name

返回ERC20代幣的名字，例如」My test token」。

symbol

返回代幣的簡稱，例如：MTT，這個也是咱們通常在代幣交易所看到的名字。

decimals

返回token使用的小數點後幾位。好比若是設置爲3，就是支持0.001表示。

totalSupply

返回token的總供應量

balanceOf

返回某個地址(帳戶)的帳戶餘額

transfer

從代幣合約的調用者地址上轉移_value的數量token到的地址_to，而且必須觸發Transfer事件。

transferFrom

從地址_from發送數量爲_value的token到地址_to,必須觸發Transfer事件。

transferFrom方法用於容許合同代理某人轉移token。條件是from帳戶必須通過了approve。這個後面會舉例說明。

approve

容許_spender屢次取回您的賬戶，最高達_value金額。 若是再次調用此函數，它將以_value覆蓋當前的餘量。

allowance

返回_spender仍然被容許從_owner提取的金額。

後面三個方法很差理解，這裏還須要補充說明一下，

approve是受權第三方（好比某個服務合約）從發送者帳戶轉移代幣，而後經過 transferFrom() 函數來執行具體的轉移操做。

帳戶A有1000個ETH，想容許B帳戶隨意調用他的100個ETH，過程以下：

1. A帳戶按照如下形式調用approve函數approve(B,100)

2. B帳戶想用這100個ETH中的10個ETH給C帳戶，調用transferFrom(A, C, 10)

3. 調用allowance(A, B)能夠查看B帳戶還可以調用A帳戶多少個token

後面兩個是事件，事件是爲了獲取日誌方便提供的。前者是在代幣被轉移時觸發，後者是在調用approve方法時觸發。

基於ERC20編寫的一個代幣合約

pragma solidity ^0.4.16;
contract Token{
    uint256 public totalSupply;

    function balanceOf(address _owner) public constant returns (uint256 balance);
    function transfer(address _to, uint256 _value) public returns (bool success);
    function transferFrom(address _from, address _to, uint256 _value) public returns   
    (bool success);

    function approve(address _spender, uint256 _value) public returns (bool success);

    function allowance(address _owner, address _spender) public constant returns 
    (uint256 remaining);

    event Transfer(address indexed _from, address indexed _to, uint256 _value);
    event Approval(address indexed _owner, address indexed _spender, uint256 
    _value);
}

contract TokenDemo is Token {

    string public name;                   //名稱，例如"My test token"
    uint8 public decimals;               //返回token使用的小數點後幾位。好比若是設置爲3，就是支持0.001表示.
    string public symbol;               //token簡稱,like MTT

    function TokenDemo(uint256 _initialAmount, string _tokenName, uint8 _decimalUnits, string _tokenSymbol) public {
        totalSupply = _initialAmount * 10 ** uint256(_decimalUnits);         // 設置初始總量
        balances[msg.sender] = totalSupply; // 初始token數量給予消息發送者，由於是構造函數，因此這裏也是合約的建立者

        name = _tokenName;                   
        decimals = _decimalUnits;          
        symbol = _tokenSymbol;
    }

    function transfer(address _to, uint256 _value) public returns (bool success) {
        //默認totalSupply 不會超過最大值 (2^256 - 1).
        //若是隨着時間的推移將會有新的token生成，則能夠用下面這句避免溢出的異常
        require(balances[msg.sender] >= _value && balances[_to] + _value > balances[_to]);
        require(_to != 0x0);
        balances[msg.sender] -= _value;//從消息發送者帳戶中減去token數量_value
        balances[_to] += _value;//往接收帳戶增長token數量_value
        Transfer(msg.sender, _to, _value);//觸發轉幣交易事件
        return true;
    }


    function transferFrom(address _from, address _to, uint256 _value) public returns 
    (bool success) {
        require(balances[_from] >= _value && allowed[_from][msg.sender] >= _value);
        balances[_to] += _value;//接收帳戶增長token數量_value
        balances[_from] -= _value; //支出帳戶_from減去token數量_value
        allowed[_from][msg.sender] -= _value;//消息發送者能夠從帳戶_from中轉出的數量減小_value
        Transfer(_from, _to, _value);//觸發轉幣交易事件
        return true;
    }
    function balanceOf(address _owner) public constant returns (uint256 balance) {
        return balances[_owner];
    }


    function approve(address _spender, uint256 _value) public returns (bool success)   
    { 
        allowed[msg.sender][_spender] = _value;
        Approval(msg.sender, _spender, _value);
        return true;
    }

    function allowance(address _owner, address _spender) public constant returns (uint256 remaining) {
        return allowed[_owner][_spender];//容許_spender從_owner中轉出的token數
    }
    mapping (address => uint256) balances;
    mapping (address => mapping (address => uint256)) allowed;
}

代碼沒必要過多的解釋，註釋都寫得很清楚了。

這裏可能有人會有疑問，name，totalSupply這些按照標準不該該都是方法嗎，怎麼這裏定義的是屬性變量？ 這是由於solidity會自動給public變量生成同名的getter接口。

部署測試

我會提供兩個環境的部署測試流程，都是親測過的，你們能夠根據本身的喜愛選擇。我我的平時用得比較多的是後者。

Remix+MetaMask環境部署測試

這部分要求你的瀏覽器已經安裝了MetaMask插件，至於什麼是MetaMask以及如何安裝和使用請自行搜索查詢。MetaMask咱們用的是測試環境的網絡，在測試網絡中能夠申請一些以太幣進行測試。

咱們把代碼複製到remix編譯，沒問題的話以下圖所示點擊create建立合約，參數能夠按照下圖的方式設置。注意環境選擇injected web3，這樣會打開瀏覽器插件MetaMask進行測試部署。

點擊create後會彈出合約確認界面，直接點擊submit，等待合約確認。

咱們能夠在MetaMask裏點擊該筆合約提交的明細，就會跳轉到以太坊的瀏覽器中，能夠在這裏看到合約的各類信息：

如上圖所示，1表示該筆交易(合約也是一種交易)的hash值，2是當前合約所處的區塊位置(固然是測試環境)和已經被確認的區塊鏈數量，3是合約的建立地址，4是合約本省所在的地址。

3和4的概念容易混淆，注意理解。

進入MetaMask的token界面中，點擊add token，而後咱們把合約的地址複製到過去提交就能夠看到咱們的代幣了。還能夠點擊代幣的圖標打開瀏覽器查看代幣的詳細信息。

到這裏你已經完成了代幣的開發部署。接下來咱們還要看看如何進行代幣的轉帳，這個也是代幣比較經常使用的操做。轉帳咱們須要結合以太坊錢包MyEtherWallet，這是個以太坊的網頁版輕量級錢包，利用它能夠很方便的對咱們的以太幣和其它代幣進行管理。

轉帳前咱們首先要把代幣加入到錢包中，

注意在上圖中，咱們選擇的環境一樣是測試環境而且和MetaMask中的環境一致。點擊add custome token，輸入代幣地址等信息就能夠看到代幣了，而後進行轉帳操做。

 
咱們隨便轉入一個地址，轉帳完成後，發現代幣餘額確實減小了。

以太坊錢包mist+geth私有環境部署測試

我我的開發用這個環境比較多，不過這個環境安裝起來比較麻煩，具體流程能夠看下我之前的文章。

打開mist錢包，進入合約界面，而後點擊deploy new contact，而後把代碼複製進去編譯。

而後點擊deploy

輸入帳戶密碼開始部署。

隨着挖礦的進行，合約就被部署到個人geth私有環境中了，

回到錢包的合約界面已經能夠看到合約了， 

點擊transfer ether&tokens，進入轉帳界面，進行轉帳。

成功後能夠看到餘額已經減小，而且轉入帳戶的餘額增長。

 

若是對以太坊開發有興趣，推薦兩個教程：

1.適合區塊鏈新手的以太坊DApp開發：

http://xc.hubwiz.com/course/5a952991adb3847553d205d1

2.用區塊鏈、星際文件系統（IPFS）、Node.js和MongoDB來構建以太坊DApp電商平臺:

http://xc.hubwiz.com/course/5abbb7acc02e6b6a59171dd6

若是想加入以太坊技術開發羣能夠加微信拉你入羣。