SQL Server 大數據搬遷之文件組備份還原實戰

一.本文所涉及的內容（Contents）

1. 本文所涉及的內容（Contents）
2. 背景（Contexts）
3. 解決方案（Solution）
4. 搬遷步驟（Procedure）
5. 搬遷腳本（SQL Codes）
6. 注意事項（Attention）
7. 疑問（Questions）
8. 參考文獻（References）

二.背景（Contexts）

　　有一個數據庫大概在700G左右，須要從服務器A搬遷到服務器B，兩臺服務器網絡傳輸速度能夠達到8MB/s，怎麼作才能更快的搬遷而且宕機時間最短呢？

　　數據庫業務邏輯概述：這個數據庫只會插入數據，天天大概有300W條數據，不會對數據進行修改，只有一個表比較大，而且這個表是以自增ID做爲分區依據列的，文件組會被重用，數據庫爲簡單恢復模式，我定時會對錶數據進行交換分區刪除數據；

三.解決方案（Solution）

以前我也寫過關於搬遷數據庫的一些文章：

　　1. SQL Server 數據庫最小宕機遷移方案，這篇文章是經過徹底備份+差別備份的方式遷移數據庫的，這種方式比較合適數據庫只有20G左右的數據庫，宕機時間=差別備份時間+傳輸差別備份時間+還原差別備份時間，通常來講這個時間都比較短，由於差別備份都不會太大；

　　2. SQL Server 數據庫遷移偏方，這篇文章是經過做業的方式遷移數據庫的，一個事務中轉移N條（大約2W條）數據，N值能夠經過測試進行調整（須要看網絡狀況而定），這種方式比較適合數據庫比較大，好比幾百G的數據庫，並且網絡環境比較差的狀況下，宕機時間≈0（當轉移最後一部分數據足夠小），缺點就是遷移的時間會比較長；

　　3. 那麼這篇文章咱們再來說講其它方式的遷移，在上面提到的背景下，能夠經過對分區文件組進行備份的方式遷移數據庫，這種方式比較適合大數據庫的遷移，宕機時間=最後一個文件組備份時間+傳輸備份時間+還原最後一個文件組時間，缺點是宕機時間會比較大，可是總體遷移的時間會比較小；下面是邏輯結構圖：

（Figure1：文件組搬遷邏輯圖）

四.搬遷步驟（Procedure）

　　在講述搬遷步驟以前，咱們首先來看看文件組的大致狀況，經過下面的SQL語句能夠查看文件組的相關信息，見Figure二、Figure3；

--查看文件組信息
SELECT df.[name], df.physical_name, df.[size], df.growth, fg.[name]
[filegroup], fg.is_default
FROM sys.database_files df
JOIN sys.filegroups fg
ON df.data_space_id = fg.data_space_id

（Figure2：文件組列表）

（Figure3：文件組列表）

下面就講講搬遷的步驟：

1. 首先咱們先清理下數據，把沒必要要的數據經過交換分區的方式交換出去；

2. 查看這張大表當前的自增ID值，經過修改分區方案讓新插入的數據存入到一個空的文件組（由於空的文件組在最後備份會更小一點），不少狀況下，文件組是會重用的，因此要注意這個文件組是空的；

3. 設置數據庫爲完整恢復模式；

4. 備份除了上面提到的文件組，若是條件容許能夠進行備份的壓縮；（動態生成SQL）

5. 經過FTP傳輸備份文件到新的服務器；

6. 備份主分區，須要確保這個時候不會對主分區的數據進行修改，並傳輸主分區備份文件；

7. 先還原主分區的備份，再還原上面的文件組備份；（動態生成SQL）

8. 對最後一個文件組進行備份，對日誌進行備份，對沒有作分區對齊的索引文件組進行備份，把這3個備份傳輸到新服務器；

9. 還原文件組，還原日誌；

五.搬遷腳本（SQL Codes）

