Android中Gradle詳細實用指南

時間  2019-11-17
標籤 android gradle 詳細 實用 指南 欄目 Android 简体版
原文   原文鏈接

Android中Gradle實用指南

Gradle讓Android中的依賴管理、庫管理、渠道管理以及一些動態地編譯配置變得極爲方便！！
本文是對Gradle在Android項目中進階使用的知識點整理和簡要講解
較爲詳細的Gradle教科書Github
Gradle腳本配置文檔：Google Githubjavascript

目錄

  • Android工程中的Gradle
  • 經常使用的Gradle Task
  • 動態參數配置
  • Project:build.gradle
    • 全局屬性配置
    • 總體結構和描述
  • Module: build.gradle
    • defaucltConfig
    • signConfigs
    • buidlTypes
    • sourceSets
    • productFlavors
    • compileOptions
    • lintOptions
    • build.gradle 圖形化配置
  • dependencies項目依賴
  • 自定義方法def
  • Gradle編譯提速優化
    • 性能檢測
    • 禁用Task達到提速
    • AAPT
    • Gradle編譯優化
  • 認識Task
  • 自定義Plugin
    • build.gradle中直接定義
    • 當前工程中定義
    • 獨立Module自定義插件
  • 最後

Android工程中的Gradle

下面簡述對咱們工程最重要的幾個Gradle文件，後續也會圍繞他們進行詳細講解和補充
（請仔細看代碼中的註釋哈）html

  • 工程Project 中的 build.gradle : 工程控制Gradle編譯配置
  • 模塊module中的 build.gradle ： 控制每一個Module的編譯過程
  • gradle.properties : gradle動態參數的配置文件
  • local.properties ： 本地的配置，如：SDK位置
  • gradle-wrapper.properties ：gradle本地代理，聲明瞭指向目錄和版本
    • distributionUrl : 指定gradle版本不存在時，就從Value的地址中去下載。不少時候，咱們只要版本換成咱們本地存在的gradle版本就能夠了
  • settings.gradle ： 配置Gradle中的Module管理

    經常使用Gradle Task

    ~ 表示 gradlew
    gradlew是包裝器，自動下載包裝裏定義好的gradle 版本，保證編譯環境統一
    gradle 是用本地的gradle
  • gradlew task -all : 羅列出全部Task ，同時攜帶具體做用和相互關係

  • gradlew assembleDebug : 導出全部渠道測試包java

    • ~ assembleRelease : 導出全部渠道正式包
    • ~ assembleBaiduDebug --stacktrace : 導出指定渠道測試包，同時攜帶異常信息

  • ~ --stop : 當即中止編譯react

  • ~ check : 檢查任務
  • ~ build : 執行了 check和assemble
  • ~ clean ： 清除全部中間編譯結果

動態參數配置

在Gradle中動態配置資源參數
咱們能夠根據各自的需求在不一樣的領域（如：buildType 的debug, defaultConfig ...）下去動態替換或配置咱們項目中所使用到的資源，如 log 開關， 針對不一樣渠道的對應內容字段，不一樣版本定義引入的不一樣值等等android

首先說清一點，對於動態資源在build.gradle中多個領域中的使用，會遵循一下順序來進行覆蓋：
buildType > productFlavor > defaultConfig > Manifest中的配置 > 依賴的第三方庫的配置 > 任意領域中的默認值（也就是沒有設置值）git

  1. Manifest佔位符： 能夠動態配置Manifest的參數
在Manifest的Application節點下
        //這裏以友盟爲例
        <!-- 友盟統計相關meta-data -->
        <meta-data
            android:name="UMENG_APPKEY"
            android:value="balabalabala" />
        <meta-data
            android:name="UMENG_CHANNEL"
            android:value="${UMENG_CHANNEL_VALUE}" />

在build.gradle中對參數進行動態配置
 productFlavors {
        baidu {
            manifestPlaceholders = [UMENG_CHANNEL_VALUE: "baidu"]
        }
}複製代碼
  1. gradle.properties 的使用
    • 系統屬性：
      配置： systemProp.proName=123
      使用：System.properties['proName']
    • 自定義屬性 ：
      配置： 有key： ray.proName=123 ，無key : proName = 123
      使用： 有key： project。property('proName') , 無key ： proName
gradle.properties中的配置

#使用系統參數配置
systemProp.keyStore=ray.jks
#使用key/value鍵值對配置
ray.keyPassword=123456
#屬性配置
mKeyAlias=ray

