ORACLE基本知識：子程序和程序包(package,function,procedure)

1、程序包package、子程序的區別
    子程序是命名的PL/SQL塊，可帶參數並可在須要時隨時調用。PL/SQL有兩種類型的子程序，即存儲過程和函數。
        1.存儲過程用於執行特定的任務    2.函數用於執行任務並返回值
    程序包是對相關類型、變量、常量、遊標、異常、存儲過程和函數的封裝。
    程序包由包規範和包主體兩部分組成。相似於bo和boimpl
        1.包規範是包的接口，包含公用對象及其類型。
        2.包主體實現包規範中的遊標和子程序，包主體中的聲明僅限於在包內使用。
    程序包中游標的定義分爲遊標規範和遊標主體兩部分。

2、語法及示例：
一、存儲過程 PROCEDURE

建立存儲過程的語法：
CREATE [OR REPLACE] PROCEDURE procedure_name[(parameter_list)]  

{IS|AS}
    [local_declarations]
BEGIN
    executable_statements
[EXCEPTION
    exception_handlers]
END [procedure_name];
其中：procedure_name是過程的名稱。
        parameter_list是參數列表。
        local_declarations是局部聲明。
        executable_statements是可執行語句。
        exception_handlers是異常處理程序。
示例1：演示建立過程(參數列表中爲IN參數賦予一個默認值，不能爲OUT、IN OUT參數賦予默認值)
create or replace procedure find_emp(emp_no in number:=7900)
as
    empname varchar2(20);
begin
    select ename into empname from emp where empno=emp_no;
    dbms_output.put_line('僱員姓名是 '||empname);
exception
    when no_data_found then
        dbms_output.put_line('僱員編號未找到');
end find_emp;

調用過程：EXECUTE procudure_name(parameters_list);  也能夠在過程裏面調用，直接寫上procudure_name而沒必要寫EXECUTE。

示例2：演示建立帶OUT參數的過程
CREATE OR REPLACE PROCEDURE TEST(VALUE1 VARCHAR2, VALUE2 OUT NUMBER) IS
  IDENTITY NUMBER;
BEGIN
  SELECT SAL
    INTO IDENTITY FROM EMP WHERE EMPNO = VALUE1;
  IF IDENTITY < 2000 THEN  VALUE2 := 1000;
  ELSE  VALUE2 := 500;
  END IF;
END;

調用帶OUT參數的過程：
DECLARE
  VALUE2 NUMBER;
BEGIN
  TEST('7900', VALUE2);
  DBMS_OUTPUT.PUT_LINE(VALUE2);
END;

示例3：演示建立帶IN OUT參數的過程
CREATE OR REPLACE PROCEDURE SWAP(P1 IN OUT NUMBER, P2 IN OUT NUMBER) IS
  V_TEMP NUMBER;
BEGIN
  V_TEMP := P1;
  P1     := P2;
  P2     := V_TEMP;
END;

調用帶IN OUT參數的過程：
DECLARE
  NUM1 NUMBER := 100;
  NUM2 NUMBER := 200;
BEGIN
  SWAP(NUM1, NUM2);
  DBMS_OUTPUT.PUT_LINE('num1= ' || NUM1);
  DBMS_OUTPUT.PUT_LINE('num2= ' || NUM2);
END;

示例4：將過程的執行權限授予其餘用戶
    GRANT EXECUTE ON find_emp TO scott;
    GRANT EXECUTE ON swap TO PUBLIC;
將find_emp過程的執行權限授予給用戶scott，將執行swap過程的權限授予全部數據庫用戶。

刪除過程語法：DROP PROCEDURE procudure_name;

二、函數 FUNCTION

定義函數的語法以下：
CREATE [OR REPLACE] FUNCTION function_name[(parameter_list)]
RETURN datatype
{IS|AS}
    [local_declarations]
BEGIN
    executable_statements
[EXCEPTION
    exception_handlers]
END [function_name];
其中：function_name是函數的名稱。
        parameter_list是參數列表。
        local_declarations是局部聲明。
        executable_statements是可執行語句。
        exception_handlers是異常處理程序。
使用函數時注意：形式參數必須只使用數據庫類型，不得使用PL/SQL類型。函數的返回類型也必須是數據庫類型。
函數不能單獨執行，只能經過SQL語句或PL/SQL程序塊來調用。
示例5：演示如何建立函數
CREATE OR REPLACE FUNCTION FUN_HELLO RETURN VARCHAR2 IS
BEGIN
  RETURN '朋友，您好';
END;

調用函數：select fun_hello from dual;

函數的受權：同過和的受權同樣具體請看示例4。
刪除函數：DROP FUNCTION function_name

CREATE OR REPLACE FUNCTION "ADD_MONTHS_STRING" (SOURCE  VARCHAR2,
                                             ADD_NUM INTEGER)
    RETURN VARCHAR2 IS
BEGIN
    IF SOURCE IS NULL OR LENGTH(SOURCE) < 6 THEN
        RETURN TO_CHAR(ADD_MONTHS(SYSDATE, ADD_NUM), 'YYYYMM');
    ELSE
        RETURN TO_CHAR(ADD_MONTHS(TO_DATE(SOURCE, 'YYYYMM'), ADD_NUM),'YYYYMM');
    END IF;
END;

總結：                            過程和函數的差別
            過程                                                                                            函數