搬遷腳本包括兩個部分，一個備份使用的腳本，一個是還原使用的腳本：

1. 備份腳本，根據分區狀況來自動生成對應的備份腳本；

2. 還原腳本，根據分區狀況和備份文件的規則來生成對應的還原腳本，也就是說還原腳本是依據備份腳本的；

 

(一) 下面是用於生成備份SQL的代碼，這個代碼須要提供兩個變量值：

1. @DataBaseName指定須要進行備份的數據庫名，值爲'Barefoot.Archives'；

2. @BackupPath在舊服務器本地備份文件組存放的地址，值爲：'E:\DBBackup\'；

在舊數據庫Barefoot.Archives中執行下面的SQL腳本：

-- =============================================
-- Author:      <聽風吹雨>
-- Blog:        <http://gaizai.cnblogs.com/>
-- Create date: <2014/02/26>
-- Description: <生成分區備份腳本>
-- =============================================
DECLARE @DataBaseName SYSNAME--數據庫名稱
DECLARE @BackupPath SYSNAME--保存分區備份的路徑
DECLARE @FilegroupName SYSNAME--分區文件組名稱
DECLARE @sql NVARCHAR(MAX)--sql字符串

--設置下面變量
SET @DataBaseName = 'DataBaseName'
SET @BackupPath = 'D:\DBBackup\'

--1.設置完整模式
PRINT '--設置完整模式'
SET @sql = 'USE [master]
GO
ALTER DATABASE ['+@DataBaseName +'] SET RECOVERY FULL WITH NO_WAIT
GO'
PRINT @sql + CHAR(13)

--2.備份分區
DECLARE @itemCur CURSOR
SET @itemCur = CURSOR FOR
    SELECT [name] FROM sys.filegroups ORDER BY is_default

OPEN @itemCur
FETCH NEXT FROM @itemCur INTO @FilegroupName
WHILE @@FETCH_STATUS=0
BEGIN
    --邏輯處理
    PRINT '--備份分區- ' + @FilegroupName
    SET @sql = 'BACKUP DATABASE [' + @DataBaseName + ']
FILEGROUP = ''' + @FilegroupName + '''
TO DISK = ''' + @BackupPath+@FilegroupName + '.bak'' WITH FORMAT
GO'
    PRINT @sql + CHAR(13)
    
    FETCH NEXT FROM @itemCur INTO @FilegroupName
END 

CLOSE @itemCur
DEALLOCATE @itemCur

--3.備份日誌
PRINT '--備份日誌'
SET @sql = 'BACKUP LOG [' + @DataBaseName + ']
TO DISK = ''' + @BackupPath+@DataBaseName + '_Log.bak'' WITH FORMAT
GO'
PRINT @sql + CHAR(13)

上面SQL腳本的邏輯是：

1. 首先設置數據庫的恢復模式爲完整恢復模式，這是爲了後面對數據庫的日誌進行備份；

2. 經過當前數據庫的系統表sys.filegroups拿到文件組的名稱，這裏把默認文件排在最後面，這是由於有可能會對配置表進行的操做，因此把這個文件組放到最後備份；

3. 使用遊標的方式來循環文件組，生成文件組對應的備份SQL語句；

4. 最後備份數據庫的日誌，對文件組的還原是須要經過日誌備份才能還原的；

 

　　在舊數據庫執行上面的SQL腳本，將會產生生成下面的SQL（只保留了部分SQL）：

--設置完整模式
USE [master]
GO
ALTER DATABASE [DataBaseName] SET RECOVERY FULL WITH NO_WAIT
GO

--備份分區- FG_Archive_Id_01
BACKUP DATABASE [DataBaseName]
FILEGROUP = 'FG_Archive_Id_01'
TO DISK = 'D:\DBBackup\FG_Archive_Id_01.bak' WITH FORMAT
GO

