玩轉樹莓派－RaspBerry，3D打印個御用外殼

網上已經有不少種外殼出售，能夠直接購買。

但你也許不滿意與別人雷同，想要作出本身的創意，或者是要知足一些特殊的需求。

那麼用先進的3D打印技術，將很容易實現這一點。

即便沒有3D打印機，也沒有關係，您可使用OpenSCAD來設計一個，而後到某寶上找個3D打印店發送過去，作好了的東東過幾天就快遞到手了。

若是有3D打印機，沒有那麼多時間去設計，嗯，到Thingiverse上下一個就能夠了。爲了便於修改，推薦下載OpenSCAD格式的模型（在搜索框輸入OpenSCAD便可）。

嗯，其實咱們也能夠徹底本身去全新設計一個，上圖：

下面附上原始代碼，有興趣的朋友能夠拷下來本身研究修改，若是發現問題或者有新的創意，也歡迎共享出來，一塊兒完善。

//RaspBerry B+外殼
//注意：樹莓派其它版本有所不一樣，須要修改，不然裝不進去喲！
//Author:openthings@163.com.
//copyright 2015-2025.

/*Changelog:
2015-03-05:初步模型。
2015-03-14:修改USB和HDMI的位置,底側的厚度。
*/

//常量定義
bthick=0.1;    //盒壁厚度
bwidth=5.8;    //內徑淨寬
bhight=2.5;    //內徑淨高

blong_inter=11.0;        //內徑淨長
//外徑長度＝底厚＋內徑＋擋格＋蓋子厚度
blong=bthick+blong_inter+bthick*4;


//======================================
//盒子體，採用挖空切割方式造型。
difference() {
    //外盒
    translate([0,0,0])
    {    color([0.8,0.8,0.8])
        cube([blong,bwidth+bthick*4,
            bhight+bthick*3+0.05]);
    }
    //內盒，挖空。
    translate([bthick*2,bthick*2,bthick])
    {    color([0.2,0.8,0.8])
        cube([blong-bthick*5,bwidth,bhight+1]);
    }

    //放置蓋子的凹槽。
    translate([bthick,bthick,bhight+0.05])
    {    color([0.5,0.5,0.5])
        cube([blong_inter+bthick*3,
            bwidth+bthick*2,bthick*5]);
    }

    //通風孔。
    //右側
    translate([0,bwidth+bthick*2,0])
    rotate([90,0,0])
    for (i=[0:12],j=[0:3])
    {    color([0.8,0.2,0.2])
        translate([1.1+i*0.5,0.5+j*0.5,-0.3])
        cylinder(h = 0.4, r = 0.15,$fn=36);
    }
    //左側
    rotate([90,0,0])
    for (i=[0:12],j=[0:1])
    {    color([0.8,0.2,0.2])
        translate([1.1+i*0.5,1.6+j*0.5,-0.3])
        cylinder(h = 0.4, r = 0.15,$fn=36);
    }

    //MicroUSB接口
    translate([1.0,-0.1,0.5])
    {    color([0.2,0.8,0.8])
        cube([1,0.8,0.35]);
    }
    //HDMI接口
    translate([2.8,-0.1,0.5])
    {    color([0.2,0.8,0.8])
        cube([1.6,0.6,0.6]);
    }
    //音頻接口
    translate([5.4,-0.1,0.3])
    {    color([0.2,0.8,0.8])
        cube([0.8,0.6,0.8]);
    }


    //接線面板================
    translate([blong-0.3,0.1,0]){
    translate([bthick*2,bthick*2,bthick*2])
    {    color([0.6,0.3,0.8])
        cube([bthick+1,bwidth-bthick*2,
                bhight-bthick*5]);
    }

    //網線口。
    translate([-0.1,0.65,0.4])
    {    color([1,0.8,0.8])
        cube([1.0,1.2,1.2]);
    }
    //USB接口，挖空。
    translate([-0.1,2.4,0.4])
    {    color([1,0.8,0.8])
        cube([0.8,1.45,1.6]);
    }
    translate([-0.1,4.15,0.4])
    {    color([1,0.8,0.8])
        cube([0.8,1.45,1.6]);
    }

  }
}

//底部增強，在內部造成邊角擋格。
//上部
translate([bthick*2,bthick*2,bhight-bthick+0.05])
{    color([0.2,0.5,0.2])
    cube([bthick,bwidth,bthick]);
}
//底部
translate([bthick*2,bthick*2,bthick])
{    color([0.2,0.5,0.2])
    cube([bthick,bwidth,bthick]);
}

//底部,USB接口墊片
translate([bthick*2,bthick*2,bthick])
{    color([0.2,0.5,0.2])
    cube([2.2,bthick*5,bthick*2]);
}

//======================================
//蓋子，單獨打印。嵌入盒子內部，注意留公差。
translate([0,-6.2,0]){
//translate([bthick,bthick+0.05,
//    bhight+bthick+0.05]){ 
    difference() {
    //蓋子，挖空。
    {    color([0.5,0.6,0.6])
        cube([blong_inter+bthick*3-0.04,
            bwidth+bthick*2-0.04,bthick*1.5]);
    }
    //屏幕區域,挖空。
    translate([1.1,bthick*4-0.04,-0.1])
    {    color([0.5,0.6,0.6])
        cube([6.8,5.2,bthick+0.2]);
    }
    //面板，裝飾圓孔。
    //rotate([90,0,0])
    for (i=[0:7],j=[0:15])
    {    color([0.8,0.2,0.2])
        translate([8.5+i*0.3,0.65+j*0.3,-0.2])
        cylinder(h = 0.6, r = 0.1,$fn=36);
    }

      }

    translate([0,0.0,bthick])
    {    color([0.8,0.6,0.6])
        cube([0.1,bwidth+bthick*2-0.04,
            bthick*1.5]);
    }
    translate([blong_inter+bthick*2-0.04,0,bthick])
    {    color([0.8,0.6,0.6])
        cube([0.1,bwidth+bthick*2-0.04,
                bthick*1.5]);
    }

    translate([0,0,bthick])
    {    color([0.8,0.6,0.6])
        cube([blong_inter+bthick*3-0.04,0.1,
            bthick*1.5]);
    }
    translate([0,bwidth+bthick-0.04,bthick])
    {    color([0.8,0.6,0.6])
        cube([blong_inter+bthick*3-0.04,0.1,
            bthick*1.5]);
    }

}