動態建立Fastreport分如下幾個步驟

動態建立Fastreport分如下幾個步驟：

1.首先清空Fastreport，定義全局變量，並加載數據集
   frReport.Clear;
   frReport.DataSets.Add(frxDBDataset1);
   DataHeight :=28;
   DataWidth :=80;
   FirstTop := 50;
   FirstLeft := 15;

2.建立frxReportPage,並設置紙張大小
  Page := TfrxReportPage.Create(frReport);
  Page.CreateUniqueName;
  page.Orientation := poLandscape;
  Page.SetDefaults;  //默認大小
  //Page.PaperWidth := 210;
  //Page.PaperHeight := 297;

  //如下爲動態設置紙張大小

  {if (qryPrn.FieldCount-4)<=6 then   //當列小於6
  begin
    Page.PaperWidth := 210;
    Page.PaperHeight := 279.4;
    page.Orientation := poPortrait;
  end
  else
  begin
    page.Orientation := poLandscape;
    iWidth := 40+85+90+(qryPrn.FieldCount-4)*84+30;

    //fr01cm=3.77953;
    if iWidth<297*fr01cm then  

    //fr01cm爲frxClass中定義的常量，爲每毫米像素值,或PerMillPix :=     25.38/Screen.PixelsPerInch;(25.38爲每英寸毫米數)
    begin
      Page.PaperSize :=DMPAPER_A4;   //設置爲A4,由於激光打印機不支持自定義紙張的橫打
    end
    else
    begin
      Page.PaperWidth :=iWidth/fr01cm;
      Page.PaperHeight := 210;
    end;
  end;}
  
3.生成PageBand,並指定高度
  Band := TfrxPageHeader.Create(Page);        //頁首
  Band.Top := 10;
  Band.Height := 150;
  
  BandFoot := TfrxColumnFooter.Create(Page);   //頁腳
  BandFoot.Top := 10;
  BandFoot.Height := 50;
  
4.畫頁腳欄
  //畫操做員
  memFoot := TfrxMemoView.Create(BandFoot);
  with memFoot do
  begin
    CreateUniqueName;
    HAlign := haLeft;
    VAlign := vaCenter;
    Memo.Text := '操做員：程序員';
    SetBounds(40, 10, 150, 20);
    ParentFont := False;
    Font.Name := '宋體';
    Font.Size := 10;
  end;

  //畫打印時間
  memFoot := TfrxMemoView.Create(BandFoot);
  with memFoot do
  begin
    CreateUniqueName;
    Align := baLeft;
    HAlign := haLeft;
    VAlign := vaCenter;
    Memo.Text := '打印時間：' + FormatDateTime('yyyy-mm-dd hh:mm:ss', Now);
    SetBounds(280, 10, 270, 20);
    ParentFont := False;
    Font.Name := '宋體';
    Font.Size := 11;
  end;
  
5.畫標題欄
  //畫標題
  Memo := TfrxMemoView.Create(Band);
  with Memo do
  begin
    CreateUniqueName;
    Align := baCenter;
    Memo.Text := '******餘額彙總表';
    Frame.Typ :=[ftBottom];
    Frame.BottomLine.Style :=fsDouble;   //行類型 
    Top := FirstTop;
    Height := 30;
    AutoWidth :=True;
    HAlign := haCenter;
    ParentFont := False;
    Font.Name := '黑體';
    Font.Size := 16;
  end;  
  
  //畫單位
  Memo := TfrxMemoView.Create(Band);
  with Memo do
  begin
    CreateUniqueName;
    HAlign := haLeft;
    VAlign := vaCenter;
    Memo.Text := '單位：************';
    FirstTop := FirstTop + 40;
    FirstWidth := 200;
    FirstHeight := 30;
    SetBounds(40, FirstTop, FirstWidth, FirstHeight);
    ParentFont := False;
    Font.Name := '宋體';
    Font.Size := 10;
  end;

  //畫日期
  Memo := TfrxMemoView.Create(Band);
  with Memo do
  begin
    CreateUniqueName;
    Align := baLeft;
    VAlign := vaCenter;
    HAlign := haLeft;
    Memo.Text := '日期：' + FormatDateTime('yyyy-mm-dd', Date);
    FirstWidth := 10 + FirstWidth + 200;
    FirstLeft := FirstLeft + FirstWidth;
    SetBounds(FirstLeft, FirstTop, 200, FirstHeight);
    ParentFont := False;
    Font.Name := '宋體';
    Font.Size := 10;
  end;

  //畫頁碼
  Memo := TfrxMemoView.Create(Band);
  with Memo do
  begin
    CreateUniqueName;
    Align := baLeft;
    HAlign := haLeft;
    VAlign := vaCenter;
    Memo.Text := '第[Page#]/[TotalPages#]頁';     //[]中括起來的是FastReport系統變量
    FirstWidth := 10 + FirstWidth;
    FirstLeft := FirstLeft + 200;
    SetBounds(FirstLeft, FirstTop, 100, FirstHeight);
    HAlign := haCenter;
    ParentFont := False;
    Font.Name := '宋體';
    Font.Size := 10;
  end;  
  
  for i := 1 to qryPrn.FieldCount - 4 do
  begin
    //畫數據集的標題
    Memo := TfrxMemoView.Create(Band);
    Memo.CreateUniqueName;
    Memo.ParentFont := False;
    Memo.Font.Name := '宋體';
    Memo.Font.Size := 10;
    Memo.Text := qryPrn.Fields[i + 3].FieldName;
    Memo.Frame.Typ := [ftTop, ftBottom, ftRight];
    Memo.SetBounds(220 + (i - 1) * DataWidth, Band.Height - DataHeight, DataWidth, DataHeight);
    Memo.HAlign := haCenter;
    Memo.VAlign := vaCenter;
  end;
  