--備份分區- FG_Archive_Id_02
BACKUP DATABASE [DataBaseName]
FILEGROUP = 'FG_Archive_Id_02'
TO DISK = 'D:\DBBackup\FG_Archive_Id_02.bak' WITH FORMAT
GO

--備份分區- FG_Archive_Index
BACKUP DATABASE [DataBaseName]
FILEGROUP = 'FG_Archive_Index'
TO DISK = 'D:\DBBackup\FG_Archive_Index.bak' WITH FORMAT
GO

--備份分區- PRIMARY
BACKUP DATABASE [DataBaseName]
FILEGROUP = 'PRIMARY'
TO DISK = 'D:\DBBackup\PRIMARY.bak' WITH FORMAT
GO

--備份日誌
BACKUP LOG [DataBaseName]
TO DISK = 'D:\DBBackup\Barefoot.Archives_Log.bak' WITH FORMAT
GO

執行完上面的腳本，會生成下圖所示的備份文件：

（Figure4：備份文件列表）

 

(二) 下面是用於生成還原SQL的代碼，這個代碼須要提供幾個變量值：

1. @DataBaseName指定須要進行備份的數據庫名，值爲'Barefoot.Archives'；

2. @BackupPath在新服務器文件組備份的地址，值爲：'E:\DBBackup\'；

3. @SavePath_Drive存在數據文件的盤符，值爲：'F:\'；

4. @SavePath_FolderName存放數據文件的文件夾，值爲：'DataBase\'；

5. @SavePath_SubFolderName存放ndf文件的文件夾，值爲：'FG_Archive\'；

6. @IsSamePath表示是否延續以前的physical_name值，值爲1表示延續，這樣會使用@SavePath_Drive替換physical_name的盤符，這樣@SavePath_FolderName和@SavePath_SubFolderName就不會起做用了，值爲0表示不延續，這樣physical_name的值=@SavePath_Drive+@SavePath_FolderName+@SavePath_SubFolderName；

在舊數據庫Barefoot.Archives中執行下面的SQL腳本：

-- =============================================
-- Author:      <聽風吹雨>
-- Blog:        <http://gaizai.cnblogs.com/>
-- Create date: <2014/02/26>
-- Description: <生成分區還原腳本>
-- =============================================
DECLARE @DataBaseName SYSNAME--數據庫名稱
DECLARE @BackupPath SYSNAME--保存備份文件的路徑
DECLARE @SavePath_Drive SYSNAME--保存數據庫文件的盤符
DECLARE @SavePath_FolderName SYSNAME--保存數據庫的文件夾
DECLARE @SavePath_SubFolderName SYSNAME--保存分區的文件夾
DECLARE @FilegroupName SYSNAME--分區文件組名稱
DECLARE @FileName SYSNAME--分區文件名稱
DECLARE @PhysicalName SYSNAME--物理路徑
DECLARE @IsSamePath INT--是否跟遠路徑同樣1,0
DECLARE @sql NVARCHAR(MAX)--sql字符串

--設置下面變量
SET @DataBaseName = 'DataBaseName'
SET @BackupPath = 'E:\DBBackup\'
SET @SavePath_Drive = 'F:\'
SET @SavePath_FolderName = 'DataBase\'
SET @SavePath_SubFolderName = 'FG_Archive\'
SET @IsSamePath = 1

--1.還原主分區
SELECT @FilegroupName = [name] FROM sys.filegroups WHERE is_default = 1
PRINT '--還原主分區'
SET @sql = 'RESTORE DATABASE [' + @DataBaseName + ']
FILEGROUP = ''' + @FilegroupName + '''
FROM DISK = ''' + @BackupPath + @FilegroupName + '.bak'' WITH FILE = 1, 
MOVE N''' + @DataBaseName + ''' TO N''' + @SavePath_Drive + @SavePath_FolderName + @DataBaseName + '.mdf'',  
MOVE N''' + @DataBaseName + '_log'' TO N''' + @SavePath_Drive + @SavePath_FolderName + @DataBaseName + '_log.ldf'',
NORECOVERY,REPLACE,STATS = 10
GO'
PRINT @sql + CHAR(13)

