《社交網絡》裏的評分公式——ELO排名系統

時間 2019-12-13

原文原文鏈接

　　《社交網絡》裏的Mark Zackburg被女友甩後，在舍友的啓發下，充分發揮了技術宅男自娛自樂的惡搞天分，作出了Facemash網站，對學校女生的相貌進行排名打分，結果網站訪問流量過大，直接把學校網絡搞癱瘓了。Facemask大受歡迎的關鍵就在於Zackburg基友Eduardo寫在窗戶上的排名公式，看電影之時就對這個排名公式很是感興趣，上網瞭解下，才發現這條公式就是大名鼎鼎的ELO等級分制度。ELO的應用很是普遍，大部分棋類比賽，如今流行的Moba遊戲，像11平臺的DOTA天梯系統，都是採用ELO等級分。算法

　　之後作競技類的遊戲排行榜能夠用ELO來排名，更真實地反映玩家的實力。閒來無事，作了個flash的Facemask，挺有意思的。網絡

ELO的實現代碼app

package
{
    
    /**
     * Elo排名算法
     * @author ShuchangLiu
     */
    public class EloRating
    {
        public static const ELO_RESULT_WIN:int = 1;
        public static const ELO_RESULT_LOSS:int = -1;
        public static const ELO_RESULT_TIE:int = 0;
        
        public static const ELO_RATING_DEFAULT:int = 1500;
        
        protected var rating1:int;
        protected var rating2:int;
        protected var score1:Number;
        protected var score2:Number;
        
        public function EloRating(rating1:int = ELO_RATING_DEFAULT, rating2:int = ELO_RATING_DEFAULT):void
        {
            this.rating1 = rating1;
            this.rating2 = rating2;
        }
        
        /**
         * @param result ELO_RESULT_WIN or ELO_RESULT_LOSS or ELO_RESULT_TIE
         */        
        public function setResult(result:int):void {
            var cscore1:Number = computeScore(this.rating2, this.rating1);
            var cscore2:Number = computeScore(this.rating1, this.rating2);
            
            if (result == ELO_RESULT_WIN) {
                this.rating1 = this.rating1 + (computeK(this.rating1) * (1 - cscore1));
                this.rating2 = this.rating2 + (computeK(this.rating2) * (0 - cscore2));
            }else if(result == ELO_RESULT_LOSS) {
                this.rating1 = this.rating1 + (computeK(this.rating1) * (0 - cscore1));
                this.rating2 = this.rating2 + (computeK(this.rating2) * (1 - cscore2));
            }else{
                // Assume tie
                this.rating1 = this.rating1 + (computeK(this.rating1) * (0.5 - cscore1));
                this.rating2 = this.rating2 + (computeK(this.rating2) * (0.5 - cscore2));
            }
        }
        
        protected function computeScore($rating1:int, $rating2:int):Number {
            return (1 / (1 + Math.pow(10, ($rating1 - $rating2) / 400)));
        }
        
        protected function computeK(rating:int):int {
            if(rating>=2400){
                return 16;
            }else if(rating >= 2100){
                return 24;
            }else{
                return 36;
            }
        }
        
        /** A的獲勝指望*/
        public function getScore1():Number {
            this.score1 = computeScore(this.rating2, this.rating1);
            return this.score1;
        }
        
        /** B的獲勝指望*/
        public function getScore2():Number {
            this.score2 = computeScore(this.rating1, this.rating2);
            return this.score2;
        }
        
        /** A的排名等級*/
        public function getRating1():int {
            return this.rating1;
        }
        
        /** B的排名等級*/
        public function getRating2():int {
            return this.rating2;
        }
        
        
        
    }
}