6.畫數據集
  DataBand := TfrxMasterData.Create(Page);
  DataBand.CreateUniqueName;
  DataBand.DataSet := frxDBDataset1;
  DataBand.Top := 200;
  DataBand.Height := DataHeight;

  Memo1 := TfrxMemoView.Create(DataBand);
  with Memo1 do
  begin
    CreateUniqueName;
    ParentFont := False;
    SetBounds(30, 0, 90, DataHeight);
    VAlign := vaCenter;
    HAlign := haLeft;
    Font.Name := '宋體';
    Font.Size := 10;
    DataSet := frxDBDataset1;
    DataField := 'locus';
    Frame.Typ := [ftRight, ftBottom, ftLeft];
  end;

  Memo1 := TfrxMemoView.Create(DataBand);   
  with Memo1 do
  begin
    CreateUniqueName;
    ParentFont := False;
    SetBounds(120, 0, 100, DataHeight);
    VAlign := vaCenter;
    HAlign := haRight;
    Font.Name := '宋體';
    Font.Size := 10;
    DataSet := frxDBDataset1;
    DataField := 'TotalMoney';
    Frame.Typ := [ftRight, ftBottom];     //加上右邊和底部的邊框
  end;

  for i := 1 to qryPrn.FieldCount - 4 do
  begin
    Memo1 := TfrxMemoView.Create(DataBand);
    Memo1.CreateUniqueName;
    Memo1.ParentFont := False;
    Memo1.SetBounds(220 + (i - 1) * DataWidth, 0, DataWidth, DataHeight);
    Memo1.DisplayFormat.DecimalSeparator := '.';
    //Memo1.ExpressionDelimiters := ',';
    //Memo1.DisplayFormat.FormatStr := '%2.2f';  定義顯示格式
    //Memo1.DisplayFormat.Kind := fkNumeric;
    Memo1.VAlign := vaCenter;
    Memo1.HAlign := haRight;
    Memo1.Font.Name := '宋體';
    Memo1.Font.Size := 10;
    Memo1.DataSet := frxDBDataset1;
    Memo1.DataField := qryPrn.Fields[i + 3].FieldName;
    Memo1.Frame.Typ := [ftRight, ftBottom];
  end;  
  
7.顯示
  frReport.PrepareReport();
  frReport.ShowReport();  
 

8.將以上代碼用函數表示

(1)定義

TBandType=(PageHeader,PageFooter);

procedure CreatePage(var 　  　　　　　　　Page:TfrxReportPage;frxReport:TfrxReport;iWidth,iHeight:Double;pDirect:TPrinterOrientation);
procedure CreateBand(var band:TfrxBand;Page:TfrxReportPage;iTop,iHeight:Double;BandType:TBandType);
    procedure CreateDataBand(var band:TfrxMasterData;Page:TfrxReportPage;DbSet:TfrxDBDataset;iTop,iHeight:Integer);
    procedure CreateMemoData(var memView: TfrxMemoView; Band: TfrxBand;
      iLeft, iTop, iWidth, iHeight: Extended; fontname: string; fontsize: Integer;
      Halign: TfrxHAlign; Valign: TfrxVAlign; frxData: TfrxDBDataset; DField: string;
      FrameType: TfrxFrameTypes; Delimiters, ForStr: string; fkKind: TfrxFormatKind);
    procedure CreateMemo(var memView: TfrxMemoView; Band: TfrxBand;
      iLeft, iTop, iWidth, iHeight: Extended; fontname: string; fontsize: Integer;
      Halign: TfrxHAlign; Valign: TfrxVAlign; FrameType: TfrxFrameTypes; sText: string);

