Caffe2的安裝

源碼下載

首先下載caffe2的源碼：https://github.com/caffe2/caffe2

網上都建議使用git命令下載，由於caffe2依賴了不少第三方模塊，git會根據依賴自動下載第三方依賴模塊。可是我在下載過程當中發現不少第三方模塊的地址變了，所以git方式沒法完成第三方模塊的下載。所以，下載好caffe2源碼後，須要手動完成這些模塊的下載。這些模塊的默認地址在caffe2/.gitmodules文件內。

Windows下編譯安裝

編譯工程

　　在windows下能夠編譯成VS的工程文件，我用的是VS2017，修改caffe2/scripts/build_windows.bat文件內容以下：

:: #############################################################################
:: Example command to build on Windows.
:: #############################################################################

:: This script shows how one can build a Caffe2 binary for windows.

@echo off
setlocal

SET ORIGINAL_DIR=%cd%
SET CAFFE2_ROOT=%~dp0%..

if NOT DEFINED CMAKE_BUILD_TYPE (
  set CMAKE_BUILD_TYPE=Release
)

if NOT DEFINED USE_CUDA (
  set USE_CUDA=OFF
)

if NOT DEFINED CMAKE_GENERATOR (
  if DEFINED APPVEYOR_BUILD_WORKER_IMAGE (
    if "%APPVEYOR_BUILD_WORKER_IMAGE%" == "Visual Studio 2017" (
      set CMAKE_GENERATOR="Visual Studio 15 2017 Win64"
    ) else if "%APPVEYOR_BUILD_WORKER_IMAGE%" == "Visual Studio 2015" (
      set CMAKE_GENERATOR="Visual Studio 14 2015 Win64"
    ) else (
      echo "You made a programming error: unknown APPVEYOR_BUILD_WORKER_IMAGE:"
      echo %APPVEYOR_BUILD_WORKER_IMAGE%
      exit /b
    )
  ) else (
    :: In default we use win64 VS 2015.
    :: Main reason is that currently, cuda 9 does not support VS 2017 newest
    :: version. To use cuda you will have to use 2015.
    set CMAKE_GENERATOR="Visual Studio 15 2017 Win64"
  )
)

echo CAFFE2_ROOT=%CAFFE2_ROOT%
echo CMAKE_GENERATOR=%CMAKE_GENERATOR%
echo CMAKE_BUILD_TYPE=%CMAKE_BUILD_TYPE%

if not exist %CAFFE2_ROOT%\build mkdir %CAFFE2_ROOT%\build
cd %CAFFE2_ROOT%\build

:: Set up cmake. We will skip building the test files right now.
:: TODO: enable cuda support.
cmake .. ^
  -G%CMAKE_GENERATOR% ^
  -DBUILD_TEST=OFF ^
  -DCMAKE_BUILD_TYPE=%CMAKE_BUILD_TYPE% ^
  -DUSE_CUDA=%USE_CUDA% ^
  -DUSE_NNPACK=OFF ^
  -DUSE_CUB=OFF ^
  -DUSE_GLOG=OFF ^
  -DUSE_GFLAGS=OFF ^
  -DUSE_LMDB=OFF ^
  -DUSE_LEVELDB=OFF ^
  -DUSE_ROCKSDB=OFF ^
  -DUSE_OPENCV=OFF ^
  -DBUILD_SHARED_LIBS=OFF ^
  -DBUILD_PYTHON=OFF^
  || goto :label_error

:: Actually run the build
cmake --build . --config %CMAKE_BUILD_TYPE% || goto :label_error

echo "Caffe2 built successfully"
cd %ORIGINAL_DIR%
endlocal
exit /b 0

:label_error
echo "Caffe2 building failed"
cd %ORIGINAL_DIR%
endlocal
exit /b 1

而後打開VS2017的開發人員命令提示符，執行「build_windows.bat」便可。

等待一段時間後，便在caffe2/build下生產不少VS的工程文件。

Caffe2的安裝

以管理員運行VS2017，並使用VS打開caffe2/build/Caffe2.sln，打開後右鍵「INSTALL」項目並點擊生成，便會執行caffe2庫的編譯和安裝，默認安裝目錄爲C:\Program Files\Caffe2，能夠修改caffe2/build/cmake_install.cmake的第5行來更改caffe2的安裝路徑。

VS下使用caffe2

使用前須要把caffe2/build/lib/Release下的全部庫文件拷貝到C:\Program Files\Caffe2\lib（至於什麼緣由，我也不知道，多是默認安裝的庫文件不全）。

新建的工程須要注意如下屬性的配置：

（1）包含目錄

 

（2）庫目錄

 

（3）附加依賴項

  

（4）SDL檢查

 

 

（5）運行庫

 

 

Linux下的編譯和安裝

進入caffe2/scripts目錄，執行「sh build_local.sh」，而後進入caffe2/build目錄，執行"sudo make install"便可。