如今, Delphi 的多線程已經很是易用了!

先看一個非多線程的例子, 代碼執行時不能進行其它操做(譬如拖動窗體):

{自定義方法: 在窗體上繪製...}
procedure MyMethod;
var
  i: Integer;
begin
  for i := 0 to 500000 do
  begin
    Form1.Canvas.Lock;
    Form1.Canvas.TextOut(10, 10, IntToStr(i));
    Form1.Canvas.Unlock;
  end;
end;

{調用上面的自定義方法}
procedure TForm1.Button1Click(Sender: TObject);
begin
  MyMethod;
end;

修改成多線程(只修改一行代碼):

procedure MyMethod;
var
  i: Integer;
begin
  for i := 0 to 500000 do
  begin
    Form1.Canvas.Lock;
    Form1.Canvas.TextOut(10, 10, IntToStr(i));
    Form1.Canvas.Unlock;
  end;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  TThread.CreateAnonymousThread(MyMethod).Start; //!!!
end;

代碼分析: 

一、TThread 如今增長了許多 class 方法(直接經過類名調用的方法), TThread.CreateAnonymousThread() 就是比較有用的一個. 

二、顧名思義, CreateAnonymousThread 是創建匿名線程對象, 它的參數是咱們須要在線程中執行的方法. 

三、但 CreateAnonymousThread 創建線程後是掛起的, 須要手動運行它; 後面的 Start 方法就是用來喚醒線程的. 

四、(之前)喚醒線程還能夠使用 Resume 方法或 Suspended 屬性(Suspended := False;); 但它們即將被廢棄了, 如今應使用 Start 來啓動線程.

---

CreateAnonymousThread 的參數類型 TProc 是匿名方法(reference), 因此代碼能夠簡寫爲:

procedure TForm1.Button1Click(Sender: TObject);
begin
  TThread.CreateAnonymousThread( //直接寫入方法體
    procedure
    var
      i: Integer;
    begin
      for i := 0 to 500000 do
      begin
        Canvas.Lock;
        Canvas.TextOut(10, 10, IntToStr(i));
        Canvas.Unlock;
      end;
    end //此處無分號
  ).Start;
end;

延時執行:

var
  myThread: TThread;

procedure TForm1.FormCreate(Sender: TObject);
begin
  myThread := TThread.CreateAnonymousThread(
    procedure
    var
      i: Integer;
    begin
      for i := 0 to 500000 do
      begin
        Canvas.Lock;
        Canvas.TextOut(10, 10, IntToStr(i));
        Canvas.Unlock;
      end;
    end
  );
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  myThread.Start;
end;