玩轉OneNET物聯網平臺之MQTT服務④ —— 遠程控制LED（設備自注冊）+ Android App控制

時間 2020-05-20

標籤 onenet 聯網平臺 mqtt 服務遠程控制 led 設備註冊 android app 欄目 Android 简体版

原文原文鏈接

授人以魚不如授人以漁，目的不是爲了教會你具體項目開發，而是學會學習的能力。但願你們分享給你周邊須要的朋友或者同窗，說不定大神成長之路有博哥的奠定石。。。android

QQ技術互動交流羣：ESP8266&32 物聯網開發羣號622368884，不喜勿噴git

1、你若是想學基於Arduino的ESP8266開發技術

1、基礎篇github

ESP8266開發之旅基礎篇① 走進ESP8266的世界

ESP8266開發之旅基礎篇② 如何安裝ESP8266的Arduino開發環境

ESP8266開發之旅基礎篇③ ESP8266與Arduino的開發說明

ESP8266開發之旅基礎篇④ ESP8266與EEPROM

ESP8266開發之旅基礎篇⑤ ESP8266 SPI通訊和I2C通訊

ESP8266開發之旅基礎篇⑥ Ticker——ESP8266定時庫

2、網絡篇web

ESP8266開發之旅網絡篇① 認識一下Arduino Core For ESP8266

ESP8266開發之旅網絡篇② ESP8266 工做模式與ESP8266WiFi庫

ESP8266開發之旅網絡篇③ Soft-AP——ESP8266WiFiAP庫的使用

ESP8266開發之旅網絡篇④ Station——ESP8266WiFiSTA庫的使用

ESP8266開發之旅網絡篇⑤ Scan WiFi——ESP8266WiFiScan庫的使用

ESP8266開發之旅網絡篇⑥ ESP8266WiFiGeneric——基礎庫

ESP8266開發之旅網絡篇⑦ TCP Server & TCP Client

ESP8266開發之旅網絡篇⑧ SmartConfig——一鍵配網

ESP8266開發之旅網絡篇⑨ HttpClient——ESP8266HTTPClient庫的使用

ESP8266開發之旅網絡篇⑩ UDP服務

ESP8266開發之旅網絡篇⑪ WebServer——ESP8266WebServer庫的使用

ESP8266開發之旅網絡篇⑫ 域名服務——ESP8266mDNS庫

ESP8266開發之旅網絡篇⑬ SPIFFS——ESP8266 Flash文件系統

ESP8266開發之旅網絡篇⑭ web配網

ESP8266開發之旅網絡篇⑮ 真正的域名服務——DNSServer

ESP8266開發之旅網絡篇⑯ 無線更新——OTA固件更新

3、應用篇json

ESP8266開發之旅應用篇① 局域網應用 ——炫酷RGB彩燈

ESP8266開發之旅應用篇② OLED顯示天氣屏

ESP8266開發之旅應用篇③ 簡易版WiFi小車

4、高級篇api

ESP8266開發之旅進階篇① 代碼優化 —— ESP8266內存管理

ESP8266開發之旅進階篇② 閒聊Arduino IDE For ESP8266配置

ESP8266開發之旅進階篇③ 閒聊 ESP8266 Flash

ESP8266開發之旅進階篇④ 常見問題 —— 解決困擾

ESP8266開發之旅進階篇⑤ 代碼規範 —— 像寫文章同樣優美

ESP8266開發之旅進階篇⑥ ESP-specific APIs說明

1.理論基礎

參考博主線上博文：服務器

在前面的博文中，博主主要經過手動方式去建立設備。這種方式的缺點明顯：網絡

人爲手動控制，對於開發者來講極度不友好；
若是設備數量不少，豈不是要手動操做很是屢次；

那麼，如何實現設備自注冊呢？所謂自注冊就是設備連入網絡後自動往OneNet雲平臺註冊設備信息並獲取設備Id。app

爲了區分惟一性，咱們採用ESP-Mac地址的組合形式
同時爲了操做方便，博主花了個週末的時間作了一個對應的app，理論上不限制ESP8266接入點的數量

本篇博文的目的就在於教會你們如何和app通訊，完成MQTT協議下的App遠程控制LED燈，而且LED燈的數量能夠隨意接入，用戶能夠在app端修改設備名字以便方便操做。oop

博主極度建議你們從第一篇看起，有個大概瞭解，由於本系列教程都是有相聯繫的

