window腳本批處理BAT文件大型攻略

BAT 批處理腳本 教程

第一章 批處理基礎
第一節 經常使用批處理內部命令簡介

批處理定義顧名思義批處理文件是將一系列命令按必定的順序集合爲一個可執行的文本文件其擴展名爲BAT或者CMD。這些命令統稱批處理命令。
小知識能夠在鍵盤上按下Ctrl+C組合鍵來強行終止一個批處理的執行過程。
瞭解了大概意思後,咱們正式開始學習.先看一個簡單的例子!
@echo off
echo "歡迎來到很是BAT!"
pause
把上面的3條命令保存爲文件test.bat或者test.cmd而後執行,
他就會在屏幕上顯示如下二行話:
歡迎來到很是BAT!
請按任意鍵繼續. . .
這就是一個簡單批處理文件了這個批處理文件一共就用了2條命令 "echo" 和"pause" 還有一個特殊符號"@"
從上面這個簡單的批處理中,咱們能夠發現其實批處理就是運用一些含有特殊意義的符號和一些完成指定功能的命令組合而成,那麼在批處理中有多少這樣的特殊符號和功能命令呢咱們如今就來仔細瞭解一下一些最經常使用的!
(如下內容來源網絡,請各位仔細閱讀,好進入下節的實例說明)
======================================================
批處理的常見命令未列舉的命令還比較多請查閱幫助信息
     一、REM 和 ::
     二、ECHO 和 @
     三、PAUSE
     四、ERRORLEVEL
     五、TITLE
     六、COLOR
     七、mode 配置系統設備
     八、GOTO 和 :
     九、FIND
     十、START
     十一、assoc 和 ftype
     十二、pushd 和 popd
     1三、CALL
     1四、shift
     1五、IF
     1六、setlocal 與 變量延遲
     1七、ATTRIB  顯示或更改文件屬性

介紹命令
一、REM 和 ::
REM爲註釋命令通常用來給程序加上註解該命令後的內容不被執行但能回顯。
其次, :: 也能夠起到rem 的註釋做用, 並且更簡潔有效; 但有兩點須要注意
第一, 任何以冒號:開頭的字符行, 在批處理中都被視做標號, 而直接忽略其後的全部內容。
有效標號冒號後緊跟一個以字母數字開頭的字符串goto語句能夠識別。
無效標號冒號後緊跟一個非字母數字的一個特殊符號goto沒法識別的標號能夠起到註釋做用因此 :: 常被用做註釋符號其實 :+ 也可起註釋做用。
第二, 與rem 不一樣的是, ::後的字符行在執行時不會回顯, 不管是否用echo on打開命令行回顯狀態, 由於命令解釋器不認爲他是一個有效的命令行, 就此點來看, rem 在某些場合下將比 :: 更爲適用; 另外, rem 能夠用於 config.sys 文件中。

行內註釋格式%註釋內容%  不經常使用慎用


二、ECHO 和 @
@字符放在命令前將關閉該命令回顯不管此時echo是否爲打開狀態。
echo命令的做用列舉以下
1打開回顯或關閉回顯功能
    格式:echo [{ on|off }]
    若是想關閉「ECHO OFF」命令行自身的顯示則須要在該命令行前加上「@」。
2顯示當前ECHO設置狀態
    格式:echo
3輸出提示信息 
    格式ECHO 信息內容
    上述是ECHO命令常見的三種用法也是你們熟悉和會用的但做爲DOS命令淘金者你還應該知道下面的技巧
4關閉DOS命令提示符 
    在DOS提示符狀態下鍵入ECHO OFF可以關閉DOS提示符的顯示使屏幕只留下光標直至鍵入ECHO ON提示符纔會從新出現。
5輸出空行即至關於輸入一個回車 
    格式ECHO
    值得注意的是命令行中的「」要緊跟在ECHO後面中間不能有空格不然「」將被看成提示信息輸出到屏幕。另外「」能夠用」[\]等任一符號替代。
    命令ECHO輸出的回車經DOS管道轉向能夠做爲其它命令的輸入好比echo.|time即至關於在TIME命令執行後給出一個回車。因此執行時系統會在顯示當前時間後自動返回到DOS提示符狀態
6答覆命令中的提問 
    格式ECHO 答覆語|命令文件名
上述格式能夠用於簡化一些須要人機對話的命令如CHKDSKFFORMAT Drive:del *.*的操做它是經過DOS管道命令把ECHO命令輸出的預置答覆語做爲人機對話命令的輸入。下面的例子就至關於在調用的命令出現人機對話時輸入「Y」回車
C:>ECHO Y|CHKDSK/F
C:>ECHO Y|DEL A :*.*
7創建新文件或增長文件內容 
格式ECHO 文件內容>文件名
      ECHO 文件內容>>文件名
例如
C:>ECHO @ECHO OFF>AUTOEXEC.BAT創建自動批處理文件
C:>ECHO C:\CPAV\BOOTSAFE>>AUTOEXEC.BAT向自動批處理文件中追加內容
C:>TYPE AUTOEXEC.BAT顯示該自動批處理文件
@ECHO OFF
C:\CPAV\BOOTSAFE
8向打印機輸出打印內容或打印控制碼 
格式ECHO 打印機控制碼>;PRN
      ECHO 打印內容>;PRN
下面的例子是向M1724打印機輸入打印控制碼。Alt156是按住Alt鍵在小鍵盤鍵入156相似狀況依此類推
C:>ECHO +156+42+116>;PRN輸入下劃線命令FSt
C:>ECHO [email=+155@]+155@>;PRN[/email]輸入初始化命令ESC@
C:>ECHO.>;PRN換行
9使喇叭鳴響 
C:>ECHO ^G
「^G」是在dos窗口中用CtrlG或Alt007輸入輸入多個^G能夠產生多聲鳴響。使用方法是直接將其加入批處理文件中或作成批處理文件調用。
這裏的「^G」屬於特殊符號的使用請看本文後面的章節


三、PAUSE
PAUSE玩遊戲的人都知道暫停的意思
在這裏就是中止系統命令的執行並顯示下面的內容。
例
PAUSE
運行顯示
請按任意鍵繼續. . .
要顯示其餘提示語能夠這樣用
Echo 其餘提示語 & pause > nul


四、errorlevel
程序返回碼
echo %errorlevel%
每一個命令運行結束能夠用這個命令行格式查看返回碼
用於判斷剛纔的命令是否執行成功
默認值爲0通常命令執行出錯會設 errorlevel 爲1


五、title
設置cmd窗口的標題
title 新標題        #能夠看到cmd窗口的標題欄變了


六、COLOR
設置默認的控制檯前景和背景顏色。
COLOR [attr]
  attr        指定控制檯輸出的顏色屬性
顏色屬性由兩個十六進制數字指定 -- 第一個爲背景第二個則爲
前景。每一個數字能夠爲如下任何值之一:
    0 = 黑色       8 = 灰色
    1 = 藍色       9 = 淡藍色
    2 = 綠色       A = 淡綠色
    3 = 湖藍色     B = 淡淺綠色
    4 = 紅色       C = 淡紅色
    5 = 紫色       D = 淡紫色
    6 = ***       E = 淡***
    7 = 白色       F = 亮白色
若是沒有給定任何參數該命令會將顏色還原到 CMD.EXE 啓動時
的顏色。這個值來自當前控制檯窗口、/T 開關或
DefaultColor 註冊表值。
若是用相同的前景和背景顏色來執行 COLOR 命令COLOR 命令
會將 ERRORLEVEL 設置爲 1。
例如: "COLOR fc" 在亮白色上產生亮紅色


七、mode 配置系統設備
配置系統設備。
串行口:　　　     MODE COMm[:] [BAUD=b] [PARITY=p] [DATA=d] [STOP=s]
                                [to=on|off] [xon=on|off] [odsr=on|off]
                                [octs=on|off] [dtr=on|off|hs]
                                [rts=on|off|hs|tg] [idsr=on|off]
設備狀態:             MODE [device] [/STATUS]
打印重定向:　　 MODE LPTn[:]=COMm[:]
選定代碼頁:　　 MODE CON[:] CP SELECT=yyy
代碼頁狀態:　　 MODE CON[:] CP [/STATUS]
顯示模式:　　     MODE CON[:] [COLS=c] [LINES=n]
擊鍵率:　             MODE CON[:] [RATE=r DELAY=d]
例
mode con cols=113 lines=15 & color 9f
此命令設置DOS窗口大小15行113列


八、GOTO 和 :
GOTO會點編程的朋友就會知道這是跳轉的意思。
在批處理中容許以「:XXX」來構建一個標號而後用GOTO XXX跳轉到標號:XXX處而後執行標號後的命令。
例
if {%1}=={} goto noparms
if "%2"=="" goto noparms
標籤的名字能夠隨便起可是最好是有意義的字符串啦前加個冒號用來表示這個字符串是標籤goto命令就是根據這個冒號:來尋找下一步跳到到那裏。最好有一些說明這樣你別人看起來纔會理解你的意圖啊。

例
@echo off
:start
set /a var+=1
echo %var%
if %var% leq 3 GOTO start
pause
運行顯示
1
2
3
4
十、start 命令
批處理中調用外部程序的命令該外部程序在新窗口中運行批處理程序繼續往下執行不理會外部程序的運行情況若是直接運行外部程序則必須等外部程序完成後才繼續執行剩下的指令
例start explorer d:\
調用圖形界面打開D盤