(2)實現

procedure TForm1.CreatePage(var Page: TfrxReportPage;
  frxReport: TfrxReport; iWidth, iHeight: Double;
  pDirect: TPrinterOrientation);
begin
  Page := TfrxReportPage.Create(frxReport);
  Page.CreateUniqueName;
  Page.PaperWidth :=iWidth;
  Page.Height :=iHeight;
  Page.Orientation :=pDirect;
end; 

procedure TForm1.CreateBand(var band: TfrxBand; Page: TfrxReportPage; iTop,
  iHeight:Double;BandType:TBandType);
begin
  case BandType of
    PageHeader: band :=TfrxPageHeader.Create(Page);
    PageFooter: band :=TfrxPageFooter.Create(Page);
  end;
  band.CreateUniqueName;
  band.Top :=iTop;
  band.Height :=iHeight;
end;

procedure TForm1.CreateDataBand(var band: TfrxMasterData;
  Page: TfrxReportPage; DbSet: TfrxDBDataset; iTop, iHeight: Integer);
begin
  band :=TfrxMasterData.Create(Page);
  band.CreateUniqueName;
  band.DataSet := DbSet;
  band.Top :=iTop;
  band.Height :=iHeight;
end;

procedure TForm1.CreateMemo(var memView: TfrxMemoView; Band: TfrxBand;
  iLeft, iTop, iWidth, iHeight: Extended; fontname: string;
  fontsize: Integer; Halign: TfrxHAlign; Valign: TfrxVAlign;
  FrameType: TfrxFrameTypes; sText: string);
begin
  memView := TfrxMemoView.Create(Band);
  memView.CreateUniqueName;
  memView.ParentFont := False;
  memView.Font.Name := fontname;
  memView.Font.Size := fontsize;
  memView.SetBounds(iLeft, iTop, iWidth, iHeight);
  memView.HAlign := Halign;
  memView.VAlign := Valign;
  memView.Frame.Typ := FrameType;
  memView.Memo.Text := sText;
end;

procedure TForm1.CreateMemoData(var memView: TfrxMemoView; Band: TfrxBand;
  iLeft, iTop, iWidth, iHeight: Extended; fontname: string;
  fontsize: Integer; Halign: TfrxHAlign; Valign: TfrxVAlign;
  frxData: TfrxDBDataset; DField: string; FrameType: TfrxFrameTypes;
  Delimiters, ForStr: string; fkKind: TfrxFormatKind);
begin
  memView := TfrxMemoView.Create(Band);
  memView.CreateUniqueName;
  memView.ParentFont := False;
  memView.Font.Name := fontname;
  memView.Font.Size := fontsize;
  memView.SetBounds(iLeft, iTop, iWidth, iHeight);
  memView.HAlign := Halign;
  memView.VAlign := Valign;
  memView.DataSet := frxData;
  memView.DataField := DField;
  memView.Frame.Typ := FrameType;
  memView.ExpressionDelimiters := Delimiters;
  memView.DisplayFormat.FormatStr := ForStr;
  memView.DisplayFormat.Kind := fkKind;
end;

（３）引用代碼

const
  arrFields:array[1..12,1..2] of string=(('Quantity_Start','數量'),('Expense_Start','金額'),
    ('Quantity_Buy_Add','數量'),('Quantity_Buy_Add','金額'),
    ('Quantity_Other_Add','數量'),('Expense_Other_Add','金額'),
    ('Quantity_Out_Reduce','數量'),('Expense_Out_Reduce','金額'),
    ('Quantity_Other_Reduce','數量'),('Expense_Other_Reduce','金額'),
    ('Quantity_End','數量'),('Expense_End','金額')
    );

var
  FirstTop, FirstWidth, FirstHeight, i, DataWidth, DataHeight, MlWidth: Integer;
  Page: TfrxReportPage;
  BandHeader, BandFoot: TfrxBand;
  DataBand: TfrxMasterData;
  Memo, Memo1, memFoot: TfrxMemoView;
  iLeft, iWidth, iLeft1: Integer;
  PerMillPix: Double;
  iFont: Integer;
  haAl: TfrxHAlign;
  MemArray: array[0..4] of TfrxMemoView;
  MemArray1, MemDataArray: array[0..12] of TfrxMemoView;
  MemArray2, MemArray3: array[0..3] of TfrxMemoView;
  frx:TfrxComponent;