build.gradle中的使用
//簽名打包
        release {
            //簽名文件所在路徑
            storeFile file(System.properties['keyStore'])
            //簽名密碼
            storePassword "111111"
            //別名
            keyAlias mKeyAlias
            keyPassword project.property('ray.keyPassword')
        }複製代碼
  1. BuildConfig文件
    • 在app/build/generated/source/buildConfig文件夾下面
    • 使用： buildConfigField "String" , "key" , "\"value\""
      配置buildConfig中的屬性參數 String ： 參數類型（int,boolean...）, key : 屬性的名字， value ： 屬性的值， \ 爲轉義字符
  1. resValue 動態修改工程資源
    • 和buildConfig 相似， resValue("string","key","value")
    • 其中string 表示 會在 app/build/generated/res/resValue/.../generated.xml中生成對應的String 的 key 和Value， 代碼中能夠直接getResources().getString(R.string.key);獲取到value
    • 注意： 由於Gradle編譯的時候會將腳本配置和string.xml文件中配置進行merge，因此string.xml中已經存在的key在編譯前要刪除，不然會報錯
//下面模擬在不一樣渠道下修改資源參數
productFlavors{
baidu{
  buildConfigField "String" , "productCode" , "\"baidu 1.0\""
  resValue("string","productName","baidu")
}
}複製代碼

Project : build.gradle

全局屬性配置

  1. 在project : build.gradle 的buildscript中聲明ext和自定義屬性，而後在其餘module中就能夠直接使用這個屬性了
    以下：
Project : build.gradle
buildscript {
    //自定義工程使用的屬性
    ext {
        kotlin_version = '1.1.0'
        compile_version = 25
    }

    //聲明依賴Android Gradle 插件版本
    dependencies {
        classpath 'com.android.tools.build:gradle:2.3.0'
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlin_version"
    }
}

Module : build.gradle 中使用
Android
{
compileSdkVersion compile_version
}
dependencies
{
 compile "org.jetbrains.kotlin:kotlin-reflect:$kotlin_version"
 }複製代碼
  1. 新建本身的Gradle屬性文件 text.gradle ， 而後在Project中引入，最後就能夠在其餘的module中直接使用了，具體應用能夠參考印象筆記Github
    以下：
text.gradle 編寫以下：
ext {
    kotlinVersion = "1.1.0"
    rxjavaLibVersion = "1.2.0"

    dependencies = [
            // Rx
            rxJava: "io.reactivex:rxjava:$rxjavaLibVersion"
    ]
}

Project : build.gradle 中引入
//就是引入他的相對根目錄路徑
apply from: 'config/text.gradle'

Module : build.gradle 中使用
rootProject.ext.XXXXX

dependencies {

 def dependencies=rootProject.ext.dependencies

    compile dependencies.rxJava

    compile "org.jetbrains.kotlin:kotlin-stdlib:$rootProject.ext.kotlinVersion"

}複製代碼

總體結構與描述

//聲明引入的參數配置文件
apply from: 'config/dependencies.gradle'
apply from: 'config/text.gradle'

//編譯配置
buildscript {

    //自定義參數
    ext {
        kotlin_version = '1.1.0'
        compile_version = 25
    }

    //Gradle指定使用jcenter代碼倉庫
    repositories {
        jcenter()
    }
    //聲明依賴Android Gradle 插件版本
    dependencies {
        classpath 'com.android.tools.build:gradle:2.3.0'
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlin_version"
    }
}

//這裏能夠爲項目總體配置屬性
 allprojects{
    repositories {
        jcenter()
    }
}

//任務：每次構建的時候刪除指定目錄
task clean(type: Delete) {
    delete rootProject.buildDir
}複製代碼

Module : build.gradle

控制每一個Module的編譯過程以及具體的參數配置github

defaultConfig

基本配置信息segmentfault

//默認配置
    defaultConfig {
        //包名
        applicationId "com.rayhahah.gradledemo"
        //最低版本
        minSdkVersion 19
        //目標版本
        targetSdkVersion 25
        //版本代碼
        versionCode getVersinCode()
        //版本
        versionName "1.0"
        //自動化測試
        testInstrumentationRunner "android.support.test.runner.AndroidJUnitRunner"

        resValue "int","test","1"
    }複製代碼

signConfigs

簽名配置信息api

