操做系統-保護模式中的特權級下

Q:使用調用門如何實現不一樣特權級之間的跳轉？(從高到低)
在實際的使用中，調用門只支持從低特權級到高特權級執行，沒法利用調用門從高特權級跳轉到低特權級執行
A.調用門的特權級跳轉分析

左邊代碼段爲低特權級代碼段，利用調用門以及call指令(遠調用)能夠進入右邊高特權級代碼段，最後利用return (跳轉指令)far返回低代碼段。
實現思路
調用門的特權級跳轉-經過遠調用(call far)：低特權級到高特權級；經過遠返回(retf):高特權級到低特權級。
調用過程(近調用)以下

左邊代碼將ax bx寄存器值壓入棧，經過call指令直接調用段中func函數，call以後程序轉入func入口處執行，在此過程當中，eip寄存器會被壓入棧中，當ret指令執行時，從棧頂將eip寄存器以前的值拿出，恢復到eip寄存器中，執行完畢，程序執行流成功執行。
相同理，遠調用同樣，

實現過程
1.在實現以前須要知道的是,x86處理器對於不一樣的特權級須要使用不一樣的棧，每個特權級對應一個私有棧，特權級跳轉變化以前必須指定好相應的棧
2.從高特權級到低特權級實現:指定目標棧段選擇子，指定棧頂指針位置，指定目標代碼段選擇子，指定目標代碼段偏移，最後進行跳轉
代碼以下

%include "inc.asm"

org 0x9000

jmp ENTRY_SEGMENT

[section .gdt]
; GDT definition
;                                 段基址，       段界限，       段屬性
GDT_ENTRY       :     Descriptor    0,            0,           0
CODE32_DESC     :     Descriptor    0,    Code32SegLen - 1,    DA_C + DA_32 + DA_DPL3
VIDEO_DESC      :     Descriptor 0xB8000,     0x07FFF,         DA_DRWA + DA_32 + DA_DPL3
DATA32_DESC     :     Descriptor    0,    Data32SegLen - 1,    DA_DR + DA_32 + DA_DPL3
STACK32_DESC    :     Descriptor    0,     TopOfStack32,       DA_DRW + DA_32 + DA_DPL3
; GDT end

GdtLen    equ   $ - GDT_ENTRY

GdtPtr:
          dw   GdtLen - 1
          dd   0

; GDT Selector

Code32Selector     equ (0x0001 << 3) + SA_TIG + SA_RPL3
VideoSelector      equ (0x0002 << 3) + SA_TIG + SA_RPL3
Data32Selector     equ (0x0003 << 3) + SA_TIG + SA_RPL3
Stack32Selector    equ (0x0004 << 3) + SA_TIG + SA_RPL3

; end of [section .gdt]

TopOfStack16    equ 0x7c00

[section .s16]
[bits 16]
ENTRY_SEGMENT:
    mov ax, cs
    mov ds, ax
    mov es, ax
    mov ss, ax
    mov sp, TopOfStack16

    ; initialize GDT for 32 bits code segment
    mov esi, CODE32_SEGMENT
    mov edi, CODE32_DESC

    call InitDescItem

    mov esi, DATA32_SEGMENT
    mov edi, DATA32_DESC

    call InitDescItem

    mov esi, STACK32_SEGMENT
    mov edi, STACK32_DESC

    call InitDescItem

    ; initialize GDT pointer struct
    mov eax, 0
    mov ax, ds
    shl eax, 4
    add eax, GDT_ENTRY
    mov dword [GdtPtr + 2], eax

    ; 1. load GDT
    lgdt [GdtPtr]

    ; 2. close interrupt
    cli 

    ; 3. open A20
    in al, 0x92
    or al, 00000010b
    out 0x92, al

    ; 4. enter protect mode
    mov eax, cr0
    or eax, 0x01
    mov cr0, eax

    ; 5. jump to 32 bits code
    ; jmp dword Code32Selector : 0
    push Stack32Selector   ; 目標棧段選擇子
    push TopOfStack32      ; 棧頂指針位置
    push Code32Selector    ; 目標代碼段選擇子
    push 0                 ; 目標代碼段偏移
    retf

; esi    --> code segment label
; edi    --> descriptor label
InitDescItem:
    push eax

    mov eax, 0
    mov ax, cs
    shl eax, 4
    add eax, esi
    mov word [edi + 2], ax
    shr eax, 16
    mov byte [edi + 4], al
    mov byte [edi + 7], ah

    pop eax

    ret

[section .dat]
[bits 32]
DATA32_SEGMENT:
    DTOS               db  "D.T.OS!", 0
    DTOS_OFFSET        equ DTOS - $$

Data32SegLen equ $ - DATA32_SEGMENT

[section .s32]
[bits 32]
CODE32_SEGMENT:
    mov ax, VideoSelector
    mov gs, ax

    mov ax, Data32Selector
    mov ds, ax

    mov ax, Stack32Selector
    mov ss, ax

    mov eax, TopOfStack32
    mov esp, eax

    mov ebp, DTOS_OFFSET
    mov bx, 0x0C
    mov dh, 12
    mov dl, 33

    call PrintString;打印

    jmp $

; ds:ebp    --> string address
; bx        --> attribute
; dx        --> dh : row, dl : col
PrintString:
    push ebp
    push eax
    push edi
    push cx
    push dx

print:
    mov cl, [ds:ebp]
    cmp cl, 0
    je end
    mov eax, 80
    mul dh
    add al, dl
    shl eax, 1
    mov edi, eax
    mov ah, bl
    mov al, cl
    mov [gs:edi], ax
    inc ebp
    inc dl
    jmp print

end:
    pop dx
    pop cx
    pop edi
    pop eax
    pop ebp

    ret

Code32SegLen    equ    $ - CODE32_SEGMENT

[section .gs]
[bits 32]
STACK32_SEGMENT:
    times 1024 * 4 db 0

Stack32SegLen equ $ - STACK32_SEGMENT
TopOfStack32  equ Stack32SegLen - 1

代碼實現結果

爲了更好了解從高特權級到低特權級的轉換，首先經過反編譯找到關鍵的跳轉指令，並設置斷點進行單步調試，如圖所示，在跳轉以前查看寄存器cx值，發現最後2爲0,繼續單步調試，在程序跳轉到[section .s32][bits 32]部分時，再對寄存器進行查看，發現此時cx寄存器的值的二級制最後兩位11，爲3。此時能夠得知從高特權級到低特權級進行了轉移。

小結
1.調用門只支持從低特權級跳轉到高特權級執行
2.利用遠返回(retf)能夠從高特權級轉移到低特權級
3.x86處理器中每個特權級對應一個私有的棧
4.特權級跳轉以前必須指定好相應的棧