--2.還原分區
DECLARE @itemCur CURSOR
SET @itemCur = CURSOR FOR
    SELECT df.[name] AS FileName, df.physical_name, fg.[name] AS FilegroupName
        FROM sys.database_files df
        JOIN sys.filegroups fg
        ON df.data_space_id = fg.data_space_id
     WHERE fg.is_default = 0

OPEN @itemCur
FETCH NEXT FROM @itemCur INTO @FileName,@PhysicalName,@FilegroupName
WHILE @@FETCH_STATUS=0
BEGIN
    --邏輯處理
    PRINT '--還原分區- ' + @FilegroupName
    IF @IsSamePath = 0
        SET @PhysicalName = @SavePath_Drive + @SavePath_FolderName + @SavePath_SubFolderName + '\' + @FileName + '.ndf'
    ELSE
        SET @PhysicalName = @SavePath_Drive + SUBSTRING(@PhysicalName,CHARINDEX('\',@PhysicalName)+1,LEN(@PhysicalName))
    SET @sql = 'RESTORE DATABASE [' + @DataBaseName + ']
FILEGROUP = ''' + @FilegroupName + '''
FROM DISK = ''' + @BackupPath+@FilegroupName + '.bak'' WITH FILE = 1, 
MOVE N''' + @FileName + ''' 
TO N''' + @PhysicalName + ''',
NORECOVERY
GO'
    PRINT @sql + CHAR(13)
    
    FETCH NEXT FROM @itemCur INTO @FileName,@PhysicalName,@FilegroupName
END 

CLOSE @itemCur
DEALLOCATE @itemCur

--3.還原日誌
PRINT '--還原日誌'
SET @sql = 'RESTORE LOG [' + @DataBaseName + ']
FROM DISK = ''' + @BackupPath + @DataBaseName + '_Log.bak''
WITH NORECOVERY
GO'
PRINT @sql + CHAR(13)

--4.還原在線
PRINT '--還原在線'
SET @sql = 'RESTORE DATABASE [' + @DataBaseName + ']
WITH RECOVERY
GO'
PRINT @sql + CHAR(13)

上面SQL腳本的邏輯是：

1. 經過系統表sys.filegroups找到默認文件組，先還原這個主文件；

2. 使用遊標的方式來循環系統表sys.filegroups，拿到文件組名稱，生成文件組對應的還原SQL語句；

3. 接着還原數據庫的日誌；

4. 最後還原在線，讓數據庫在線；

 

執行上面的SQL腳本，將會產生生成下面的SQL（只保留了部分SQL）：

--還原主分區
RESTORE DATABASE [DataBaseName]
FILEGROUP = 'PRIMARY'
FROM DISK = 'E:\DBBackup\PRIMARY.bak' WITH FILE = 1, 
MOVE N'Barefoot.Archives' TO N'F:\DataBase\Barefoot.Archives.mdf',  
MOVE N'Barefoot.Archives_log' TO N'F:\DataBase\Barefoot.Archives_log.ldf',
NORECOVERY,REPLACE,STATS = 10
GO

--還原分區- FG_Archive_Id_01
RESTORE DATABASE [DataBaseName]
FILEGROUP = 'FG_Archive_Id_01'
FROM DISK = 'E:\DBBackup\FG_Archive_Id_01.bak' WITH FILE = 1, 
MOVE N'FG_Archive_Id_01_data' 
TO N'F:\DataBase\FG_Archive\FG_Archive_Id_01_data.ndf',
NORECOVERY
GO

--還原分區- FG_Archive_Id_02
RESTORE DATABASE [DataBaseName]
FILEGROUP = 'FG_Archive_Id_02'
FROM DISK = 'E:\DBBackup\FG_Archive_Id_02.bak' WITH FILE = 1, 
MOVE N'FG_Archive_Id_02_data' 
TO N'F:\DataBase\FG_Archive\FG_Archive_Id_02_data.ndf',
NORECOVERY
GO

--還原分區- FG_Archive_Index
RESTORE DATABASE [DataBaseName]
FILEGROUP = 'FG_Archive_Index'
FROM DISK = 'E:\DBBackup\FG_Archive_Index.bak' WITH FILE = 1, 
MOVE N'FG_Archive_Index_data' 
TO N'F:\DataBase\Barefoot.Archives\FG_Archive_Index_data.ndf',
NORECOVERY
GO

--還原日誌
RESTORE LOG [DataBaseName]
FROM DISK = 'E:\DBBackup\Barefoot.Archives_Log.bak'
WITH NORECOVERY
GO

--還原在線
RESTORE DATABASE [DataBaseName]
WITH RECOVERY
GO

在新服務器上執行上面的SQL腳本還原數據庫，須要注意的是：在還原在線以前數據庫都是一直處於：正在還原的狀態的；

六.注意事項（Attention）

1. 在實際運用中，能夠結合本文和SQL Server 數據庫遷移偏方進行靈活結合運用，當經過本文件組備份後，舊庫繼續進數據，在花銷時間最大的網絡傳輸過程和還原過程繼續對老庫進數據，這樣當還原好數據庫以後使用SQL Server 數據庫遷移偏方來轉移最新的數據，這樣宕機的時間會趨向於0；

2. 其實爲了確保某些文件組不被修改，能夠設置文件組的只讀屬性，這樣能夠確保只有某個文件組在進新數據，惋惜的是設置了只讀也沒法拷貝這些文件組文件經過FTP傳輸，提示：操做沒法完成，由於文件已在SQL Server（MSSQLSERVER）中打開。

3. 上面腳本的每一個文件組中只包含了一個文件，若是一個文件組包含多個文件，那就須要修改下腳本了；

4. 高文佳曾經說過，能夠先刪除索引，再壓縮備份，還原以後再建立索引，是的，這不防是一個好方法，不過須要考慮兩點，一個是在還原以後建立索引的速度與時間，若是磁盤速度不算快，那你就要考慮刪除索引是否適合了；另一點是你的數據庫是否能停機讓你刪除索引，這個跟具體的業務有關；

七.疑問（Questions）

　　1. 對primary進行完整文件組備份（做爲基備份），對FG1進行完整文件組備份（做爲基備份）這些描述有問題吧？對primary進行完整文件組備份應該不會生成基線的吧？ SQL文件組備份和還原

　　2. 若是在同一個文件組中有兩個以上的分區值，就是把兩個段的分區方案中同指向同一個分區文件組，那在備份和還原有什麼須要注意的呢？能成功備份還原嘛？

--備份分區
DECLARE @FileName VARCHAR(200)
SET @FileName = 'G:\DBBackup\FG_Archive_Id_05_null.bak'
BACKUP DATABASE [DataBaseName]
FILEGROUP='FG_Archive_Id_05' TO DISK=@FileName WITH FORMAT
GO

--還原分區
RESTORE DATABASE [DataBaseName]
FILEGROUP='FG_Archive_Id_05' FROM DISK='E:\DBBackup\FG_Archive_Id_05_null.bak' WITH  FILE = 1, 
MOVE N'FG_Archive_Id_05_data' TO N'E:\DataBase\FG_Archive\FG_Archive_Id_05_data.ndf',  
NORECOVERY
GO

　　解答：從備份和還原的代碼能夠看出只是把FILEGROUP與bak對應，與ndf文件對應，因此是不須要理會這個文件組中包含了多少個邏輯分區；

八.參考文獻（References）

SQL文件組備份和還原

Sql Server 系統表分析(1) - 備份表

如何還原到故障點 (Transact-SQL)

backupset (Transact-SQL)