signingConfigs {

        //debug模式簽名文件
        debug {}
        //簽名打包
        release {
            //簽名文件所在路徑
            storeFile file("ray.jks")
            //簽名密碼
            storePassword "111111"
            //別名
            keyAlias "rayhahah"
            keyPassword "111111"
        }

        //自定義簽名配置
        ray{
            //和上面的屬性一致，根據我的需求實現不一樣配置
        }
    }複製代碼

buildTypes

編譯類型 ： 指定編譯不一樣類型狀況下的不一樣配置信息
這裏是列舉了部分屬性和方法，所有的方法和屬性請看官網文檔瀏覽器

//構建配置
    buildTypes {
        release {

            //是否啓用資源優化
            minifyEnabled
             //啓用捨棄無用資源，只有當開啓混淆纔可以啓用
            shrinkResources false
            //指定混淆文件
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'

            //指定咱們release包的輸出文件名就是咱們的渠道名字
            applicationVariants.all { variant ->
                variant.outputs.each { output ->
                    def outputFile = output.outputFile
                    if (outputFile != null && outputFile.name.endsWith(".apk")) {

                        def fileName = "${variant.productFlavors[0].name}" + ".apk"
                        output.outputFile = new File(outputFile.parent, fileName);
                    }
                }
            }
        }

        debug {

        }

        //繼承
// rayhahah.initWith(debug)

        //自定義buildType
        rayhahah {
            //指定簽名配置文件
            signingConfig signingConfigs.debug
            //包名增長後綴
            applicationIdSuffix ".ray"

        }
    }複製代碼

sourceSets

配置資源邏輯組

  • 經過指定資源 文件夾路徑構建本身的工程目錄
指定Android所須要文件夾所在具體路徑

sourceSets {
//這樣的配置適用於將Eclipse中的項目結構遷移到AndroidStudio中
        main {
            //指定src資源目標目錄
            java.srcDirs = ['src']
            //指定asset的目標目錄
            assets.srcDirs = ['assets']
            //指定res的目標目錄
            res.srcDirs = ['res']
            //指定依賴C文件的目標目錄
            jni.srcDirs = ['jni']
             //指定依賴so文件的目標目錄
            jniLibs.srcDirs = ['libs']
            //指定Manifest的目標文件路徑
            manifest.srcFile 'AndroidManifest.xml'
        }
 }複製代碼
  • 經常使用！ 給本身的layout分包管理！！ 
1. 在res下新建文件夾 layouts（其實叫什麼都無所謂）
2. 而後在 layouts下 新建你要分的包 如： activity，fragment 或按照業務模塊來分
3. 在分包內新建Android resource directory -> layout 不要更名字
4. 在module：build gradle 以下配置
5. 而後將之前的layout文件拷貝到對應分包的layout下就可使用了

PS:只有在Project目錄才能看到，Android目錄結構是看不到的

 sourceSets {
        main {
            res.srcDirs = [
                    'src/main/res/layouts/activity',
                    'src/main/res/layouts/fragment',
                    'src/main/res/layouts',
                    'src/main/res'

            ]
        }
    }複製代碼

productFlavors

打包渠道配置信息（仔細看代碼註釋）

//多渠道打包配置
//利用Manifest佔位符動態參數配置
productFlavors {
        baidu {
            manifestPlaceholders = [UMENG_CHANNEL_VALUE: "baidu"]
        }

        wandoujia {
            manifestPlaceholders = [UMENG_CHANNEL_VALUE: "wandoujia"]
        }

        googleplayer {
            manifestPlaceholders = [UMENG_CHANNEL_VALUE: "googleplayer"]
        }

        //不想每個都去配置渠道名稱也能夠用下面這個函數
        //這個函數能夠將 Manifest中的佔位符替換成 每一個渠道的名字
        productFlavors.all {
            flavor -> flavor.manifestPlaceholders = [UMENG_CHANNEL_VALUE: name]
        }
    }複製代碼

compileOptions

//編譯配置項
    //主要配置Java編譯版本
    compileOptions {
        sourceCompatibility org.gradle.api.JavaVersion.VERSION_1_8
        targetCompatibility org.gradle.api.JavaVersion.VERSION_1_8
    }複製代碼

lintOptions