先上個概念圖：

2.遠程控制LED，實現設備自注冊

2.1 實驗材料

ESP8266 NodeMcu
Android手機
OneNet平臺

2.2 實驗步驟

2.2.1 建立 ESP8266智能燈系統產品（MQTT協議）

注意點：

務必選擇MQTT協議

建立完畢後，咱們點擊查看具體的產品信息：

注意點：

須要記錄產品ID，其用來區分產品惟一標識符，這個ID待會須要填入App
Master-APIkey，網絡請求鑑權信息，接口調用須要帶入，這個ID待會須要填入App

2.2.2 NodeMcu燒錄代碼 —— MQTT設備端

爲了明確區分代碼功能，博哥命名工程名爲P_OneNet_Exam05:

P_OneNet_Exam05.ino文件：

/**
 *  功能：ESP8266 Mqtt客戶端自注冊功能，經過配套App控制Led消息，理論上能夠接入無數個esp8266
 *  做者：單片機菜鳥
 *  時間：2019-10-27
 *  描述：
 *      1.初始化工做：初始化網絡配置，Mqtt客戶端自注冊，鏈接鑑權，訂閱主題
 *      2.訂閱消息：獲取發送過來的消息（json格式），解析消息，實現控制亮滅燈
*/

#include <ESP8266WiFi.h>
#include <PubSubClient.h>
#include <ESP8266HTTPClient.h>
#include <ArduinoJson.h>
#include <EEPROM.h>
#include <Ticker.h>
#include "H_project.h"

#define MAGIC_NUMBER 0xAA

int state;
WiFiClient espClient;

//聲明方法
void initSystem();
void initOneNetMqtt();
void callback(char* topic, byte* payload, unsigned int length);
void saveConfig();
void loadConfig();
bool parseRegisterResponse();
void parseOneNetMqttResponse(char* payload);

/**
 * 初始化
 */
void setup() {
  initSystem();
  initOneNetMqtt();
}

void loop() {
  ESP.wdtFeed();
  state = connectToOneNetMqtt();
  if(state == ONENET_RECONNECT){
     //重連成功 須要從新註冊
     mqttClient.subscribe(TOPIC,1);
     mqttClient.loop();
  }else if(state == ONENET_CONNECTED){
     mqttClient.loop();
  }
  delay(2000);
}

void initSystem(){
    int cnt = 0;
    Serial.begin (115200);
    Serial.println("\r\n\r\nStart ESP8266 MQTT");
    Serial.print("Firmware Version:");
    Serial.println(VER);
    Serial.print("SDK Version:");
    Serial.println(ESP.getSdkVersion());
    wifi_station_set_auto_connect(0);//關閉自動鏈接
    ESP.wdtEnable(5000);
    WiFi.disconnect();
    delay(100);
    WiFi.begin(ssid, password);
    while (WiFi.status() != WL_CONNECTED) {
          delay(500);
          cnt++;
          Serial.print(".");
          if(cnt>=40){
            cnt = 0;
            //重啓系統
            delayRestart(1);
          }
    }
    pinMode(LED_BUILTIN, OUTPUT);

    loadConfig();
    //尚未註冊
    if(strcmp(config.deviceid,DEFAULT_ID) == 0){
        int tryAgain = 0;
        while(!registerDeviceToOneNet()){
          Serial.print(".");
          delay(500);
          tryAgain++;
          if(tryAgain == 5){
            //嘗試5次
            tryAgain = 0;
            //重啓系統
            delayRestart(1);
          }
        }
        if(!parseRegisterResponse()){
            //重啓系統
            delayRestart(1);
            while(1);
        }
    }
}

void initOneNetMqtt(){
    mqttClient.setServer(mqttServer,mqttPort);
    mqttClient.setClient(espClient);
    mqttClient.setCallback(callback);

    initOneNet(PRODUCT_ID,API_KEY,config.deviceid);
}

void callback(char* topic, byte* payload, unsigned int length) {
  Serial.print("Message arrived [");
  Serial.print(topic);
  Serial.print("] ");
  for (int i = 0; i < length; i++) {
    Serial.print((char)payload[i]);
  }
  Serial.println();
  parseOneNetMqttResponse((char *)payload);
}

