sql某個日期是當年的第幾周

/*
*週一做爲一週的開始
*當年的1月1號所在的周算做第一週
*/
CREATE function GetWeekIndexFirstDate
(
   @date datetime
)
returns int
as
begin
 
/*
*計算邏輯
*1.先找出當年的1月1號@firstDate
*2.計算出當年的第一個週日@firstSunday
*3.以@firstSunday爲分界線，@firstSunday前面的算做第一週，@firstSunday後面的經過除7再加1，來計算週數
*/
 
   declare @index int;
   declare @firstDate datetime;--當年的1月1號
   declare @firstSunday datetime;--當年的第一個週日
   declare @firstWeekSunday datetime;--當年的第一週的週日
 
   set @firstDate = convert(datetime,convert(varchar(4),Year(@date)) + '-1-1')
 
   set @firstSunday = case when datepart(dw,@firstDate)=1 then @firstDate else dateadd(dd,8-datepart(dw,@firstDate),@firstDate) end;
 
   if(@date<=@firstSunday)
      set  @index = 1;
   else
      set @index = ceiling(datediff(dd,@firstSunday,@date)/7.0)+1
 
   return @index;
end



 
 
/*
*週一做爲一週的開始
*當年的第一個週一所在的周算做第一週
*/
CREATE function GetWeekIndexFirstMonday
(
   @date datetime
)
returns int
as
begin
 
 
 
/*
*計算邏輯
*1.先找出當年的1月1號@firstDate
*2.計算出當年的第一個週一@firstMonday
*3.以@firstMonday爲分界線，@firstMonday前面的算做上一年的最後一週，@firstMonday後面的經過除7再加1，來計算週數
*/
 
   declare @index int;
   declare @firstDate datetime;--當年的1月1號
   declare @firstMonday datetime;--當年的第一個週一
   declare @lastYearFirstDate datetime;--上一年的1月1號
   declare @lastYearFirstMonday datetime;--上一年的第一個週一
 
   select @firstDate = convert(datetime,convert(varchar(4),Year(@date)) + '-1-1')
      , @lastYearFirstDate = convert(datetime,convert(varchar(4),datepart(yyyy,@date)-1) + '-1-1')
 
   select @firstMonday = case when datepart(dw,@firstDate)<=2 then dateadd(dd,2-datepart(dw,@firstDate) ,@firstDate)
                      else dateadd(dd,9-datepart(dw,@firstDate),@firstDate) end
      ,@lastYearFirstMonday = case when datepart(dw,@lastYearFirstDate)<=2 then dateadd(dd,2-datepart(dw,@lastYearFirstDate) ,@lastYearFirstDate)
                      else dateadd(dd,9-datepart(dw,@lastYearFirstDate),@lastYearFirstDate) end;
 



   if(@date >=@firstMonday)
      set  @index = floor(datediff(dd,@firstMonday,@date)/7.0)+1;
   else
      set @index = floor(datediff(dd,@lastYearFirstMonday,@date)/7.0)+1
 
   return @index;
end