//lint配置項
    lintOptions {

        //啓用出錯中止grgradle構建
      abortOnError false

      // true--檢查全部問題點，包含其餘默認關閉項
      checkAllWarnings true

      // 關閉指定問題檢查
      disable 'TypographyFractions','TypographyQuotes'
      // 打開指定問題檢查
      enable 'RtlHardcoded','RtlCompat', 'RtlEnabled'
      // 僅檢查指定問題
      check 'NewApi', 'InlinedApi'

      // true--生成HTML報告(帶問題解釋，源碼位置，等)
      htmlReport true
      // html報告可選路徑(構建器默認是lint-results.html )
      htmlOutput file("lint-report.html")

      // 忽略指定問題的規則(同關閉檢查)
      ignore 'TypographyQuotes'
    }複製代碼

build.gradle 圖形化配置

AndroidStuido 給咱們提供了十分友好地對於Build.gradle 圖形化配置的界面，使用以下：

  • File -> Project Structure -> 選擇須要配置的 Module —> 選擇須要配置的領域
    如圖十分直觀：

圖形化界面

dependencies 項目依賴

  1. build.gradle中dependencies中的配置解析
//dependencies ： 當前Android Module構建過程當中所依賴的全部庫
dependencies {
    //依賴指定目錄下全部指定後綴的文件
    compile fileTree(dir: 'libs', include: ['*.jar'])
    //測試工具依賴
    testCompile 'junit:junit:4.12'
    //遠程庫的依賴 （當從遠程庫中下載一次事後，就會緩存到本地了）
    //默認遠程庫配置爲 jcenter() 
    compile 'com.android.support:appcompat-v7:25.2.0'

    //依賴指定文件（這裏依賴的是jar包）
    compile file('libs/test-1.0.0.jar')
    //依賴本地項目庫
    compile project(':testLibrary')

    //格式： groupId: com.squareup.retrofit2
    // artifactId : retrofit
    // version: 2.1.0
    // SNAPSHOT : 表示依賴 retrofit 及其依賴的全部項目，若是他所依賴的項目在本項目中重複出現依賴，則只依賴retrofit項目中的。
    // @aar : 表示只依賴retrofit，不依賴他所依賴的項目
    compile ('com.squareup.retrofit2:retrofit:2.1.0-SNAPSHOT@aar')
    {
         //強制刷新遠程庫，避免遠程庫刷新，本地未更新
         transitive = true        
          //exclude : 單獨去除okhttp3的依賴
         exclude module ： 'com.squareup.okhttp3:okhttp:3.3.0' 
    }

}複製代碼

  1. so庫依賴

    • 在src/main目錄下建立jniLibs，而後將so文件拷貝進去就能夠了
    • 固然也能夠經過sourceSet指定jniLib的目標目錄來自定義管理依賴的so文件存放

  2. 本地Module依賴

    • 在build.gradle的dependencies 領域中添加 compile project(':testLibrary')
    • 在setting.gradle 中添加module到include中 如：include ':app',':testLibrary'

方法def定義

在Gradle中你能夠寫方法供 配置信息動態調用

//自定義函數
def getVersinCode() {
// ......
}

Android{
    defaultConfig{
        versionCode getVersinCode()
    }
}複製代碼

Gradle編譯提速優化

檢測

  • gradlew build -profile : 編譯工程同時生成編譯性能分析文件，在根目錄build/reports/profile/profile-xxxx.xxx....html ，經過瀏覽器打開之後
    如圖： 咱們須要優化的就是Task Execution

profile.html

  • 往下拉，能夠看到TaskExcution的詳細參數

TaskExcution

能夠看到lint耗時最多，而後咱們就能夠根據本身項目中的具體狀況來作優化

禁用Task達到提速

  • 根據上面的耗時來對應禁用Task來達到提速的效果
  • 在Project:build.gradle 中的 buildScript中動態配置編譯時禁用便可， 代碼：gradle.startParameter.excludedTaskNames.add('lint') 就能夠實現禁用了，具體須要繼續禁用的能夠根據項目輸出的編譯分析文件來做出添加和調整

AAPT

aapt即Android Asset Packaging Tool，在SDK的build-tools目錄下。該工具能夠查看，建立， 更新ZIP格式的文檔附件(zip, jar, apk)。也可將資源文件編譯成二進制文件，儘管你可能沒有直接使用過aapt工具，可是build scripts和IDE插件會使用這個工具打包apk文件構成一個Android 應用程序（百度百科）

  • 在Debug模式下，咱們須要優化AAPT來大量提速咱們的編譯(記得在release下改回來)
aaptOtions{
    cruncherEnabled = false
}複製代碼

Gradle編譯優化

  • 提高Gradle自己編譯速度
    • gradle.properties中配置
//開啓守護線程支持
org.gradle.daemon=true