/*
 * 保存參數到EEPROM
*/
void saveConfig()
{
  Serial.println("Save OneNet config!");
  Serial.print("deviceId:");
  Serial.println(config.deviceid);

  EEPROM.begin(150);
  uint8_t *p = (uint8_t*)(&config);
  for (int i = 0; i < sizeof(config); i++)
  {
    EEPROM.write(i, *(p + i));
  }
  EEPROM.commit();
}

/*
 * 從EEPROM加載參數
*/
void loadConfig()
{
  EEPROM.begin(150);
  uint8_t *p = (uint8_t*)(&config);
  for (int i = 0; i < sizeof(config); i++)
  {
    *(p + i) = EEPROM.read(i);
  }
  EEPROM.commit();
  if (config.magic != MAGIC_NUMBER)
  {
    strcpy(config.deviceid, DEFAULT_ID);
    config.magic = MAGIC_NUMBER;
    saveConfig();
    Serial.println("Restore config!");
  }
  Serial.println("-----Read config-----");
  Serial.print("deviceId:");
  Serial.println(config.deviceid);
  Serial.println("-------------------");
}

/**
 * 解析mqtt數據
 */
void parseOneNetMqttResponse(char* payload){
   Serial.println("start parseOneNetMqttResponse");
   StaticJsonBuffer<100> jsonBuffer;
     // StaticJsonBuffer 在棧區分配內存   它也能夠被 DynamicJsonBuffer（內存在堆區分配） 代替
     // DynamicJsonBuffer  jsonBuffer;
   JsonObject& root = jsonBuffer.parseObject(payload);

     // Test if parsing succeeds.
   if (!root.success()) {
       Serial.println("parseObject() failed");
       return ;
   }

   String deviceId = root["Did"];
   int status = root["sta"];

   if(strcmp(config.deviceid,deviceId.c_str()) == 0){
        if (status == 1) {
            digitalWrite(LED_BUILTIN, LOW);
        } else {
            digitalWrite(LED_BUILTIN, HIGH);
        }
    }
}

/**
 * 解析註冊返回結果
 */
bool parseRegisterResponse(){
   Serial.println("start parseRegisterResponse");
   StaticJsonBuffer<200> jsonBuffer;
     // StaticJsonBuffer 在棧區分配內存   它也能夠被 DynamicJsonBuffer（內存在堆區分配） 代替
     // DynamicJsonBuffer  jsonBuffer;
   JsonObject& root = jsonBuffer.parseObject(response);

     // Test if parsing succeeds.
   if (!root.success()) {
       Serial.println("parseObject() failed");
       return false;
   }

   int errno = root["errno"];
   if(errno !=0){
       Serial.println("register failed!");
       return false;
   }else{
       Serial.println("register sucess!");
       strcpy(config.deviceid, root["data"]["device_id"]);
       saveConfig();
       return true;
   }
}

H_project.h 代碼:

#ifndef _MAIN_H__
#define _MAIN_H__


extern "C" {
#include "user_interface.h"
#include "smartconfig.h"
}

struct onenet_config
{
  char deviceid[15];
  uint8_t magic;
};

/************** ESP8266相關操做 **************************/
void delayRestart(float t);
void delayNs(uint8_t m);
/*********************************************************/

/*************** OneNet MQTT相關操做 ****************************/
void initOneNet(uint8_t *productId,uint8_t *apiKey,uint8_t *deviceId);
int connectToOneNetMqtt();
/*********************************************************/

/**************** OneNet Http相關操做 ***************************/
HTTPClient http;
String response;
const char* host = "api.heclouds.com";
bool registerDeviceToOneNet();
/****************************************************************/

#define ONENET_DISCONNECTED 1 //已經斷開
#define ONENET_CONNECTED 2    //已經鏈接上
#define ONENET_RECONNECT 3    //重連成功

//常量
#define VER             "MQTT_LED_V1.0"
const char* ssid = "xxxxxxxx";//wifi帳號
const char* password = "xxxxxxx";//wifi祕密

//OneNet相關
PubSubClient mqttClient;
const char* mqttServer = "183.230.40.39";//mqtt服務器
const uint16_t mqttPort = 6002;
#define PRODUCT_ID    "253190" //此爲博哥本身的產品id 請新建本身的
#define API_KEY    "xxxxxx"
#define DEFAULT_ID "123456"
#define TOPIC     "esp8266led"

unsigned long lastWiFiCheckTick = 0;
bool ledState = 0;

onenet_config config;

#endif

所有工程代碼，博哥放在我的QQ羣裏或者代碼下載地址。

注意點：