做爲PL/SQL語句執行                                                                     做爲表達式的一部分調用
在規範中不包含RETURN子句                                                          必須在規範中包含RETURN子句
不返回任何值                                                                               必須返回單個值
能夠包含RETURN語句，可是與函數不一樣，它不能用於返回值                必須包含至少一條RETURN語句

三、程序包
建立包規範的語法：
CREATE [OR REPLACE] PACKAGE package_name
IS|AS
    [Public type and item declarations]
    [Subprogram specifications]
END [package_name];
其中：package_name是包的名稱。
        Public type and item declarations是聲明類型、常量、變量、異常和遊標等。
        Subprogram specifications聲明PL/SQL子程序。

示例6：演示建立程序包規範
CREATE OR REPLACE PACKAGE PACK_OP IS
  PROCEDURE PRO_PRINT_ENAME(ID NUMBER);
  PROCEDURE PRO_PRINT_SAL(ID NUMBER);
  FUNCTION FUN_RE_DATE(ID NUMBER) RETURN DATE;
END;

建立包主體的語法：
CREATE [OR REPLACE] PACKAGE BODY package_name
IS|AS
    [Public type and item declarations]
    [Subprogram bodies]
[BEGIN
    Initialization_statements]
END [package_name];
其中：package_name是包的名稱。
        Public type and item declarations是聲明類型、常量、變量、異常和遊標等。
        Subprogram bodies是定義公共和私有PL/SQL子程序。

示例7：演示建立程序包主體

CREATE OR REPLACE PACKAGE BODY PACK_OP IS

  PROCEDURE PRO_PRINT_ENAME(ID NUMBER) IS
    NAME EMP.ENAME%TYPE;
  BEGIN
    SELECT ENAME INTO NAME FROM EMP WHERE EMPNO = ID;
    DBMS_OUTPUT.PUT_LINE('職員姓名：' || NAME);
  END PRO_PRINT_ENAME;

  PROCEDURE PRO_PRINT_SAL(ID NUMBER) IS
    SALARY EMP.SAL%TYPE;
  BEGIN
    SELECT SAL INTO SALARY FROM EMP WHERE EMPNO = ID;
    DBMS_OUTPUT.PUT_LINE('職員工資：' || SALARY);
  END PRO_PRINT_SAL;

  FUNCTION FUN_RE_DATE(ID NUMBER) RETURN DATE IS
    BEDATE EMP.HIREDATE%TYPE;
  BEGIN
    SELECT HIREDATE INTO BEDATE FROM EMP WHERE EMPNO = ID;
    RETURN BEDATE;
  END FUN_RE_DATE;
END PACK_OP;

示例8：調用程序包中建立的過程和函數
exec pack_op.pro_print_ename(7900);
exec pack_op.pro_print_sal(7900);
select pack_op.fun_re_date(7900) from dual;

示例9：演示程序包中的遊標
建立包規範：
CREATE OR REPLACE PACKAGE PACK_EMP IS
  CURSOR CUR_EMP RETURN EMP%ROWTYPE;
  PROCEDURE PRO_CUR;
END PACK_EMP;

建立包主體：
CREATE OR REPLACE PACKAGE BODY PACK_EMP IS
  --遊標
  CURSOR CUR_EMP RETURN EMP%ROWTYPE IS
    SELECT * FROM EMP;--遊標表示 EMP表的每一列
  --過程
  PROCEDURE PRO_CUR IS
    REC_EMP EMP%ROWTYPE;  --記錄REC_EMP 表示表EMP的列
  BEGIN
    OPEN CUR_EMP;
    LOOP          --循環表的每一列
      FETCH CUR_EMP
        INTO REC_EMP;
      EXIT WHEN CUR_EMP%NOTFOUND;
      IF REC_EMP.SAL < 1000 THEN
        DBMS_OUTPUT.PUT_LINE('員工工資：' || REC_EMP.SAL || '，需加倍努力爭取提升工資');
      ELSIF REC_EMP.SAL >= 1000 AND REC_EMP.SAL < 2000 THEN
        DBMS_OUTPUT.PUT_LINE('員工工資：' || REC_EMP.SAL || '，工資通常，爭取搞個部門經理作作');
      ELSE
        DBMS_OUTPUT.PUT_LINE('員工工資：' || REC_EMP.SAL || '，工資不錯，爭取搞個總經理作作');
      END IF;
    END LOOP;
  END PRO_CUR;
END PACK_EMP;

調用程序包中的過程以調用程序包中的遊標
    exec pack_emp.pro_cur;

示例10：存儲過程返回遊標的子程序包(此程序包返回r_cur遊標)

CREATE OR REPLACE PACKAGE SCOTT.PK_WT IS
  TYPE MYTYPE IS REF CURSOR;   --REF Cursor遊標  弱類型REF遊標,不指定return type，能和任何類型的CURSOR變量匹配，用於獲取任何結果集
  PROCEDURE P_WT(MYCS OUT MYTYPE);
END;

CREATE OR REPLACE PACKAGE BODY SCOTT.PK_WT IS
  PROCEDURE P_WT(MYCS OUT MYTYPE) AS
    R_CUR MYTYPE;
  BEGIN
    OPEN R_CUR FOR
      SELECT * FROM EMP;--查詢語句返回結果集
    MYCS := R_CUR;
  END P_WT;
END PK_WT;

查詢有關過程、函數和程序包的信息：USER_OBJECTS數據字典視圖column object_name format a18select object_name,object_type from user_objects where object_type in ('PROCEDURE','FUNCTION','PACKAGE','PACKAGE BODY');