//開啓並行編譯
org.gradle.parallel=true
//按需編譯
org.gradle.configureondemand=true

//手動配置Gradle編譯時內存分配
# Default value: -Xmx10248m -XX:MaxPermSize=256m
org.gradle.jvmargs=-Xmx2048m -XX:MaxPermSize=512m -XX:+HeapDumpOnOutOfMemoryError -Dfile.encoding=UTF-8

# 開啓JNI編譯支持過期API
android.useDeprecatedNdk=true複製代碼
  • build.gradle中配置 
//增長編譯內存到4g
dexOptions{
    incremental true    
    javaMaxHeapSize "4g"
}複製代碼

認識Task

  • Task基本使用：
task testTask << {

    println 'testTask << print'

    // 表示在task最前面來執行的過程
    doFirst {
        println 'testTask do first'}
    // << 和 doLast表示對當前task追加執行過程，效果是同樣的
    doLast{
        println 'testTask do last!'}
}

//task之間的依賴 dependsOn
//當執行存在依賴的task時，會先執行他的父類也就是依賴目標
task testDependsOn(dependsOn:testTask){
    println 'testDependsOn default print '
}
//或者
testDependsOn.dependsOn testTask
//當執行testDependsOn是 打印順序： testDependsOn default print -> testTask do first -> testTask << print -> testTask do last!
//順序總結爲：
//1.不加doLast和doFirst的最早執行
//2.依賴task優先級高於本身的doFirst和doLast
//3.同一個task中的doLast按從上向下順序執行
//4.同一個task中的doFirst按從下到上倒序執行
//5.同一個task的doFirst優先級高於doLast

//顯示聲明類型爲Copy， 不聲明默認爲defaultTask
task testCopy(type : Copy){
    //將當前gradle文件從src目錄拷貝到dst目錄
    from "src"
    into "dst"
}
//每個特定的Task類型還能夠含有特定的Property，好比Copy的from和to等。

//自定義property
ext.testProperty = ""

task testExtProperty << {
    //直接使用自定義的property
    println testProperty
}複製代碼
  • 自定義Task:
//局部自定義Task
//直接在build.gradle中自定義Task
//可是也只能在當前module中引用
class TestCustomTask extends DefaultTask {
    //@Optional，表示在配置該Task時，message是可選的。
    @Optional
    String message = 'I am jjx'
    //@TaskAction表示該Task要執行的動做,即在調用該Task時，hello()方法將被執行
    @TaskAction
    def hello() {
        println "hello world $message"
    }
}

//hello使用了默認的message值
task hello(type: TestCustomTask)

//從新設置了message的值
task helloOne(type: TestCustomTask) {
    message = "I am a android developer"
}


全局自定義Task
若是須要自定義大量的Task，就要新建一個Gradle文件來統一管理
經過apply來引入使用
//這是插件
apply plugin: 'com.android.application'
//這裏gradle-quality.gradle就是另外單獨定義了task的gradle
apply from: '../build-config/gradle-quality.gradle'複製代碼

自定義Plugin

自定義Plugin可讓咱們在工程編譯根據需求中自動去完成一些操做
下面就是一個編譯後自動打印當前時間的Plugin

build.gradle中直接定義

與自定義Task十分相似
能夠在build.gradle中自定義plugin
apply plugin: DateAndTimePlugin

dateAndTime {
    timeFormat = 'HH:mm:ss.SSS'
    dateFormat = 'MM/dd/yyyy'
}

class DateAndTimePlugin implements Plugin<Project> {
    //該接口定義了一個apply()方法，在該方法中，咱們能夠操做Project，
    //好比向其中加入Task，定義額外的Property等。
    void apply(Project project) {
        //加載Extension
        project.extensions.create("dateAndTime", DateAndTimePluginExtension)

        //使用Extension配置信息
        project.task('showTime') << {
            println "Current time is " + new Date().format(project.dateAndTime.timeFormat)
        }

        project.tasks.create('showDate') << {
            println "Current date is " + new Date().format(project.dateAndTime.dateFormat)
        }
    }
}
//每一個Gradle的Project都維護了一個ExtenionContainer，
//咱們能夠經過project.extentions進行訪問
//好比讀取額外的Property和定義額外的Property等。
//向Project中定義了一個名爲dateAndTime的extension
//並向其中加入了2個Property，分別爲timeFormat和dateFormat
class DateAndTimePluginExtension {
    String timeFormat = "MM/dd/yyyyHH:mm:ss.SSS"
    String dateFormat = "yyyy-MM-dd"
}複製代碼

