Erlang/OTP之gen_fsm行爲模式

　1. Fsm 稱爲 有限狀態機，舉個例子，遊戲中的怪物稱爲NPC，NPC通常有幾種狀態，好比：靜止，移動，死亡，被攻擊，攻擊英雄等等幾個有限的狀態，那麼咱們就能夠有限狀態機實現NPC的狀態變動。

　　一個有限狀態機能夠用一個關係式來描述，State(靜止狀態S1) x Event(英雄進入視野範圍事件E) -> Actions(開始移動動做A), State(移動狀態S2)

　　解釋以下：當一個NPC處於靜止狀態S1，有一個英雄進入NPC視野範圍時E，會觸發NPC開始移動動做A,而且NPC轉變狀態爲移動狀態S2。

　　對於一個用 gen_fsm 行爲實現的FSM來講，狀態轉換規則被寫爲符合以下約定的一系列Erlang函數：

StateName( Event, StateData ) ->

　　　　.. 這裏放動做的代碼 ...

　　　　{ next_state, StateName', StateData' }

　　2. 接下來咱們來看個例子，遊戲中NPC狀態變化，固然我作了很大的簡化，真正遊戲中的邏輯比這複雜的多。這裏我只是爲了說明，erlang OTP設計原則中的gen_fsm如何使用，代碼以下：

-module(npc).

 

-behaviour(gen_fsm).

 

%% API

-export([start_link/0]).

 

%% gen_fsm callbacks

-export([init/1, static/2, moving/2, handle_event/3,

     handle_sync_event/4, handle_info/3, terminate/3, code_change/4]).

 

-export([hero_join/0, hero_leave/0]).

 

-define(SERVER, ?MODULE).

 

-record(npc, {state}).

 

start_link() ->

    gen_fsm:start_link({local, ?SERVER}, ?MODULE, [], []).

 

%% 初始化NPC爲靜止狀態

init([]) ->

    io:format("init...~n"),

    State = #npc{state = static},

    io:format("init State: ~p~n", [State]),

　　 {ok, static, State}.

 

%% 英雄進入視野

hero_join() ->

    gen_fsm:send_event(?SERVER, hero_join).

 

%% 英雄離開視野

hero_leave() ->

    gen_fsm:send_event(?SERVER, hero_leave).

 

%% 靜止狀態下，接受來自客戶端的事件

static(Event, State) ->

    case Event of

    hero_join -> %% 英雄進入視野

        do_moving(), %% 執行動做

        NewState = State#npc{state = moving},

        io:format("npc set state: ~p~n", [NewState]),

        {next_state, moving, NewState}

    end.

 

%% 移動狀態下，接受來自客戶端的事件

moving(Event, State) ->

    case Event of

    hero_leave -> %% 英雄離開視野

        do_static(), %% 執行動做

        NewState = State#npc{state = static},

        io:format("npc set state: ~p~n", [NewState]),

        {next_state, static, NewState}

    end.

 

handle_event(_Event, StateName, State) ->

    {next_state, StateName, State}.

 

handle_sync_event(_Event, _From, StateName, State) ->

    Reply = ok,

    {reply, Reply, StateName, State}.

 

handle_info(_Info, StateName, State) ->

    {next_state, StateName, State}.

 

terminate(_Reason, _StateName, _State) ->

    ok.

 

code_change(_OldVsn, StateName, State, _Extra) ->

    {ok, StateName, State}.

 

%% NPC 開始移動，進入移動狀態

do_moving() ->

    io:format("npc beigin moving...~n").

 

%% NPC 中止移動，進入靜止狀態

do_static() ->

    io:format("npc stop moving, join static...~n").

 　　代碼註釋比較詳細，接下來能夠經過運行代碼，來好好理解下這個例子，

　　1. 首先，調用 npc:start_link(). 來初始化NPC服務；這個時候NPC處於靜止狀態 static；

　　2. 當npc處於靜止狀態時，咱們經過調用 npc:hero_join().來表示有一個俠客進入NPC的視野，那麼這個時候gen_fsm會默認調用當前gen_fsm處於的狀態，也就是static的處理方法，也就是 static(Event, State) 這個函數,這邊可能比較繞，我已經儘可能去用直白的語言來表達，能力有限，你們多思考下，呵呵；

　　3. 當處理 static 函數時，Event 這個變量，就是 gen_fsm:send_event(?SERVER, hero_join). hero_join，緊接着執行對應的動做，在這裏也就是 do_moving(),開始移動；

　　4. 最後，咱們須要返回 {next_state, moving, NewState} 讓gen_fsm進入下一個狀態，也就是 moving 狀態；

　　5. 當npc處於移動時，咱們經過調用 npc:hero_leave(). 來表示 該俠客移動NPC的視野，那麼對應的 moving(Event, State) 函數就會被調用，其餘的處理與 static 時的處理是相似的，這裏就不重複表述了。