十一、assoc 和 ftype
文件關聯
assoc 設置'文件擴展名'關聯關聯到'文件類型'
ftype 設置'文件類型'關聯關聯到'執行程序和參數'
當你雙擊一個.txt文件時windows並非根據.txt直接判斷用 notepad.exe 打開
而是先判斷.txt屬於 txtfile '文件類型'
再調用 txtfile 關聯的命令行 txtfile=%SystemRoot%\system32\NOTEPAD.EXE %1
能夠在"文件夾選項"→"文件類型"裏修改這2種關聯
assoc           #顯示全部'文件擴展名'關聯
assoc .txt      #顯示.txt表明的'文件類型'結果顯示 .txt=txtfile
assoc .doc      #顯示.doc表明的'文件類型'結果顯示 .doc=Word.Document.8
assoc .exe      #顯示.exe表明的'文件類型'結果顯示 .exe=exefile
ftype           #顯示全部'文件類型'關聯
ftype exefile   #顯示exefile類型關聯的命令行結果顯示 exefile="%1" %* 
assoc .txt=Word.Document.8
設置.txt爲word類型的文檔能夠看到.txt文件的圖標都變了
assoc .txt=txtfile
恢復.txt的正確關聯

ftype exefile="%1" %*
恢復 exefile 的正確關聯
若是該關聯已經被破壞能夠運行 command.com 再輸入這條命令


十二、pushd 和 popd
切換當前目錄
@echo off
c: & cd\ & md mp3       #在 C:\ 創建 mp3 文件夾
md d:\mp4               #在 D:\ 創建 mp4 文件夾
cd /d d:\mp4            #更改當前目錄爲 d:\mp4
pushd c:\mp3            #保存當前目錄並切換當前目錄爲 c:\mp3
popd                    #恢復當前目錄爲剛纔保存的 d:\mp4
通常用處不大在當前目錄名不肯定時會有點幫助。dos編程中頗有用