工程中定義

其實本質上就是對上面的自定義Plugin結構化拆解

  1. Plugin目錄建立

    • 在根目錄下建立buildSrc
    • 子目錄結構以下：buildSrc/src/main/groovy/com/ray 和 buildSrc/src/main/resources/META-INF/gradle-plugins

  2. 建立buildSrc/build.gradle ， 配置以下

apply plugin:'groovy'

dependecies{
    compile gradleApi()
    compile localGroovy()
}複製代碼
  1. Plugin 邏輯實現
    自定義Plugin的主要實現邏輯
    在buildSrc/src/main/groovy/com/ray 下建立DateAndTimePlugin
class DateAndTimePlugin implements Plugin<Project> {
    void apply(Project project) {
        //加載Extension
        project.extensions.create("dateAndTime", DateAndTimePluginExtension)

        //使用Extension中的配置信息
        project.task('showTime') << {
            println "Current time is " + new Date().format(project.dateAndTime.timeFormat)
        }

        project.tasks.create('showDate') << {
            println "Current date is " + new Date().format(project.dateAndTime.dateFormat)
        }
    }
}複製代碼
  1. Extension實現
    Extension至關於Gradle配置信息（至關於實體類），而後主項目的build.gradle 經過Extension傳遞配置（至關於賦值）

一樣在buildSrc/src/main/groovy/com/ray下建立DateAndTimePluginExtension

//每一個Gradle的Project都維護了一個ExtenionContainer，
//咱們能夠經過project.extentions進行訪問
//好比讀取額外的Property和定義額外的Property等。
//向Project中定義了一個名爲dateAndTime的extension
//並向其中加入了2個Property，分別爲timeFormat和dateFormat
class DateAndTimePluginExtension {
    String timeFormat = "MM/dd/yyyyHH:mm:ss.SSS"
    String dateFormat = "yyyy-MM-dd"
}複製代碼

  1. Plugin命名
    自定義外部引用時Plugin的名字
    在buildSrc/src/main/resources/META-INF/gradle-plugins 下建立
    timePlugin.properties ,內容只有一行代碼 ： implementation-class = com.ray.DateAndTimePlugin

  2. Plugin的使用
    主項目中apply plugin:'timePlugin'
    可選：配置Extension : 

timePlugin{
    //動態修改和配置Extension屬性
    //這裏修改了日期格式
    timeFormat = 'MM/dd/yyyy'
}複製代碼

獨立Module自定義插件

  1. 新建plugin目錄結構如圖：

ModulePlugin目錄

  1. buildSrc/build.gradle的修改 以下：
apply plugin: 'groovy'
//增長Maven的支持
apply plugin: 'maven'

version = 1.0
group = 'com.ray.plugin'
archivesBaseName = 'timeplugin'
repositories.mavenCentral()

dependencies {
    compile gradleApi()
    groovy localGroovy()
}

//將插件部署到repo目錄下
uploadArchives {
    repositories.mavenDeployer {
        repository(url: uri('../repo'))
    }
}複製代碼
  1. 發佈：和其餘Module同樣發佈到中央庫中
  2. 使用插件，主項目中配置以下：
apply plugin: 'timePlugin'

buildscript {
    repositories {
        maven {
            url uri('../repo')
        } }
    dependencies {
        classpath group: 'com.ray.plugin', name: 'timePlugin',
                version: '1.0'
    }
}複製代碼

最後

以上就是總結的Gradle實用的進階指南，讓咱們能夠更加爲所欲爲地去管理咱們的工程。之後若是有一些新的認識或者想法，我也會在這裏實時更新的。也算是本身對Gradle認識和學習的總結整理吧。
正確使用Gradle的配置是爲了讓咱們開發更加便捷、效率更高，千萬不要本末倒置了。
文中哪裏有錯誤的話，歡迎你們指出糾正
若是文章對你有用的話，請點贊鼓勵一下哈O(∩_∩)O~~~~

參考和感謝如下博文和項目：

相關文章
相關標籤/搜索
每日一句
    每一个你不满意的现在，都有一个你没有努力的曾经。
本站公眾號
   歡迎關注本站公眾號,獲取更多信息
聯繫我們 最近搜索 最新文章 沪ICP备13005482号-10 MyBatis教程 SQL 教程 MySQL教程 Java 教程 Thymeleaf 教程 Hibernate教程 Spring教程 Redis教程