begin
  frReport.Clear;
  iFont := iFont10;
  frxDBDataset1.DataSet := qryPrn;
  frReport.DataSets.Add(frxDBDataset1);
  CreatePage(Page, frReport, 210, 279.4, poLandscape);

  //fr01cm :=3.77953;
  DataHeight := 25; //DataHeight*3爲欄首高度(目錄高度)
  MlWidth := 84; //目錄寬度
  DataWidth := 40;
  FirstTop := 40;
  FirstHeight := 30;
  iLeft := 60;
  iLeft1 := 40;

  CreateBand(BandHeader, Page, 10, 220, PageHeader);
  CreateBand(BandFoot, Page, 10, 50, PageFooter);

  //畫操做員
  CreateMemo(memFoot, BandFoot, 65, 10, 150, 20, FName, iFont, haLeft, vaCenter,
    [], '操做員：'+IGlobalVar.GetUserName);
  //畫打印時間
  CreateMemo(memFoot, BandFoot, 280, 10, 270, 20, FName, iFont, haLeft, vaCenter,
    [], '打印時間：' + FormatDateTime('yyyy-mm-dd hh:mm:ss', Now));

  //畫標題
  Memo := TfrxMemoView.Create(BandHeader);
  with Memo do
  begin
    CreateUniqueName;
    Align := baCenter;
    Memo.Text := '**********彙總表';
    Frame.Typ := [ftBottom];
    Frame.BottomLine.Style := fsDouble;
    Top := FirstTop;
    Height := 24;
    AutoWidth := True;
    HAlign := haCenter;
    ParentFont := False;
    Font.Name := '黑體';
    Font.Size := 16;
  end;

  //畫單位
  FirstTop := FirstTop + 40;
  FirstWidth := 150;
  CreateMemo(MemArray[0], BandHeader, 65, FirstTop, FirstWidth, FirstHeight, FName, iFont, haLeft,
    vaCenter,
    [], '單位：'+IGlobalVar.GetUnitID);

  //畫日期
  CreateMemo(MemArray[1], BandHeader, 128, MemArray[0].Top,
    270, FirstHeight, FName, iFont, haLeft, vaCenter,
    [], '日期：' + FormatDateTime('yyyy年mm月dd日', Date) + '至' +
    FormatDateTime('yyyy年mm月dd日', Date));

  //畫倉庫
  FirstWidth := 170;
  CreateMemo(MemArray[2], BandHeader, MemArray[0].Left, MemArray[0].Top + 20, FirstWidth,
    FirstHeight, FName, iFont, haLeft, vaCenter,
    [], '倉庫：'+LcbWh.Text);

  //畫分類方法
  FirstWidth := 10 + FirstWidth;
  CreateMemo(MemArray[3], BandHeader, MemArray[1].Left, MemArray[2].Top, 200, FirstHeight, '宋體',
    iFont, haLeft, vaCenter,
    [], '分類方法：'+lcb1.Text);

  //畫頁碼
  FirstWidth := 10 + FirstWidth;
  CreateMemo(MemArray[4], BandHeader, MemArray[3].Left + MemArray[3].Width + 100, MemArray[2].Top,
    100, FirstHeight, FName, iFont, haLeft, vaCenter,
    [], '第[Page#]頁 共[TotalPages#]頁');

  //畫欄標題
  iWidth := 32 * Pix10; //14個漢字(28字符)所用的像素值
  CreateMemo(MemArray1[0], BandHeader, iLeft, BandHeader.Height - DataHeight * 3, iWidth, DataHeight
    * 3, FName, iFont,
    haCenter, vaCenter, [ftTop, ftRight, ftBottom, ftLeft], '目錄');
  iLeft := iLeft + iWidth;
  for i := 1 to 12 do
  begin
    if (i = 1) or (i = 2) or (i = 11) or (i = 12) then
      CreateMemo(MemArray1[i], BandHeader, MemArray1[i - 1].Left + MemArray1[i - 1].Width,
        BandHeader.Height -
        DataHeight * 2, GetWidth(i),
        DataHeight * 2,
        FName, iFont, haCenter, vaCenter, [ftTop, ftBottom, ftRight], arrFields[i, 2])
    else
      CreateMemo(MemArray1[i], BandHeader, MemArray1[i - 1].Left + MemArray1[i - 1].Width,
        BandHeader.Height -
        DataHeight, GetWidth(i),
        DataHeight,
        FName, iFont, haCenter, vaCenter, [ftTop, ftBottom, ftRight], arrFields[i, 2]);
  end;
  CreateMemo(Memo, BandHeader, MemArray1[3].Left,MemArray1[1].Top,
     MemArray1[3].Width+MemArray1[4].Width,DataHeight,
        FName, iFont, haCenter, vaCenter, [ftTop, ftBottom, ftRight], '外購');
  CreateMemo(Memo, BandHeader, MemArray1[5].Left,MemArray1[1].Top,
     MemArray1[5].Width+MemArray1[6].Width,DataHeight,
        FName, iFont, haCenter, vaCenter, [ftTop, ftBottom, ftRight], '其它');
  CreateMemo(Memo, BandHeader, MemArray1[7].Left,MemArray1[1].Top,
     MemArray1[7].Width+MemArray1[8].Width,DataHeight,
        FName, iFont, haCenter, vaCenter, [ftTop, ftBottom, ftRight], '報廢');
  CreateMemo(Memo, BandHeader, MemArray1[9].Left,MemArray1[1].Top,
     MemArray1[9].Width+MemArray1[10].Width,DataHeight,
        FName, iFont, haCenter, vaCenter, [ftTop, ftBottom, ftRight], '其它');

  CreateMemo(Memo, BandHeader, MemArray1[1].Left,MemArray1[0].Top,
     MemArray1[1].Width+MemArray1[2].Width,DataHeight,
        FName, iFont, haCenter, vaCenter, [ftTop, ftBottom, ftRight], '期初餘額');
  CreateMemo(Memo, BandHeader, MemArray1[3].Left,MemArray1[0].Top,
     MemArray1[3].Width+MemArray1[4].Width+MemArray1[5].Width+MemArray1[6].Width,DataHeight,
        FName, iFont, haCenter, vaCenter, [ftTop, ftBottom, ftRight], '本期增長');
  CreateMemo(Memo, BandHeader, MemArray1[7].Left,MemArray1[0].Top,
     MemArray1[7].Width+MemArray1[8].Width+MemArray1[9].Width+MemArray1[10].Width,DataHeight,
        FName, iFont, haCenter, vaCenter, [ftTop, ftBottom, ftRight], '本期減小');
  CreateMemo(Memo, BandHeader, MemArray1[11].Left,MemArray1[0].Top,
     MemArray1[11].Width+MemArray1[12].Width,DataHeight,
        FName, iFont, haCenter, vaCenter, [ftTop, ftBottom, ftRight], '期末餘額');

  CreateDataBand(DataBand, Page, frxDBDataset1, 200, DataHeight);
  iWidth := 85;
  CreateMemoData(MemDataArray[0], DataBand, MemArray1[0].Left, 0, MemArray1[0].Width, DataHeight,
    FName, iFont, haLeft, vaCenter,
    frxDBDataset1, 'contents', [ftRight, ftBottom, ftLeft], '', '', fkText);
  frReport.Script.Clear;
  frReport.ScriptLanguage :='PascalScript';
  frReport.ScriptText.LoadFromFile('C:\fr_script.pas');          
  MemDataArray[0].OnBeforePrint :='MemoOnBeforePrint';    //動態定義OnBeforePrint事件

  iLeft1 := iLeft1 + iWidth;
  for i := 1 to 12 do
  begin
    if Odd(i) then
      CreateMemoData(MemDataArray[i], DataBand, MemArray1[i].Left, 0, MemArray1[i].Width,
        DataHeight,
        FName, iFont, haCenter, vaCenter, frxDBDataset1, arrFields[i, 1],
        [ftRight, ftBottom], '', '', fkText)
    else
      CreateMemoData(MemDataArray[i], DataBand, MemArray1[i].Left, 0, MemArray1[i].Width,
        DataHeight,
        FName, iFont, haRight, vaCenter, frxDBDataset1, arrFields[i, 1],
        [ftRight, ftBottom], ',', '%2.2n', fkNumeric);
  end;
  frReport.PrepareReport();
  frReport.ShowReport();
end;

C:\fr_script.pas中寫入腳本

procedure MemoOnBeforePrint(Sender: TfrxComponent);
begin
  if Length(TfrxMemoView(Sender).Memo.Text)>10 then
  begin              
    TfrxMemoView(Sender).Memo.Text :=Trim(TfrxMemoView(Sender).Memo.Text);
    TfrxMemoView(Sender).HAlign :=haLeft;  
    //TfrxMemoView(Sender).VAlign :=VaTop;                                   
  end;
end;

begin

end.