1三、CALL
CALL命令能夠在批處理執行過程當中調用另外一個批處理當另外一個批處理執行完後再繼續執行原來的批處理
CALL command
調用一條批處理命令和直接執行命令效果同樣特殊狀況下頗有用好比變量的多級嵌套見教程後面。在批處理編程中能夠根據必定條件生成命令字符串用call能夠執行該字符串見例子。
CALL [drive:][path]filename [batch-parameters]
調用的其它批處理程序。filename 參數必須具備 .bat 或 .cmd 擴展名。
CALL :label arguments
調用本文件內命令段至關於子程序。被調用的命令段以標籤:label開頭
以命令goto :eof結尾。
另外批腳本文本參數參照(%0、%一、等等)已以下改變:
     批腳本里的 %* 指出全部的參數(如 %1 %2 %3 %4 %5 ...)
     批參數(%n)的替代已被加強。您可使用如下語法:看不明白的直接運行後面的例子
         %~1         - 刪除引號(")擴充 %1
         %~f1        - 將 %1 擴充到一個徹底合格的路徑名
         %~d1        - 僅將 %1 擴充到一個驅動器號
         %~p1        - 僅將 %1 擴充到一個路徑
         %~n1        - 僅將 %1 擴充到一個文件名
         %~x1        - 僅將 %1 擴充到一個文件擴展名
         %~s1        - 擴充的路徑指含有短名
         %~a1        - 將 %1 擴充到文件屬性
         %~t1        - 將 %1 擴充到文件的日期/時間
         %~z1        - 將 %1 擴充到文件的大小
         %~$PATH : 1 - 查找列在 PATH 環境變量的目錄並將 %1
                       擴充到找到的第一個徹底合格的名稱。若是環境
                       變量名未被定義或者沒有找到文件此組合鍵會
                       擴充到空字符串
    能夠組合修定符來取得多重結果:
        %~dp1       - 只將 %1 擴展到驅動器號和路徑
        %~nx1       - 只將 %1 擴展到文件名和擴展名
        %~dp$PATH:1 - 在列在 PATH 環境變量中的目錄裏查找 %1
                       並擴展到找到的第一個文件的驅動器號和路徑。
        %~ftza1     - 將 %1 擴展到相似 DIR 的輸出行。
    在上面的例子中%1 和 PATH 能夠被其餘有效數值替換。
%~ 語法被一個有效參數號碼終止。%~ 修定符不能跟 %*使用
注意參數擴充時不理會參數所表明的文件是否真實存在均以當前目錄進行擴展
要理解上面的知識下面的例子很關鍵。
例
@echo off
Echo 產生一個臨時文件 > tmp.txt
Rem 下行先保存當前目錄再將c:\windows設爲當前目錄
pushd c:\windows
Call :sub tmp.txt
Rem 下行恢復前次的當前目錄
Popd
Call :sub tmp.txt
pause
Del tmp.txt
exit
:sub
Echo 刪除引號 %~1
Echo 擴充到路徑 %~f1
Echo 擴充到一個驅動器號 %~d1
Echo 擴充到一個路徑 %~p1 
Echo 擴充到一個文件名 %~n1
Echo 擴充到一個文件擴展名 %~x1
Echo 擴充的路徑指含有短名 %~s1 
Echo 擴充到文件屬性 %~a1 
Echo 擴充到文件的日期/時間 %~t1 
Echo 擴充到文件的大小 %~z1 
Echo 擴展到驅動器號和路徑%~dp1
Echo 擴展到文件名和擴展名%~nx1
Echo 擴展到相似 DIR 的輸出行%~ftza1
Echo.
Goto :eof
例
set aa=123456
set cmdstr=echo %aa%
call %cmdstr%
pause
本例中若是不用call而直接運行%cmdstr%將顯示結果%aa%而不是123456

1四、shift
更改批處理文件中可替換參數的位置。
SHIFT [/n]
若是命令擴展名被啓用SHIFT 命令支持/n 命令行開關該命令行開關告訴
命令從第 n 個參數開始移位n 介於零和八之間。例如:
    SHIFT /2
會將 %3 移位到 %2將 %4 移位到 %3等等而且不影響 %0 和 %1。
1五、IF
IF 條件判斷語句語法格式以下
IF [NOT] ERRORLEVEL number command
IF [NOT] string1==string2 command
IF [NOT] EXIST filename command
下面逐一介紹更詳細的分析請看後面章節。

(1) IF [NOT] ERRORLEVEL number command
IF ERRORLEVEL這個句子必須放在某一個命令的後面執行命令後由IF ERRORLEVEL 來判斷命令的返回值。
Number的數字取值範圍0~255判斷時值的排列順序應該由大到小。返回的值大於等於指定的值時條件成立
例
@echo off
dir c:
rem退出代碼爲>=1就跳至標題1處執行>=0就跳至標題0處執行
IF ERRORLEVEL 1 goto 1
IF ERRORLEVEL 0 goto 0
Rem 上面的兩行不可交換位置不然失敗了也顯示成功。
:0
echo 命令執行成功
Rem 程序執行完畢跳至標題exit處退出
goto exit
:1
echo 命令執行失敗
Rem 程序執行完畢跳至標題exit處退出
goto exit
:exit
pause
運行顯示命令執行成功
(2) IF [NOT] string1==string2 command
string1和string2都爲字符的數據英文內字符的大小寫將看做不一樣這個條件中的等於號必須是兩個絕對相等的意思
條件相等後即執行後面的command
檢測當前變量的值作出判斷爲了防止字符串中含有空格可用如下格式
if [NOT] {string1}=={string2} command
if [NOT] [string1]==[string2] command
if [NOT] "string1"=="string2" command
這種寫法實際上將括號或引號當成字符串的一部分了只要等號左右兩邊一致就好了好比下面的寫法就不行
if {string1}==[string2] command

(3) IF [NOT] EXIST filename command
EXIST filename爲文件或目錄存在的意思
echo off
IF EXIST autoexec.bat echo 文件存在
IF not EXIST autoexec.bat echo 文件不存在
這個批處理你們能夠放在C盤和D盤分別執行看看效果



1六、setlocal 與 變量延遲
本條內容引用[英雄出品]的批處理教程
要想進階變量延遲是必過的一關因此這一部分但願你能認真看。
爲了更好的說明問題咱們先引入一個例子。
例1:
@echo off
set a=4
set a=5 & echo %a%
pause
結果4
解說爲何是4而不是5呢在echo以前明明已經把變量a的值改爲5了
讓咱們先了解一下批處理運行命令的機制
批處理讀取命令時是按行讀取的另外例如for命令等其後用一對圓括號閉合的全部語句也看成一行在處理以前要完成必要的預處理工做這其中就包括對該行命令中的變量賦值。咱們如今分析一下例1批處理在運行到這句「set a=5 & echo %a%」以前先把這一句整句讀取並作了預處理——對變量a賦了值那麼%a%固然就是4了沒有爲何批處理就是這樣作的。
而爲了可以感知環境變量的動態變化批處理設計了變量延遲。簡單來講在讀取了一條完整的語句以後不當即對該行的變量賦值而會在某個單條語句執行以前再進行賦值也就是說「延遲」了對變量的賦值。
那麼如何開啓變量延遲呢變量延遲又須要注意什麼呢舉個例子說明一下
例2:
@echo off
setlocal enabledelayedexpansion
set a=4
set a=5 & echo !a!
pause 
結果5
解說啓動了變量延遲獲得了正確答案。變量延遲的啓動語句是「setlocal enabledelayedexpansion」而且變量要用一對歎號「!!」括起來注意要用英文的歎號不然就沒有變量延遲的效果。
分析一下例2首先「setlocal enabledelayedexpansion」開啓變量延遲而後「set a=4」先給變量a賦值爲
4「set a=5 & echo !a!」這句是給變量a賦值爲5並輸出因爲啓動了變量延遲因此批處理可以感知到動態變化即不是先給該行變量賦值而是在運行過程當中給變量賦值所以此時a的值就是5了。
再舉一個例子鞏固一下。
例3:
@echo off
setlocal enabledelayedexpansion
for /l %%i in (1,1,5) do (
set a=%%i
echo !a!
)
pause
結果
1
2
3
4
5
解說本例開啓了變量延遲並用「!!」將變量擴起來所以獲得咱們預期的結果。若是不用變量延遲會出現什
麼結果呢結果是這樣的
ECHO 處於關閉狀態。
ECHO 處於關閉狀態。
ECHO 處於關閉狀態。
ECHO 處於關閉狀態。
ECHO 處於關閉狀態。
即沒有感知到for語句中的動態變化。
提示在沒有開啓變量延遲的狀況下某條命令行中的變量改變必須到下一條命令才能體現。這一點也能夠加以利用看例子。
例交換兩個變量的值且不用中間變量
@echo off
::目的交換兩個變量的值可是不使用臨時變量
::Code by JM 2007-1-24 [email=CMD@XP]CMD@XP[/email]
::出處http://www.cn-dos.net/forum/viewthread.php?tid=27078
set var1=abc
set var2=123
echo 交換前 var1=%var1% var2=%var2%
set var1=%var2%& set var2=%var1%
echo 交換後 var1=%var1% var2=%var2%
pause

1七、ATTRIB  顯示或更改文件屬性
ATTRIB [+R|-R] [+A|-A] [+S|-S] [+H|-H] [[drive:] [path] filename] [/S [/D]]
  +   設置屬性。
  -    清除屬性。
  R   只讀文件屬性。
  A   存檔文件屬性。
  S   系統文件屬性。
  H   隱藏文件屬性。
  [drive:][path][filename]
      指定要處理的文件屬性。
  /S  處理當前文件夾及其子文件夾中的匹配文件。
  /D  也處理文件夾。

例
md autorun
attrib +a +s +h autorun
上面的命令將創建文件夾autorun而後將其設爲存檔、系統、隱藏屬性
第二節 經常使用特殊符號
    一、@  命令行回顯屏蔽符
    二、%  批處理變量引導符
    三、>   重定向符
    四、>>  重定向符
    五、<、>&、<& 重定向符
    六、|  命令管道符
    七、^  轉義字符
    八、&  組合命令
    九、&& 組合命令
    十、||  組合命令
    十一、""  字符串界定符
    十二、, 逗號
    1三、; 分號
    1四、() 括號
    1五、! 感嘆號
    1六、批處理中可能會見到的其它特殊標記符: 略
        CR(0D) 命令行結束符 
        Escape(1B) ANSI轉義字符引導符 
        Space(20) 經常使用的參數界定符 
        Tab(09) ; = 不經常使用的參數界定符 
        + COPY命令文件鏈接符 
        * ? 文件通配符 
        / 參數開關引導符 
        : 批處理標籤引導符 

廢話少說開講了
一、@  命令行回顯屏蔽符
這個字符在批處理中的意思是關閉當前行的回顯。咱們從前幾課知道
ECHO OFF能夠關閉掉整個批處理命令的回顯但不能關掉ECHO OFF這個命令如今咱們在ECHO OFF這個命令前加個@就能夠達到全部命令均不回顯的要求

二、%  批處理變量引導符
這個百分號嚴格來講是算不上命令的它只是批處理中的參數而已多個%一塊兒使用的狀況除外之後還將詳細介紹。
引用變量用%var%調用程序外部參數用%1至%9等等
%0  %1  %2  %3  %4  %5  %6  %7  %8  %9  %*爲命令行傳遞給批處理的參數
%0 批處理文件自己包括完整的路徑和擴展名
%1 第一個參數
%9 第九個參數
%* 從第一個參數開始的全部參數
參數%0具備特殊的功能能夠調用批處理自身以達到批處理自己循環的目的也能夠複製文件自身等等。
例最簡單的複製文件自身的方法
copy %0 d:\wind.bat
小技巧添加行內註釋
%註釋內容%能夠用做行內註釋不能出現重定向符號和管道符號
爲何這樣呢此時「註釋內容」其實被看成變量其值是空的故只起註釋做用不過這種用法容易出現語法錯誤通常不用。

三、>   重定向符
輸出重定向命令
這個字符的意思是傳遞而且覆蓋他所起的做用是將運行的結果傳遞到後面的範圍後邊能夠是文件也能夠是默認的系統控制檯
    在NT系列命令行中重定向的做用範圍由整個命令行轉變爲單個命令語句受到了命令分隔符&,&&,||和語句塊的制約限制。
好比
使用命令echo hello >1.txt將創建文件1.txt內容爲」hello 「注意行尾有一空格
使用命令echo hello>1.txt將創建文件1.txt內容爲」hello「注意行尾沒有空格

四、>>  重定向符
輸出重定向命令
這個符號的做用和>有點相似但他們的區別是>>是傳遞並在文件的末尾追加而>是覆蓋
用法同上
一樣拿1.txt作例子
使用命令
echo hello > 1.txt
echo world >>1.txt
這時候1.txt 內容以下:
hello
world

五、<、>&、<& 重定向符
這三個命令也是管道命令但它們通常不經常使用你只須要知道一下就ok了固然若是想仔細研究的話能夠本身查一下資料。(本人已查過網上也查不到相關資料)
<輸入重定向命令從文件中讀入命令輸入而不是從鍵盤中讀入。
@echo off
echo 2005-05-01>temp.txt
date <temp.txt
del temp.txt
這樣就能夠不等待輸入直接修改當前日期
>&將一個句柄的輸出寫入到另外一個句柄的輸入中。
<&恰好和>&相反從一個句柄讀取輸入並將其寫入到另外一個句柄輸出中。
經常使用句柄0、一、2未定義句柄3—9
1>nul 表示禁止輸出正確的信息
2>nul 表示禁止輸出錯誤信息。
其中的1與2都是表明某個數據流輸入輸出的地址NT CMD 稱之爲句柄MSDOS稱之爲設備。
句柄0標準輸入stdin鍵盤輸入
句柄1標準輸出stdout輸出到命令提示符窗口console代碼爲CON
句柄2標準錯誤stderr輸出到命令提示符窗口console代碼爲CON
其中的stdin可被<重定向stdout可被>、>>重定向。
咱們已經知道讀取文本中的內容能夠用for命令但若是隻須要讀取第一行用for命令就有點麻煩。簡單的辦法以下:
@echo off
set /p str=<%0
echo %str%
pause
運行顯示批處理文件自身的第一行@echo off

六、|  命令管道符
格式第一條命令 | 第二條命令 [| 第三條命令...]
將第一條命令的結果做爲第二條命令的參數來使用記得在unix中這種方式很常見。
例如
dir c:\|find "txt"
以上命令是查找C\全部並發現TXT字符串。
FIND的功能請用 FIND /? 自行查看
在不使format的自動格式化參數時我是這樣來自動格式化A盤的
echo y|format a: /s /q /v:system
用過format的都知道再格盤時要輸入y來確認是否格盤這個命令前加上echo y並用|字符來將echo y的結果傳給format命令
從而達到自動輸入y的目的
這條命令有危害性測試時請慎重


七、^  轉義字符
^是對特殊符號<,>,&的前導字符在命令中他將以上3個符號的特殊功能去掉僅僅只把他們當成符號而不使用他們的特殊意義。
好比
echo test ^>1.txt
結果則是test > 1.txt
他沒有追加在1.txt裏呵呵。只是顯示了出來
另外此轉義字符還能夠用做續行符號。
舉個簡單的例子
@echo off
echo 英雄^
是^
好^
男人
pause
不用多說本身試一下就明白了。
爲何轉義字符放在行尾能夠起到續行符的做用呢緣由很簡單由於每行末尾還有一個看不見的符號即回車符轉義字符位於行尾時就讓回車符失效了從而起到了續行的做用。


八、&  組合命令
語法第一條命令 & 第二條命令 [& 第三條命令...]
&、&&、||爲組合命令顧名思義就是能夠把多個命令組合起來當一個命令來執行。這在批處理腳本里是容許的並且用的很是普遍。由於批處理認行不認命令數目。
這個符號容許在一行中使用2個以上不一樣的命令當第一個命令執行失敗了也不影響後邊的命令執行。
這裏&兩邊的命令是順序執行的從前日後執行。
好比
dir z:\ & dir y:\ & dir c:\
以上命令會連續顯示z,y,c盤的內容不理會該盤是否存在


九、&& 組合命令
語法第一條命令 && 第二條命令 [&& 第三條命令...]
用這種方法能夠同時執行多條命令當碰到執行出錯的命令後將不執行後面的命令若是一直沒有出錯則一直執行完全部命令
這個命令和上邊的相似但區別是第一個命令失敗時後邊的命令也不會執行
dir z:\ && dir y:\ && dir c:\


十、||  組合命令
語法第一條命令 || 第二條命令 [|| 第三條命令...]
用這種方法能夠同時執行多條命令當一條命令失敗後才執行第二條命令當碰到執行正確的命令後將不執行後面的命令若是沒有出現正確的命令則一直執行完全部命令

提示組合命令和重定向命令一塊兒使用必須注意優先級
管道命令的優先級高於重定向命令重定向命令的優先級高於組合命令
問題把C盤和D盤的文件和文件夾列出到a.txt文件中。看例
dir c:\ && dir d:\ > a.txt
這樣執行後a.txt裏只有D盤的信息爲何由於組合命令的優先級沒有重定向命令的優先級高因此這句在執行時將本行分紅這兩部分dir c:\和dir d:\ > a.txt而並非如你想的這兩部分dir c:\ && dir d:\和> a.txt。要使用組合命令&&達到題目的要求必須得這麼寫
dir c:\ > a.txt && dir d:\ >> a.txt
這樣依據優先級高低DOS將把這句話分紅如下兩部分dir c:\ > a.txt和dir d:\ >> a.txt。例十八中的幾句的差異比較特殊值得好好研究體會一下。
固然這裏還能夠利用&命令本身想一下道理哦
dir c:\ > a.txt & dir d:\ >> a.txt
[這個也能夠用 dir c:\;d:\ >>a.txt 來實現]

十一、""  字符串界定符
雙引號容許在字符串中包含空格進入一個特殊目錄能夠用以下方法
cd "program files"
cd progra~1
cd pro*
以上三種方法均可以進入program files這個目錄


十二、, 逗號
逗號至關於空格在某些狀況下「,」能夠用來當作空格使
好比
dir,c:\

1三、; 分號
分號當命令相同時能夠將不一樣目標用來隔離但執行效果不變如執行過程當中發生錯誤則只返回錯誤報告但程序仍會執行。有人說不會繼續執行其實測試一下就知道了
好比
dir c:\;d:\;e:\;z:\
以上命令至關於
dir c:\
dir d:\
dir e:\
dir f:\
若是其中z盤不存在運行顯示系統找不到指定的路徑。而後終止命令的執行。
例dir c:\;d:\;e:\1.txt
以上命令至關於
dir c:\
dir d:\
dir e:\1.txt
其中文件e:\1.txt不存在但e盤存在有錯誤提示但命令仍會執行。

爲何若是目標路徑不存在則終止執行若是路徑存在僅文件不存在則繼續執行。
就說這些了!各位有什麼意見請回貼!有什麼疑問請到BAT交流區發貼!下一節改進!


1四、() 括號
小括號在批處理編程中有特殊的做用左右括號必須成對使用括號中能夠包括多行命令這些命令將被當作一個總體視爲一條命令行。
    括號在for語句和if語句中常見用來嵌套使用循環或條件語句其實括號()也能夠單獨使用請看例子。
例
命令echo 1 & echo 2 & echo 3
能夠寫成
(
echo 1
echo 2
echo 3
)
上面兩種寫法效果同樣這兩種寫法都被視爲是一條命令行。
注意這種多條命令被視爲一條命令行時若是其中有變量就涉及到變量延遲的問題。


1五、! 感嘆號
沒啥說的在變量延遲問題中用來表示變量即%var%應該表示爲!var!請看前面的setlocal命令介紹。

第二章 DOS循環for命令詳解

講FOR以前呢,咋先告訴各位新手朋友,若是你有什麼命令不懂,直接在CMD下面輸入:
name /? 這樣的格式來看系統給出的幫助文件,好比for /? 就會把FOR命令的幫助所有顯示出來!固然許多菜鳥都看不懂....因此纔會有那麼多批處理文章!!!!俺也照顧菜鳥,把FOR命令用我本身的方式說明下!
正式開始:

1、基本格式
FOR %%variable IN (set) DO command [command-parameters]
  %%variable  指定一個單一字母表示可替換的參數。
  (set)      指定一個或一組文件。可使用通配符。
  command    指定對每一個文件執行的命令。
  command-parameters
             爲特定命令指定參數或命令行開關。



參數:FOR有4個參數 /d   /l   /r   /f   他們的做用我在下面用例子解釋
如今開始講每一個參數的意思

2、參數 /d
FOR /D %%variable IN (set) DO command [command-parameters]
    若是集中包含通配符則指定與目錄名匹配而不與文件
    名匹配。
若是 Set (也就是我上面寫的 "相關文件或命令") 包含通配符* 和 ?將對與 Set 相匹配的每一個目錄而不是指定目錄中的文件組執行指定的 Command。
這個參數主要用於目錄搜索,不會搜索文件,看這樣的例子
@echo off
for /d %%i in (c:\*) do echo %%i
pause
運行會把C盤根目錄下的所有目錄名字打印出來,而文件名字一個也不顯示!
在來一個,好比咱們要把當前路徑下文件夾的名字只有1-3個字母的打出來
@echo off
for /d %%i in (???) do echo %%i
pause
這樣的話若是你當前目錄下有目錄名字只有1-3個字母的,就會顯示出來,沒有就不顯示了
這裏解釋下*號和?號的做用,*號表示任意N個字符,而?號只表示任意一個字符
知道做用了,給你們個思考題目!
@echo off
for /d %%i in (window?) do echo %%i
pause
保存到C盤下執行,會顯示什麼呢?本身看吧! 顯示windows
/D參數只能顯示當前目錄下的目錄名字,這個你們要注意!


3、參數 /R
FOR /R [[drive:]path] %%variable IN (set) DO command [command-parameters]
    檢查以 [drive:]path 爲根的目錄樹指向每一個目錄中的
    FOR 語句。若是在 /R 後沒有指定目錄則使用當前
目錄。若是集僅爲一個單點(.)字符則枚舉該目錄樹。

遞歸
上面咱們知道,/D只能顯示當前路徑下的目錄名字,那麼如今這個/R也是和目錄有關,他能幹嗎呢?放心他比/D強大多了!
他能夠把當前或者你指定路徑下的文件名字所有讀取,注意是文件名字,有什麼用看例子!
請注意2點
    一、set中的文件名若是含有通配符(或*)則列舉/R參數指定的目錄及其下面的所用子目錄中與set相符合的全部文件無相符文件的目錄則不列舉。
    二、相反若是set中爲具體文件名不含通配符則枚舉該目錄樹即列舉該目錄及其下面的全部子目錄而無論set中的指定文件是否存在。這與前面所說的單點.枚舉目錄樹是一個道理單點表明當前目錄也可視爲一個文件。
例
@echo off
for /r c:\ %%i in (*.exe) do echo %%i
pause
我們把這個BAT保存到D盤隨便哪裏而後執行,我會就會看到,他把C盤根目錄,和每一個目錄的子目錄下面所有的EXE文件都列出來了!!!!
例
@echo off
for /r %%i in (*.exe) do @echo %%i
pause
參數不同了吧!這個命令前面沒加那個C:\也就是搜索路徑,這樣他就會以當前目錄爲搜索路徑,好比你這個BAT你把他放在d:\test目錄下執行,那麼他就會把D:\test目錄和他下面的子目錄的所有EXE文件列出來!!!
例
@echo off
for /r c:\ %%i in (boot.ini) do echo %%i
pause
運行本例發現枚舉了c盤全部目錄爲了只列舉boot.ini存在的目錄可改爲下面這樣
@echo off
for /r c:\ %%i in (boot.ini) do if exist %%i echo %%i
pause
用這條命令搜索文件真不錯。。。。。。
這個參數你們應該理解了吧!仍是滿好玩的命令!


4、參數 /L
FOR /L %%variable IN (start,step,end) DO command [command-parameters]
    該集表示以增量形式從開始到結束的一個數字序列。
    所以(1,1,5) 將產生序列 1 2 3 4 5(5,-1,1) 將產生
    序列 (5 4 3 2 1)。
使用迭代變量設置起始值 (Start#)而後逐步執行一組範圍的值直到該值超過所設置的終止值 (End#)。/L 將經過對 Start# 與 End# 進行比較來執行迭代變量。若是 Start# 小於 End#就會執行該命令。若是迭代變量超過 End#則命令解釋程序退出此循環。還可使用負的 Step# 以遞減數值的方式逐步執行此範圍內的值。例如(1,1,5) 生成序列 1 2 3 4 5而 (5,-1,1) 則生成序列 (5 4 3 2 1)。語法是
看着這說明有點暈吧!我們看例子就不暈了!
@echo off
for /l %%i in (1,1,5) do @echo %%i
pause
保存執行看效果,他會打印從1 2 3 4 5  這樣5個數字
(1,1,5)這個參數也就是表示從1開始每次加1直到5終止!
等會暈,就打印個數字有P用...好的知足你們,看這個例子
@echo off
for /l %%i in (1,1,5) do start cmd
pause
執行後是否是嚇了一跳,怎麼多了5個CMD窗口,呵呵!若是把那個 (1,1,5)改爲 (1,1,65535)會有什麼結果,我先告訴你們,會打開65535個CMD窗口....這麼多你不死機算你強!
固然咱們也能夠把那個start cmd改爲md %%i 這樣就會創建指定個目錄了!!!名字爲1-65535
看完這個被我賦予破壞性質的參數後,咱們來看最後一個參數
5、參數 /F
\迭代及文件解析
使用文件解析來處理命令輸出、字符串及文件內容。使用迭代變量定義要檢查的內容或字符串並使用各類options選項進一步修改解析方式。使用options令牌選項指定哪些令牌應該做爲迭代變量傳遞。請注意在沒有使用令牌選項時/F 將只檢查第一個令牌。
文件解析過程包括讀取輸出、字符串或文件內容將其分紅獨立的文本行以及再將每行解析成零個或更多個令牌。而後經過設置爲令牌的迭代變量值調用 for 循環。默認狀況下/F 傳遞每一個文件每一行的第一個空白分隔符號。跳過空行。

詳細的幫助格式爲
FOR /F ["options"] %%variable IN (file-set) DO command [command-parameters]
FOR /F ["options"] %%variable IN ("string") DO command [command-parameters]
FOR /F ["options"] %%variable IN ('command') DO command [command-parameters]
    帶引號的字符串"options"包括一個或多個
    指定不一樣解析選項的關鍵字。這些關鍵字爲:
        eol=c           - 指一個行註釋字符的結尾(就一個)
        skip=n          - 指在文件開始時忽略的行數。
        delims=xxx      - 指分隔符集。這個替換了空格和跳格鍵的
                          默認分隔符集。
        tokens=x,y,m-n  - 指每行的哪個符號被傳遞到每一個迭代
                          的 for 自己。這會致使額外變量名稱的分配。m-n
                          格式爲一個範圍。經過 nth 符號指定 mth。若是
                          符號字符串中的最後一個字符星號
                          那麼額外的變量將在最後一個符號解析以後
                          分配並接受行的保留文本。經測試該參數最多
                          只能區分31個字段。
        usebackq        - 使用後引號鍵盤上數字1左面的那個鍵`。
                        未使用參數usebackq時file-set表示文件但不能含有空格
                            雙引號表示字符串即"string"
                            單引號表示執行命令即'command'
                          使用參數usebackq時file-set和"file-set"都表示文件
                          當文件路徑或名稱中有空格時就能夠用雙引號括起來
                            單引號表示字符串即'string'
                            後引號表示命令執行即`command`

以上是用for /?命令得到的幫助信息直接複製過來的。
暈慘了!我這就舉個例子幫助你們來理解這些參數!

For命令例1****************************************
@echo off
rem 首先創建臨時文件test.txt
echo ;註釋行,這是臨時文件,用完刪除 >test.txt
echo 11段 12段 13段 14段 15段 16段 >>test.txt
echo 21段,22段,23段,24段,25段,26段 >>test.txt
echo 31段-32段-33段-34段-35段-36段 >>test.txt
FOR /F "eol=; tokens=1,3* delims=,- " %%i in (test.txt) do echo %%i %%j %%k
Pause
Del test.txt
運行顯示結果
11段 13段 14段 15段 16段
21段 23段 24段,25段,26段
31段 33段 34段-35段-36段
請按任意鍵繼續. . .
爲何會這樣?我來解釋
eol=;          分號開頭的行爲註釋行
tokens=1,3*    將每行第1段,第3段和剩餘字段分別賦予變量%%i%%j%%k
delims=,-     減號後有一空格以逗號減號和空格爲分隔符空格必須放在最後

For命令例2****************************************
@echo off
FOR /F "eol= delims=" %%i in (test.txt) do echo %%i
Pause
運行將顯示test.txt所有內容包括註釋行不解釋了哈。

For命令例3****************************************
另外/F參數還能夠以輸出命令的結果看這個例子
@echo off
FOR /F "delims=" %%i in ('net user') do @echo %%i
pause
這樣你本機所有賬號名字就出來了把擴號內的內容用兩個單引號引發來就表示那個當命令執行,FOR會返回命令的每行結果,加那個"delims=" 是爲了讓我空格的行能整行顯示出來,不加就只顯示空格左邊一列!

基本上講完了FOR的基本用法了...若是你看過FOR的系統幫助,你會發現他下面還有一些特定義的變量,這些我先不講.你們因該都累了吧!你不累我累啊....
所謂文武之道一張一弛現休息一下。






第三章 FOR命令中的變量
FOR命令中有一些變量,他們的用法許多新手朋友還不太瞭解,今天給你們講解他們的用法!

先把FOR的變量所有列出來:
     ~I          - 刪除任何引號(")擴展 %I
     %~fI        - 將 %I 擴展到一個徹底合格的路徑名
     %~dI        - 僅將 %I 擴展到一個驅動器號
     %~pI        - 僅將 %I 擴展到一個路徑
     %~nI        - 僅將 %I 擴展到一個文件名
     %~xI        - 僅將 %I 擴展到一個文件擴展名
     %~sI        - 擴展的路徑只含有短名
     %~aI        - 將 %I 擴展到文件的文件屬性
     %~tI        - 將 %I 擴展到文件的日期/時間
     %~zI        - 將 %I 擴展到文件的大小
     %~$PATH:I   - 查找列在路徑環境變量的目錄並將 %I 擴展
                   到找到的第一個徹底合格的名稱。若是環境變量名
                   未被定義或者沒有找到文件此組合鍵會擴展到
                   空字符串

咱們能夠看到每行都有一個大寫字母"I",這個I其實就是咱們在FOR帶入的變量,咱們FOR語句代入的變量名是什麼,這裏就寫什麼.
好比:FOR /F  %%z IN ('set') DO @echo %%z
這裏咱們代入的變量名是z那麼咱們就要把那個I改爲z,例如%~fI改成%~fz
至於前面的%~p這樣的內容就是語法了!

好開始講解:

1、 ~I          - 刪除任何引號(")擴展 %I
這個變量的做用就如他的說明,刪除引號!
咱們來看這個例子:
首先創建臨時文件temp.txt內容以下
"1111
"2222"
3333"
"4444"44
"55"55"55
可創建個BAT文件代碼以下:
@echo off
echo ^"1111>temp.txt
echo "2222">>temp.txt
echo 3333^">>temp.txt
echo "4444"44>>temp.txt
echo ^"55"55"55>>temp.txt
rem 上面創建臨時文件注意不成對的引號要加轉義字符^重定向符號前不要留空格
FOR /F "delims=" %%i IN (temp.txt) DO echo  %%~i
pause
del temp.txt
執行後,咱們看CMD的回顯以下:
1111           #字符串前的引號被刪除了
2222           #字符串首尾的引號都被刪除了
3333"          #字符串前無引號後面的引號保留
4444"44        #字符串前面的引號刪除了而中間的引號保留
55"55"55       #字符串前面的引號刪除了而中間的引號保留
請按任意鍵繼續. . .
和以前temp.txt中的內容對比一下,咱們會發現第一、二、5行的引號都消失了,這就是刪除引號~i的做用了!
刪除引號規則以下(BAT兄補充!)
一、若字符串首尾同時存在引號則刪除首尾的引號
二、若字符串尾不存在引號則刪除字符串首的引號
三、若是字符串中間存在引號或者只在尾部存在引號則不刪除。
龍捲風補充無頭不刪有頭連尾刪。


2、 %~fI        - 將 %I 擴展到一個徹底合格的路徑名
看例子:
把代碼保存放在隨便哪一個地方,我這裏就放桌面吧.
FOR /F "delims==" %%i IN ('dir /b') DO @echo  %%~fi
pause
執行後顯示內容以下
C:\Documents and Settings\Administrator\桌面\test.bat
C:\Documents and Settings\Administrator\桌面\test.vbs
當我把代碼中的 %%~fi直接改爲%%i
FOR /F "delims==" %%i IN ('dir /b') DO @echo  %%i
pause
執行後就會顯示如下內容
test.bat
test.vbs
經過對比,咱們很容易就看出沒有路徑了,這就是"將 %I 擴展到一個徹底合格的路徑名"的做用
也就是若是%i變量的內容是一個文件名的話,他就會把這個文件所在的絕對路徑打印出來,而不僅單單打印一個文件名,本身動手動實驗下就知道了!


3、 %~dI        - 僅將 %I 擴展到一個驅動器號
看例子:
代碼以下,我仍是放到桌面執行!
FOR /F "delims==" %%i IN ('dir /b') DO @echo  %%~di
pause
執行後我CMD裏顯示以下
C:
C:
我桌面就兩個文件test.bat,test.vbs,%%~di做用是,若是變量%%i的內容是一個文件或者目錄名,他就會把他這文件
或者目錄所在的盤符號打印出來!


4、 %~pI        - 僅將 %I 擴展到一個路徑
這個用法和上面同樣,他只打印路徑不打印文件名字
FOR /F "delims==" %%i IN ('dir /b') DO @echo  %%~pi
pause
我就不打結果了,你們本身複製代碼看結果吧,下面幾個都是這麼個用法,代碼給出來,你們本身看結果吧!


5、 %~nI        - 僅將 %I 擴展到一個文件名
只打印文件名字
FOR /F "delims==" %%i IN ('dir /b') DO @echo  %%~ni
pause


6、 %~xI        - 僅將 %I 擴展到一個文件擴展名
只打印文件的擴展名
FOR /F "delims==" %%i IN ('dir /b') DO @echo  %%~xi
pause


7、 %~sI        - 擴展的路徑只含有短名
打印絕對短文件名
FOR /F "delims==" %%i IN ('dir /b') DO @echo  %%~si
pause


8、 %~aI        - 將 %I 擴展到文件的文件屬性
打印文件的屬性
FOR /F "delims==" %%i IN ('dir /b') DO @echo  %%~ai
pause


9、 %~tI        - 將 %I 擴展到文件的日期/時間
打印文件創建的日期
FOR /F "delims==" %%i IN ('dir /b') DO @echo  %%~ti
pause

10、 %~zI        - 將 %I 擴展到文件的大小
打印文件的大小
FOR /F "delims==" %%i IN ('dir /b') DO @echo  %%~zi
pause
上面例子中的"delims=="能夠改成"delims="即不要分隔符


11、 %~$PATH:I - 查找列在路徑環境變量的目錄並將 %I 擴展
                   到找到的第一個徹底合格的名稱。若是環境變量名
                   未被定義或者沒有找到文件此組合鍵會擴展到
                   空字符串
這是最後一個,和上面那些都不同,我單獨說說!

而後在把這些代碼保存爲批處理,放在桌面。
@echo off
FOR /F "delims=" %%i IN (「notepad.exe」) DO echo  %%~$PATH:i
pause
龍捲風補充上面代碼顯示結果爲C:\WINDOWS\system32\notepad.exe
他的意思就在PATH變量裏指定的路徑裏搜索notepad.exe文件若是有notepad.exe則會把他所在絕對路徑打印出來沒有就打印一個錯誤

好了,FOR的的變量就介紹到這了!
                                 
第四章 批處理中的變量
批處理中的變量,我把他分爲兩類,分別爲"系統變量"和"自定義變量"
咱們如今來詳解這兩個變量!

1、系統變量
他們的值由系統將其根據事先定義的條件自動賦值,也就是這些變量系統已經給他們定義了值,
不須要咱們來給他賦值,咱們只須要調用而以!  我把他們所有列出來!

%ALLUSERSPROFILE% 本地 返回「全部用戶」配置文件的位置。
%APPDATA% 本地 返回默認狀況下應用程序存儲數據的位置。
%CD% 本地 返回當前目錄字符串。
%CMDCMDLINE% 本地 返回用來啓動當前的 Cmd.exe 的準確命令行。
%CMDEXTVERSION% 系統 返回當前的「命令處理程序擴展」的版本號。
%COMPUTERNAME%  系統 返回計算機的名稱。
%COMSPEC%  系統 返回命令行解釋器可執行程序的準確路徑。
%DATE%  系統 返回當前日期。使用與 date /t 命令相同的格式。由 Cmd.exe 生成。有關
date 命令的詳細信息請參閱 Date。
%ERRORLEVEL%  系統 返回上一條命令的錯誤代碼。一般用非零值表示錯誤。
%HOMEDRIVE%  系統 返回鏈接到用戶主目錄的本地工做站驅動器號。基於主目錄值而設置。用
戶主目錄是在「本地用戶和組」中指定的。
%HOMEPATH%  系統 返回用戶主目錄的完整路徑。基於主目錄值而設置。用戶主目錄是在「本地用戶和組」中指定的。
%HOMESHARE%  系統 返回用戶的共享主目錄的網絡路徑。基於主目錄值而設置。用戶主目錄是
在「本地用戶和組」中指定的。
%LOGONSERVER%  本地 返回驗證當前登陸會話的域控制器的名稱。
%NUMBER_OF_PROCESSORS%  系統 指定安裝在計算機上的處理器的數目。
%OS%  系統 返回操做系統名稱。Windows 2000 顯示其操做系統爲 Windows_NT。
%PATH% 系統 指定可執行文件的搜索路徑。
%PATHEXT% 系統 返回操做系統認爲可執行的文件擴展名的列表。
%PROCESSOR_ARCHITECTURE%  系統 返回處理器的芯片體系結構。值x86 或 IA64 基於
Itanium
%PROCESSOR_IDENTFIER% 系統 返回處理器說明。
%PROCESSOR_LEVEL%  系統 返回計算機上安裝的處理器的型號。
%PROCESSOR_REVISION% 系統 返回處理器的版本號。
%PROMPT% 本地 返回當前解釋程序的命令提示符設置。由 Cmd.exe 生成。
%RANDOM% 系統 返回 0 到 32767 之間的任意十進制數字。由 Cmd.exe 生成。
%SYSTEMDRIVE% 系統 返回包含 Windows server operating system 根目錄即系統根目錄
的驅動器。
%SYSTEMROOT%  系統 返回 Windows server operating system 根目錄的位置。
%TEMP% 和 %TMP% 系統和用戶 返回對當前登陸用戶可用的應用程序所使用的默認臨時目錄。
有些應用程序須要 TEMP而其餘應用程序則須要 TMP。
%TIME% 系統 返回當前時間。使用與 time /t 命令相同的格式。由 Cmd.exe 生成。有關
time 命令的詳細信息請參閱 Time。
%USERDOMAIN% 本地 返回包含用戶賬戶的域的名稱。
%USERNAME% 本地 返回當前登陸的用戶的名稱。
%USERPROFILE% 本地 返回當前用戶的配置文件的位置。
%WINDIR% 系統 返回操做系統目錄的位置。

這麼多系統變量,咱們如何知道他的值是什麼呢?
在CMD裏輸入  echo %WINDIR%
這樣就能顯示一個變量的值了!
舉個實際例子,好比咱們要複製文件到當前賬號的啓動目錄裏就能夠這樣
copy d:\1.bat "%USERPROFILE%\「開始」菜單\程序\啓動\"
%USERNAME% 本地 返回當前登陸的用戶的名稱。  注意有空格的目錄要用引號引發來

另外還有一些系統變量,他們是表明一個意思,或者一個操做!
他們分別是%0 %1 %2 %3 %4 %5 ......一直到%9 還有一個%*
%0 這個有點特殊,有幾層意思,先講%1-%9的意思.
%1 返回批處理的第一個參數
%2 返回批處理的第二個參數
%3-%9依此推類
反回批處理參數?到底怎麼個返回法?
咱們看這個例子,把下面的代碼保存爲test.BAT而後放到C盤下
@echo off
echo %1 %2 %3 %4
echo %1
echo %2
echo %3
echo %4
進入CMD,輸入cd c:\
而後輸入 test.bat 我是第一個參數 我是第二個參數  我是第三個參數  我是第四個參數
注意中間的空格,咱們會看到這樣的結果:
我是第一個參數 我是第二個參數 我是第三個參數 我是第四個參數
我是第一個參數
我是第二個參數
我是第三個參數
我是第四個參數
對比下代碼,%1就是」我是第一個參數」  %2就是」我是第二個參數」
怎麼樣理解了吧!

這些%1和%9可讓批處理也能帶參數運行,大大提升批處理功能!

還有一個%*  他是什麼呢?他的做用不是很大,只是返回參數而已,不過他是一次返回所有參數的值,不用在輸入%1 %2來肯定一個個的

例子
@echo off
echo %*
一樣保存爲test.bat 放到C盤
進入CMD,輸入cd c:\
而後輸入 test.bat 我是第一個參數 我是第二個參數  我是第三個參數  我是第四個參數
能夠看到他一次把所有參數都顯示出來了

好如今開始講那個比較特殊的%0

%0  這個不是返回參數的值了,他有兩層意思!
第一層意思:返回批處理所在絕對路徑
例子:
@echo off
echo %0
pause
保存爲test.BAT放在桌面運行,會顯示以下結果
"C:\Documents and Settings\Administrator\桌面\test.bat"
他把當前批處理執行的所在路經打印出來了,這就是返回批處理所在絕對路徑的意思
第二層意思:無限循環執行BAT
例子:
@echo off
net user
%0
保存爲BAT執行,他就會無限循環執行net user這條命令,直到你手動中止.
龍捲風補充其實%0就是第一參數%1前面那個參數固然就是批處理文件名包括路徑。
以上就是批處理中的一些系統變量,另外還有一些變量,他們也表示一些功能,
FOR命令中的那些就是,FOR變量已經說過,就不講了.


2、自定義變量
故名思意,自定義變量就是由咱們來給他賦予值的變量
要使用自定義變量就得使用set命令了,看例子.
@echo off
set var=我是值
echo %var%
pause
保存爲BAT執行,咱們會看到CMD裏返回一個  "我是值"
var爲變量名,=號右變的是要給變量的值
這就是最簡單的一種設置變量的方法了
若是咱們想讓用戶手工輸入變量的值,而不是在代碼裏指定,能夠用用set命令的/p參數
例子:
@echo off
set /p var=請輸入變量的值
echo %var%
pause
var變量名  =號右邊的是提示語,不是變量的值
變量的值由咱們運行後本身用鍵盤輸入! 

1、交互界面設計

沒啥說的看看高手設計的菜單界面吧
@echo off
cls
title 終極多功能修復
:menu
cls
color 0A
echo.
echo                 ==============================
echo                 請選擇要進行的操做而後按回車
echo                 ==============================
echo.
echo              1.網絡修復及上網相關設置,修復IE,自定義屏蔽網站
echo.
echo              2.病毒專殺工具端口關閉工具,關閉自動播放
echo.
echo              3.清除全部多餘的自啓動項目修復系統錯誤
echo.
echo              4.清理系統垃圾,提升啓動速度
echo.
echo              Q.退出
echo.
echo.
:cho
set choice=
set /p choice=          請選擇:
IF NOT "%choice%"=="" SET choice=%choice:~0,1%
if /i "%choice%"=="1" goto ip
if /i "%choice%"=="2" goto setsave
if /i "%choice%"=="3" goto kaiji
if /i "%choice%"=="4" goto clean
if /i "%choice%"=="Q" goto endd
echo 選擇無效請從新輸入
echo.
goto cho
只要學完本教程前面的章節上面的程序應該能看懂了。





2、if…else…條件語句

前面已經談到DOS條件語句主要有如下形式
IF [NOT] ERRORLEVEL number command
IF [NOT] string1==string2 command
IF [NOT] EXIST filename command
加強用法IF [/I] string1 compare-op string2 command
加強用法中加上/I就不區分大小寫了!
加強用法中還有一些用來判斷數字的符號

EQU - 等於
NEQ - 不等於
LSS - 小於
LEQ - 小於或等於
GTR - 大於
GEQ - 大於或等於


上面的command命令均可以用小括號來使用多條命令的組合包括else子句組合命令中能夠嵌套使用條件或循環命令。

例如:

    IF EXIST filename (
        del filename
    ) ELSE (
        echo filename missing
    )

也可寫成
if exist filename (del filename) else (echo filename missing)
但這種寫法不適合命令太多或嵌套命令的使用。


3、循環語句

一、指定次數循環
FOR /L %variable IN (start,step,end) DO command [command-parameters]

組合命令
FOR /L %variable IN (start,step,end) DO (
Command1
Command2
……
) 

二、對某集合執行循環語句。
FOR %%variable IN (set) DO command [command-parameters]

  %%variable  指定一個單一字母可替換的參數。
  (set)      指定一個或一組文件。可使用通配符。
  command   對每一個文件執行的命令可用小括號使用多條命令組合。

FOR /R [[drive:]path] %variable IN (set) DO command [command-parameters]

    檢查以 [drive:]path 爲根的目錄樹指向每一個目錄中的
    FOR 語句。若是在 /R 後沒有指定目錄則使用當前
目錄。若是集僅爲一個單點(.)字符則枚舉該目錄樹。

同前面同樣command能夠用括號來組合
FOR /R [[drive:]path] %variable IN (set) DO (
Command1
Command2
……
commandn
)

三、條件循環
    上面的循環結構是用for命令來實現的for命令循環有一個缺點就是整個循環被看成一條命令語句涉及到變量延遲的問題。
    利用goto語句和條件判斷dos能夠實現條件循環很簡單啦看例子

例
@echo off
set var=0
rem ************循環開始了
:continue
set /a var+=1
echo 第%var%次循環
if %var% lss 100 goto continue
rem ************循環結束了
echo 循環執行完畢
pause

例
@echo off
set var=100
rem ************循環開始了
:continue
echo 第%var%次循環
set /a var-=1
if %var% gtr 0 goto continue
rem ************循環結束了
echo 循環執行完畢
pause





4、子程序

在批處理程序中能夠調用外部可運行程序好比exe程序也可調用其餘批處理程序這些也能夠看做子程序可是不夠方便若是被調用的程序不少就顯得不夠簡明瞭很繁瑣。
   在windowsXP中批處理能夠調用本程序中的一個程序段至關於子程序這些子程序通常放在主程序後面。

子程序調用格式
  CALL :label arguments

子程序語法
  :label
  command1
  command2
  ......
  commandn
  goto :eof

在子程序段中參數%0指標籤:label

子過程通常放在最後而且注意在主程序最後要加上exit或跳轉語句避免錯誤的進入子過程。

子程序和主程序中的變量都是全局變量其做用範圍都是整個批處理程序。

傳至子程序的參數在call語句中指定在子程序中用%一、%2至%9的形式調用而子程序返回主程序的數據只需在調用結束後直接引用就能夠了固然也能夠指定返回變量請看下面的例子。

子程序例1
@echo off
call :sub return 你好
echo 子程序返回值%return%
pause

:sub
set %1=%2
goto :eof
運行結果你好



子程序例2設計一個求多個整數相加的子程序
@echo off
set sum=0
call :sub sum 10 20 35
echo 數據求和結果%sum%
pause

:sub
rem 參數1爲返回變量名稱
set /a %1=%1+%2
shift /2
if not "%2"=="" goto sub
goto :eof

運行結果65

5、用ftp命令實現自動下載

ftp是經常使用的下載工具ftp界面中有40多個經常使用命令本身學習了不介紹了。這裏介紹如何用dos命令行調用ftp命令實現ftp自動登陸並上傳下載並自動退出ftp程序。
其實能夠將ftp命令組合保存爲一個文本文件而後用如下命令調用便可。

ftp  -n -s:[[drive:]path]filename

上面的filename爲ftp命令文件包括登陸IP地址用戶名、密碼、操做命令等
例
open 90.52.8.3   打開ip
user iware       用戶爲iware
password8848    密碼
bin             二進制傳輸模式
prompt
cd tmp1         切換至iware用戶下的tmp1目錄
pwd
lcd d:\download   本地目錄
mget *          下載tmp1目錄下的全部文件
bye             退出ftp




6、用7-ZIP實現命令行壓縮和解壓功能

語法格式詳細狀況見7-zip幫助文件看得頭暈能夠跳過用到再學
7z <command> [<switch>...] <base_archive_name> [<arguments>...]

7z.exe的每一個命令都有不一樣的參數<switch>,請看幫助文件
<base_archive_name>爲壓縮包名稱
<arguments>爲文件名稱支持通配符或文件列表

其中7z是至命令行壓縮解壓程序7z.exe<command>是7z.exe包含的命令列舉以下

a Adds files to archive. 添加至壓縮包
a命令可用參數
  -i (Include)
  -m (Method)
  -p (Set Password)
  -r (Recurse)
  -sfx (create SFX)
  -si (use StdIn)
  -so (use StdOut)
  -ssw (Compress shared files)
  -t (Type of archive)
  -u (Update)
  -v (Volumes)
  -w (Working Dir)
  -x (Exclude) 

b Benchmark 

d Deletes files from archive. 從壓縮包中刪除文件
d命令可用參數
  -i (Include)
  -m (Method)
  -p (Set Password)
  -r (Recurse)
  -u (Update)
  -w (Working Dir)
  -x (Exclude) 

e Extract解壓文件至當前目錄或指定目錄
e命令可用參數
  -ai (Include archives)
  -an (Disable parsing of archive_name)
  -ao (Overwrite mode)
  -ax (Exclude archives)
  -i (Include)
  -o (Set Output Directory)
  -p (Set Password)
  -r (Recurse)
  -so (use StdOut)
  -x (Exclude)
  -y (Assume Yes on all queries) 

l Lists contents of archive.
t Test 
u Update 

x eXtract with full paths用文件的完整路徑解壓至當前目錄或指定目錄
x命令可用參數
  -ai (Include archives)
  -an (Disable parsing of archive_name)
  -ao (Overwrite mode)
  -ax (Exclude archives)
  -i (Include)
  -o (Set Output Directory)
  -p (Set Password)
  -r (Recurse)
  -so (use StdOut)
  -x (Exclude)
  -y (Assume Yes on all queries) 




7、調用VB******程序

使用 Windows 腳本宿主能夠在命令提示符下運行腳本。C******.exe 提供了用於設置腳本屬性的命令行開關。


用法C****** 腳本名稱 [腳本選項...] [腳本參數...]

選項
//B         批模式不顯示腳本錯誤及提示信息
//D         啓用 Active Debugging
//E:engine  使用執行腳本的引擎
//H:C****** 將默認的腳本宿主改成 C******.exe
//H:W****** 將默認的腳本宿主改成 W******.exe 默認
//I         交互模式默認與 //B 相對)
//Job:xxxx  執行一個 WSF 工做
//Logo      顯示徽標默認
//Nologo    不顯示徽標執行時不顯示標誌
//S         爲該用戶保存當前命令行選項
//T:nn      超時設定秒容許腳本運行的最長時間
//X         在調試器中執行腳本
//U         用 Unicode 表示來自控制檯的重定向 I/O


「腳本名稱」是帶有擴展名和必需的路徑信息的腳本文件名稱如d:\admin\vb******s\chart.vbs。
「腳本選項和參數」將傳遞給腳本。腳本參數前面有一個斜槓 (/)。每一個參數都是可選的但不能在未指定腳本名稱的狀況下指定腳本選項。若是未指定參數則 C****** 將顯示 C****** 語法和有效的宿主參數。




8、將批處理轉化爲可執行文件

因爲批處理文件是一種文本文件任何人均可以對其進行隨便編輯不當心就會把裏面的命令破壞掉因此若是將其轉換成.com格式的可執行文件不只執行效率會大大提升並且不會破壞原來的功能更能將優先級提到最高。Bat2Com就能夠完成這個轉換工做。
小知識在DOS環境下可執行文件的優先級由高到低依次爲.com>.exe>.bat>.cmd即若是在同一目錄下存在文件名相同的這四類文件當只鍵入文件名時DOS執行的是name.com若是須要執行其餘三個文件則必須指定文件的全名如name.bat。

這是一個只有5.43K大小的免費綠色工具能夠運行在純DOS或DOS窗口的命令行中用法Bat2Com
FileName這樣就會在同一目錄下生成一個名爲FileNme.com的可執行文件執行的效果和原來的.bat文件同樣。

9、時間延遲

本條參考引用[英雄]教程
什麼是時間延遲顧名思義就是執行一條命令後延遲一段時間再進行下一條命令。
延遲的應用見下節「模擬進度條」。
一、利用ping命令延時
例
  @echo off
  echo 延時前%time%
  ping /n 3 127.0.0.1 >nul
  echo 延時後%time%
  pause 
解說用到了ping命令的「/n」參數表示要發送多少次請求到指定的ip。本例中要發送3次請求到本機的ip127.0.0.1。127.0.0.1可簡寫爲127.1。「>nul」就是屏蔽掉ping命令所顯示的內容。

二、利用for命令延時
例
  @echo off
  echo 延時前%time%
  for /l %%i in (1,1,5000) do echo %%i>nul
  echo 延時後%time%
  pause
解說原理很簡單就是利用一個計次循環並屏蔽它所顯示的內容來達到延時的目的。

三、利用vbs延遲函數精確度毫秒偏差1000毫秒內

例
    @echo off
    echo %time%
    call :delay 5000
    echo %time%
    pause
    exit

    :delay
    echo W******.Sleep %1>delay.vbs
    C****** //B delay.vbs
    del delay.vbs
    goto :eof

運行顯示
10:44:06.45
10:44:11.95
請按任意鍵繼續. . .

上面的運行結果顯示實際延時了5500毫秒多出來的500毫秒時創建和刪除臨時文件所耗費的時間。偏差在一秒以內。


四、僅用批處理命令實現任意時間延遲精確度10毫秒偏差50毫秒內

僅用批處理命令就能夠實現延遲操做。

例

@echo off
set /p delay=請輸入需延遲的毫秒數
set TotalTime=0
set NowTime=%time%
::讀取起始時間時間格式爲13:01:05.95
echo 程序開始時間%NowTime%
:delay_continue
set /a minute1=1%NowTime:~3,2%-100
::讀取起始時間的分鐘數
set /a second1=1%NowTime:~-5,2%%NowTime:~-2%0-100000
::將起始時間的秒數轉爲毫秒
set NowTime=%time%
set /a minute2=1%NowTime:~3,2%-100
:: 讀取如今時間的分鐘數
set /a second2=1%NowTime:~-5,2%%NowTime:~-2%0-100000
::將如今時間的秒數轉爲毫秒
set /a TotalTime+=(%minute2%-%minute1%+60)%%60*60000+%second2%-%second1%
if %TotalTime% lss %delay% goto delay_continue
echo 程序結束時間%time%
echo 設定延遲時間%delay%毫秒
echo 實際延遲時間%TotalTime%毫秒
pause

運行顯示

   請輸入需延遲的毫秒數6000
   程序開始時間15:32:16.37
   程序結束時間15:32:22.37
   設定延遲時間6000毫秒
   實際延遲時間6000毫秒
   請按任意鍵繼續. . .

實現原理首先設定要延遲的毫秒數而後用循環累加時間直到累加時間大於等於延遲時間。

偏差windows系統時間只能精確到10毫秒因此理論上有可能存在10毫秒偏差。
      經測試當延遲時間大於500毫秒時上面的延遲程序通常不存在偏差。當延遲時間小於500毫秒時可能有幾十毫秒偏差爲何由於延遲程序自己也是有運行時間的同時系統時間只能精確到10毫秒。

爲了方便引用可將上面的例子改成子程序調用形式

@echo off
echo 程序開始時間%Time%
call :delay 10
echo 實際延遲時間%totaltime%毫秒
echo 程序結束時間%time%
pause
exit

::-----------如下爲延時子程序--------------------
:delay
@echo off
if "%1"=="" goto :eof
set DelayTime=%1
set TotalTime=0
set NowTime=%time%
::讀取起始時間時間格式爲13:01:05.95
:delay_continue
set /a minute1=1%NowTime:~3,2%-100
set /a second1=1%NowTime:~-5,2%%NowTime:~-2%0-100000
set NowTime=%time%
set /a minute2=1%NowTime:~3,2%-100
set /a second2=1%NowTime:~-5,2%%NowTime:~-2%0-100000
set /a TotalTime+=(%minute2%-%minute1%+60)%%60*60000+%second2%-%second1%
if %TotalTime% lss %DelayTime% goto delay_continue
goto :eof






10、模擬進度條

下面給出一個模擬進度條的程序。若是將它運用在你本身的程序中可使你的程序更漂亮。

@echo off
mode con cols=113 lines=15 &color 9f
cls
echo.
echo  程序正在初始化. . . 
echo.
echo  ┌──────────────────────────────────────┐
set/p=  ■<nul
for /L %%i in (1 1 38) do set /p a=■<nul&ping /n 1 127.0.0.1>nul
echo   100%%
echo  └──────────────────────────────────────┘
pause

解說「set /p a=■<nul」的意思是隻顯示提示信息「■」且不換行也不需手工輸入任何信息這樣可使每一個「■」在同一行逐個輸出。「ping /n 0 127.1>nul」是輸出每一個「■」的時間間隔即每隔多少時間輸出一個「■」。





11、特殊字符的輸入及應用

開始 -> 運行 -> 輸入cmd -> edit -> ctrl+p意思是容許輸入特殊字符-> 按ctrl+a將會顯示笑臉圖案。

若是要繼續輸入特殊字符請再次按ctrl+p而後ctrl+某個字母

以上是特殊字符的輸入方法選自[英雄]教程很管用的。也就是用編輯程序edit輸入特殊字符而後保存爲一文本文件再在windows下打開此文件複製其中的特殊符號便可。

一些簡單的特殊符號能夠在dos命令窗口直接輸入並用重定向保存爲文本文件。
例
C:>ECHO ^G>temp.txt
「^G」是用CtrlG或Alt007輸入輸入多個^G能夠產生多聲鳴響。


特殊字符的應用也頗有意思這裏僅舉一例退格鍵

退格鍵表示刪除左邊的字符此鍵不能在文檔中正常輸入但能夠經過edit編輯程序錄入並複製出來。即「」。

利用退格鍵能夠設計閃爍文字效果



例文字閃爍
@echo off
:start
set/p=牀前明月光<nul
::顯示文字光標停於行尾
ping -n 0 127.0.0.1>nul
::設置延遲時間
set /p a=<nul
:: 輸出一些退格符將光標置於該行的最左端退格符的數量能夠本身調整。
set /p a=                               <nul
::輸出空格將以前輸出的文字覆蓋掉。
set /p a=<nul
::再次輸出退格符將光標置於該行的最左端這裏的退格符數量必定不能比前面的空格數少。
::不然光標不能退到最左端。
goto start


例輸出唐詩一首每行閃動屢次
@echo off
setlocal enabledelayedexpansion

set str=牀前明月光 疑是地上霜 舉頭望明月 低頭思故鄉
::定義字符串str
for %%i in (%str%) do (
rem 因爲str中含有空格則以空格爲分隔符將str中的每個部分依次賦給變量%%i。
        set char=%%i
        echo.
        echo.
        for /l %%j in (0,1,5) do (
                set/p=!char:~%%j,1!<nul
  rem 依次取出變量char中的每個字符並顯示。
                ping -n 0 127.0.0.1>nul
  rem 設置輸出每一個字符的時間延遲。
        )
call :hero %%i
)
pause>nul
exit

:hero
for /l %%k in (1,1,10) do (
ping /n 0 127.0.0.1>nul
set /p a=<nul
set /p a=                               <nul
set /p a=<nul
ping /n 0 127.0.0.1>nul
set /p a=%1<nul
)
::文字閃動
goto :eof

12、隨機數%random%的應用技巧

%RANDOM% 系統變量 返回 0 到 32767 之間的任意十進制數字。由 Cmd.exe 生成。

2的15次方等於32768上面的032767實際就是15位二進制數的範圍。

那麼如何獲取100之內的隨機數呢很簡單將%RANDOM%按100進行求餘運算便可見例子。

例生成5個100之內的隨機數
  @echo off
  setlocal enabledelayedexpansion
  for /L %%i in (1 1 5) do (
     set /a randomNum=!random!%%100
     echo 隨機數!randomNum!
  )
  pause
運行結果每次運行不同
隨機數91
隨機數67
隨機數58
隨機數26
隨機數20
請按任意鍵繼續. . .

求餘數運算set /a randomNum=!random!%%100中的100能夠是132768之間的任意整數。

總結利用系統變量%random%求餘數運算%%字符串處理等能夠實現不少隨機處理。


思考題目生成給定位數的隨機密碼
解答思路將26個英文字母或10數字以及其它特殊字符組成一個字符串隨機抽取其中的若干字符。

參考答案1簡單
@echo off
call :randomPassword 5 pass1 pass2
echo %pass1% %pass2% 
pause
exit

:randomPassword
::---------生成隨機密碼
::---------%1爲密碼長度%2及之後爲返回變量名稱
::---------for命令最多隻能區分31個字段
@echo off
set password_len=%1
if not defined password_len goto :eof
if %password_len% lss 1 goto :eof
set wordset=a b c d e f g h i j k l m n o p q r s t u v w x y z
set return=
set num=0
:randomPassword1
set /a num+=1
set /a numof=%random%%%26+1
for /f "tokens=%numof% delims= " %%i in ("%wordset%") do set return=%return%%%i
if %num% lss %password_len% goto randomPassword1
if not "%2"=="" set %2=%return%
shift /2
if not "%2"=="" goto randomPassword
goto :eof





參考答案2最優
@echo off
call :randomPassword 6 pass1 pass2 pass3
echo %pass1% %pass2% %pass3%
pause
exit

:randomPassword
::---------生成隨機密碼
::---------%1爲密碼長度%2及之後爲返回變量名稱
::---------goto循環、變量嵌套、命令嵌套
@echo off
if "%1"=="" goto :eof
if %1 lss 1 goto :eof
set password_len=%1
set return=
set wordset=abcdefghijklmnopqrstuvwxyz023456789_
::---------------------------循環
:randomPassword1
set /a numof=%random%%%36
call set return=%return%%%wordset:~%numof%,1%%
set /a password_len-=1
if %password_len% gtr 0 goto randomPassword1
::---------------------------循環
if not "%2"=="" set %2=%return%
shift /2
if not "%2"=="" goto randomPassword
goto :eof



說明本例涉及到變量嵌套和命令嵌套的應用見後。





十3、變量嵌套 與 命令嵌套

    和其它編程語言相比dos功能顯得相對簡單要實現比較複雜的功能須要充分運用各類技巧變量嵌套與命令嵌套就是此類技巧之一。

先複習一下前面的「字符串截取」的關鍵內容

**********************************************
截取功能統一語法格式爲%a:~[m[,n]]%
**********************************************
方括號表示可選%爲變量標識符a爲變量名不可少冒號用於分隔變量名和說明部分符號能夠簡單理解爲「偏移」便可m爲偏移量缺省爲0n爲截取長度缺省爲所有。

百分號若是須要當成單一字符必須寫成%%

以上是dos變量處理的通用格式若是其中的m、n爲變量那麼這種狀況就是變量嵌套了。

好比設變量word爲「abcdefghij」變量num爲「123456789」
%word:~4,1%爲e其中4能夠從變量num中取值即%num:~3,1%寫成組合形式以下
%word:~%num:~3,1%,1% 經測試這種寫法不能正確執行寫成%word:~(%num:~3,1%),1%一樣不行那麼怎麼實現這種變量嵌套呢這就必須結合命令嵌套。

什麼是命令嵌套呢簡單的說首先用一條dos命令生成一個字符串而這個字符串是另外一條dos命令用call語句調用字符串將其執行從而獲得最終結果。

例用call語句實現命令嵌套
@echo off
set str1=aaa echo ok bbb
echo 初始字符串%str1%
echo 生成命令字符串以下
echo %str1:~4,7%
echo 運行命令字符串生成最終結果爲
call %str1:~4,7%
pause

運行顯示
初始字符串aaa echo ok bbb
生成命令字符串以下
echo ok
運行命令字符串生成最終結果爲
ok
請按任意鍵繼續. . .