Oracle 儲存過程

咱們在進行pl/sql編程時打交道最多的就是存儲過程了。存儲過程的結構是很是的簡單的，咱們在這裏除了學習存儲過程的基本結構外，還會學習編寫存儲過程時相關的一些實用的知識。如：遊標的處理，異常的處理，集合的選擇等等 

1.存儲過程結構 
1.1 第一個存儲過程 

1. create or replace procedure proc1(   
2.   p_para1 varchar2,   
3.   p_para2 out varchar2,   
4.   p_para3 in out varchar2   
5. )as    
6.  v_name varchar2(20);   
7. begin   
8.   v_name := '張三丰';   
9.   p_para3 := v_name;   
10.   dbms_output.put_line('p_para3:'||p_para3);   
11. end;  

上面就是一個最簡單的存儲過程。一個存儲過程大致分爲這麼幾個部分: 
建立語句：create or replace procedure 存儲過程名 
若是沒有or replace語句，則僅僅是新建一個存儲過程。若是系統存在該存儲過程，則會報錯。Create or replace procedure 若是系統中沒有此存儲過程就新建一個，若是系統中有此存儲過程則把原來刪除掉，從新建立一個存儲過程。 
存儲過程名定義：包括存儲過程名和參數列表。參數名和參數類型。參數名不能重複， 參數傳遞方式:IN, OUT, IN OUT 
IN 表示輸入參數，按值傳遞方式。 
OUT 表示輸出參數，能夠理解爲按引用傳遞方式。能夠做爲存儲過程的輸出結果，供外部調用者使用。 
IN OUT 便可做輸入參數，也可做輸出參數。 
參數的數據類型只須要指明類型名便可，不須要指定寬度。 
參數的寬度由外部調用者決定。 
過程能夠有參數，也能夠沒有參數 
變量聲明塊：緊跟着的as (is )關鍵字，能夠理解爲pl/sql的declare關鍵字，用於聲明變量。 
變量聲明塊用於聲明該存儲過程須要用到的變量，它的做用域爲該存儲過程。另外這裏聲明的變量必須指定寬度。遵循PL/SQL的變量聲明規範。 
過程語句塊：從begin 關鍵字開始爲過程的語句塊。存儲過程的具體邏輯在這裏來實現。 
異常處理塊：關鍵字爲exception ，爲處理語句產生的異常。該部分爲可選 
結束塊：由end關鍵字結果。 

1.2 存儲過程的參數傳遞方式 
存儲過程的參數傳遞有三種方式:IN,OUT,IN OUT . 
IN 按值傳遞，而且它不容許在存儲過程當中被從新賦值。若是存儲過程的參數沒有指定存參數傳遞類型，默認爲IN 

1. create or replace procedure proc1(   
2.   p_para1 varchar2,   
3.   p_para2 out varchar2,   
4.   p_para3 in out varchar2   
5. )as    
6.  v_name varchar2(20);   
7. begin   
8.   p_para1 :='aaa';   
9.   p_para2 :='bbb';   
10.   v_name := '張三丰';   
11.   p_para3 := v_name;   
12.   dbms_output.put_line('p_para3:'||p_para3);   
13.   null;   
14. end;   
15.        
16. Warning: Procedure created with compilation errors   
17.   
18. SQL> show error;   
19. Errors for PROCEDURE LIFEMAN.PROC1:   
20.   
21. LINE/COL ERROR   
22. -------- ----------------------------------------------------------------------   
23. 8/3      PLS-00363: expression 'P_PARA1' cannot be used as an assignment target   
24. 8/3      PL/SQL: Statement ignored  

這一點與其它高級語言都不一樣。它至關於java在參數前面加上final關鍵字。 


OUT 參數：做爲輸出參數，須要注意，當一個參數被指定爲OUT類型時，就算在調用存儲過程以前對該參數進行了賦值，在存儲過程當中該參數的值仍然是null. 

1. create or replace procedure proc1(   
2.   p_para1 varchar2,   
3.   p_para2 out varchar2,   
4.   p_para3 in out varchar2   
5. )as    
6.  v_name varchar2(20);   
7. begin   
8.   v_name := '張三丰';   
9.   p_para3 := v_name;   
10.   dbms_output.put_line('p_para1:'||p_para1);   
11.   dbms_output.put_line('p_para2:'||p_para2);   
12.   dbms_output.put_line('p_para3:'||p_para3);   
13. end;   
14.   
15. SQL> var p1 varchar2(10);   
16. SQL> var p2 varchar2(10);   
17. SQL> var p3 varchar2(10);   
18. SQL> exec :p1 :='aaaa';   
19. SQL> exec :p2 :='bbbb';   
20. SQL> exec :p3 :='cccc';   
21. SQL> exec proc1(:p1,:p2,:p3);   
22. p_para1:aaaa   
23. p_para2:   
24. p_para3:張三丰   
25. SQL> exec dbms_output.put_line(:p2);   
26.   
27.   
28. PL/SQL procedure successfully completed   
29. p2   
30. ---------  

INOUT 是真正的按引用傳遞參數。便可做爲傳入參數也能夠做爲傳出參數。 

1. 1.3 存儲過程參數寬度   
2. create or replace procedure proc1(   
3.   p_para1 varchar2,   
4.   p_para2 out varchar2,   
5.   p_para3 in out varchar2   
6. )as    
7.  v_name varchar2(2);   
8. begin   
9.   v_name := p_para1;   
10. end;   
11.   
12. SQL> var p1 varchar2(10);   
13. SQL> var p2 varchar2(20);   
14. SQL> var p3 varchar2(30);   
15. SQL> exec :p1 :='aaaaaa';   
16. SQL> exec proc1(:p1,:p2,:p3);   
17.        
18.        
19. ORA-06502: PL/SQL: numeric or value error: character string buffer too small   
20. ORA-06512: at "LIFEMAN.PROC1", line 8  
21. ORA-06512: at line 1  

首先，咱們要明白，咱們沒法在存儲過程的定義中指定存儲參數的寬度，也就致使了咱們沒法在存儲過程當中控制傳入變量的寬度。這個寬度是徹底由外部傳入時決定的。 
咱們再來看看OUT類型的參數的寬度。 

1. create or replace procedure proc1(   
2.   p_para1 varchar2,   
3.   p_para2 out varchar2,   
4.   p_para3 in out varchar2   
5. )as    
6.  v_name varchar2(2);   
7. begin   
8.   p_para2 :='aaaaaaaaaaaaaaaaaaaa';   
9. end;   
10. SQL> var p1 varchar2(1);   
11. SQL> var p2 varchar2(1);   
12. SQL> var p3 varchar2(1);   
13. SQL> exec :p2 :='a';   
14. SQL> exec proc1(:p1,:p2,:p3);  

在該過程當中，p_para2被賦予了20個字符a. 
而在外部的調用過程當中，p2這個參數僅僅被定義爲varchar2(1). 
而把p2做爲參數調用這個過程，卻並無報錯。並且它的真實值就是20個a 

1. SQL> select dump(:p2) from dual;   
2. DUMP(:P2)   
3. ---------------------------------------------------------------------------   
4. Typ=1 Len=20: 97,97,97,97,97,97,97,97,97,97,97,97,97,97,97,97,97,97,97,97  
5. p2   
6. ---------   
7. aaaaaaaaaaaaaaaaaaaa   
8.        
9.     再來看看IN OUT參數的寬度   
10. create or replace procedure proc1(   
11.   p_para1 varchar2,   
12.   p_para2 out varchar2,   
13.   p_para3 in out varchar2   
14. )as    
15.  v_name varchar2(2);   
16. begin   
17.   p_para3 :='aaaaaaaaaaaaaaaaaaaa';   
18. end;   
19.   
20. SQL> var p1 varchar2(1);   
21. SQL> var p2 varchar2(1);   
22. SQL> var p3 varchar2(1);   
23. SQL> exec proc1(:p1,:p2,:p3);  

執行這個過程，仍然正確執行。 

可見，對於IN參數，其寬度是由外部決定。 
對於OUT 和IN OUT 參數，其寬度是由存儲過程內部決定。 
所以，在寫存儲過程時，對參數的寬度進行說明是很是有必要的，最明智的方法就是參數的數據類型使用%type。這樣雙方就達成了一致。 

1.3 參數的默認值 
存儲過程的參數能夠設置默認值 

1. create or replace procedure procdefault(p1 varchar2,   
2.                                         p2 varchar2 default 'mark')   
3. as    
4. begin   
5.   dbms_output.put_line(p2);   
6. end;   
7.   
8. SQL> set serveroutput on;   
9. SQL> exec procdefault('a');  

mark 
能夠經過default 關鍵字爲存儲過程的參數指定默認值。在對存儲過程調用時，就能夠省略默認值。 
須要注意的是：默認值僅僅支持IN傳輸類型的參數。OUT 和 IN OUT不能指定默認值 

對於有默認值的參數不是排在最後的狀況。 

1. create or replace procedure procdefault2(p1 varchar2 default 'remark',   
2.                                         p2 varchar2 )   
3. as    
4. begin   
5.   dbms_output.put_line(p1);   
6. end;  

第一個參數有默認值，第二個參數沒有。若是咱們想使用第一個參數的默認值時 
exec procdefault2('aa'); 
這樣是會報錯的。 
那怎麼變呢？能夠指定參數的值。 

1. SQL> exec procdefault2(p2 =>'aa');  

remark 
這樣就OK了，指定aa傳給參數p2 


2. 存儲過程內部塊 
2.1 內部塊 
咱們知道了存儲過程的結構，語句塊由begin開始，以end結束。這些塊是能夠嵌套。在語句塊中能夠嵌套任何如下的塊。 

1. Declare … begin … exception … end;   
2. create or replace procedure innerBlock(p1 varchar2)   
3. as    
4.   o1 varchar2(10) := 'out1';   
5. begin   
6.   dbms_output.put_line(o1);   
7.   declare    
8.     inner1 varchar2(20);   
9.   begin   
10.     inner1 :='inner1';   
11.     dbms_output.put_line(inner1);   
12.   
13.     declare    
14.       inner2 varchar2(20);   
15.     begin   
16.       inner2 := 'inner2';   
17.       dbms_output.put_line(inner2);   
18.     end;   
19.   exception    
20.     when others then   
21.       null;   
22.   end;   
23. end;  

須要注意變量的做用域。 

3.存儲過程的經常使用技巧 
3.1 哪一種集合? 
咱們在使用存儲過程的時候常常須要處理記錄集，也就是多條數據記錄。分爲單列多行和多列多行，這些類型均可以稱爲集合類型。咱們在這裏進行比較這些集合類型，以便於在編程時作出正確的選擇。 
索引表,也稱爲pl/sql表，不能存儲於數據庫中，元素的個數沒有限制,下標能夠爲負值。 

1. type t_table is table of varchar2(20) index by binary_integer;   
2.  v_student t_table;  

varchar2(20)表示存放元素的數據類型，binary_integer表示元素下標的數據類型。 
嵌套表，索引表沒有 index by子句就是嵌套表，它能夠存放於數據中，元素個數無限，下標從1開始，而且須要初始化 

1. type t_nestTable is table of varchar2(20);   
2. v_class t_nestTable ;  

僅是這樣聲明是不能使用的，必須對嵌套表進行初始化，對嵌套表進行初始化可使用它的構造函數 

1. v_class :=t_nestTable('a','b','c');  

變長數組，變長數組與高級語言的數組類型很是類似，下標以1開始，元素個數有限。 

1. type t_array is varray (20) of varchar2(20);  

varray(20)就定義了變長數組的最大元素個數是20個 
變長數組與嵌套表同樣，也能夠是數據表列的數據類型。 
同時，變長數組的使用也須要事先初始化。 

類型 可存儲於數據庫 元素個數 是否需初始化 初始下標值 
索引表 否 無限 不需 
嵌套表 可 無限 需 1 
可變數組 可 有限(自定義) 需 1 

因而可知，若是僅僅是在存儲過程當中看成集合變量使用，索引表是最好的選擇。 

3.2 選用何種遊標? 
顯示遊標分爲：普通遊標，參數化遊標和遊標變量三種。 
下面以一個過程來進行說明 

1. create or replace procedure proccursor(p varchar2)   
2. as    
3. v_rownum number(10) := 1;   
4. cursor c_postype is select pos_type from pos_type_tbl where rownum =1;   
5. cursor c_postype1 is select pos_type from pos_type_tbl where rownum = v_rownum;   
6. cursor c_postype2(p_rownum number) is select pos_type from pos_type_tbl where rownum = p_rownum;   
7. type t_postype is ref cursor ;   
8. c_postype3 t_postype;   
9. v_postype varchar2(20);   
10. begin   
11.   open c_postype;   
12.   fetch c_postype into v_postype;   
13.   dbms_output.put_line(v_postype);   
14.   close c_postype;   
15.   open c_postype1;   
16.   fetch c_postype1 into v_postype;   
17.   dbms_output.put_line(v_postype);   
18.   close c_postype1;   
19.   open c_postype2(1);   
20.   fetch c_postype2 into v_postype;   
21.   dbms_output.put_line(v_postype);   
22.   close c_postype2;   
23.   open c_postype3 for select pos_type from pos_type_tbl where rownum =1;   
24.   fetch c_postype3 into v_postype;   
25.   dbms_output.put_line(v_postype);   
26.   close c_postype3;   
27. end;  

cursor c_postype is select pos_type from pos_type_tbl where rownum =1 
這一句是定義了一個最普通的遊標，把整個查詢已經寫死,調用時不能夠做任何改變。 
cursor c_postype1 is select pos_type from pos_type_tbl where rownum = v_rownum; 
這一句並無寫死，查詢參數由變量v_rownum來決定。須要注意的是v_rownum必須在這個遊標定義以前聲明。 
cursor c_postype2(p_rownum number) is select pos_type from pos_type_tbl where rownum = p_rownum; 
這一條語句與第二條做用類似，都是能夠爲遊標實現動態的查詢。可是它進一步的縮小了參數的做用域範圍。可是可讀性下降了很多。 
type t_postype is ref cursor ; 
c_postype3 t_postype; 
先定義了一個引用遊標類型，而後再聲明瞭一個遊標變量。 
open c_postype3 for select pos_type from pos_type_tbl where rownum =1; 
而後再用open for 來打開一個查詢。須要注意的是它能夠屢次使用,用來打開不一樣的查詢。 
從動態性來講，遊標變量是最好用的，可是閱讀性也是最差的。 
注意，遊標的定義只能用使關鍵字IS，它與AS不通用。 

3.3 遊標循環最佳策略 
咱們在進行PL/SQL編程時，常常須要循環讀取結果集的數據。進行逐行處理，這個過程就須要對遊標進行循環。對遊標進行循環的方法有多種，咱們在此一一分析。 

1. create or replace procedure proccycle(p varchar2)   
2. as    
3. cursor c_postype is select pos_type, description from pos_type_tbl where rownum < 6;   
4. v_postype varchar2(20);   
5. v_description varchar2(50);   
6. begin   
7. open c_postype;   
8.   if c_postype%found then   
9.     dbms_output.put_line('found true');   
10.   elsif c_postype%found = false then   
11.     dbms_output.put_line('found false');   
12.   else  
13.     dbms_output.put_line('found null');   
14.   end if;   
15.   loop   
16.    fetch c_postype into v_postype,v_description ;   
17.    exit when c_postype%notfound;   
18.    dbms_output.put_line('postype:'||v_postype||',description:'||v_description);   
19.   end loop;   
20.   close c_postype;   
21. dbms_output.put_line('---loop end---');   
22.   open c_postype;   
23.     fetch c_postype into v_postype,v_description;   
24.     while c_postype%found loop   
25.       dbms_output.put_line('postype:'||v_postype||',description:'||v_description);   
26.       fetch c_postype into v_postype,v_description ;   
27.     end loop;   
28.   
29.   close c_postype;   
30. dbms_output.put_line('---while end---');   
31.   for v_pos in c_postype loop   
32.     v_postype := v_pos.pos_type;   
33.     v_description := v_pos.description;   
34.     dbms_output.put_line('postype:'||v_postype||',description:'||v_description);   
35.   end loop;   
36.   dbms_output.put_line('---for end---');   
37. end;  

使用遊標以前須要開打遊標,open cursor，循環完後再關閉遊標close cursor. 
這是使用遊標應該慎記於心的法則。 
上面的過程演示了遊標循環的三種方法。 
在討論循環方法以前，咱們先看看%found和%notfound這些遊標的屬性。 

1. open c_postype;   
2.  if c_postype%found then   
3.    dbms_output.put_line('found true');   
4.  elsif c_postype%found = false then   
5.    dbms_output.put_line('found false');   
6.  else  
7.    dbms_output.put_line('found null');   
8.  end if;  

在打開一個遊標以後，立刻檢查它的%found或%notfound屬性，它獲得的結果即不是true也不是false.而是null.必須執行一條fetch語句後，這些屬性纔有值。 

第一種使用loop 循環 

1. loop   
2.    fetch c_postype into v_postype,v_description ;   
3.    exit when c_postype%notfound;   
4.    ……   
5. end loop  

這裏須要注意，exit when語句必定要緊跟在fetch以後。必避免多餘的數據處理。 
處理邏輯須要跟在exit when以後。這一點須要多加當心。 
循環結束後要記得關閉遊標。 

第二種使用while循環。 

1.    fetch c_postype into v_postype,v_description;   
2. while c_postype%found loop   
3.    ……   
4.       fetch c_postype into v_postype,v_description ;   
5. end loop;  

咱們知道了一個遊標打開後，必須執行一次fetch語句，遊標的屬性纔會起做用。因此使用while 循環時，就須要在循環以前進行一次fetch動做。 
並且數據處理動做必須放在循環體內的fetch方法以前。循環體內的fetch方法要放在最後。不然就會多處理一次。這一點也要很是的當心。 
總之，使用while來循環處理遊標是最複雜的方法。 

第三種 for循環 

1. for v_pos in c_postype loop   
2.    v_postype := v_pos.pos_type;   
3.    v_description := v_pos.description;   
4.    …   
5.  end loop;  

可見for循環是比較簡單實用的方法。 
首先，它會自動open和close遊標。解決了你忘記打開或關閉遊標的煩惱。 
其它,自動定義了一個記錄類型及聲明該類型的變量，並自動fetch數據到這個變量中。 
咱們須要注意v_pos 這個變量無須要在循環外進行聲明，無須要爲其指定數據類型。 
它應該是一個記錄類型，具體的結構是由遊標決定的。 
這個變量的做用域僅僅是在循環體內。 
把v_pos看做一個記錄變量就能夠了，若是要得到某一個值就像調用記錄同樣就能夠了。 
如v_pos.pos_type 
因而可知，for循環是用來循環遊標的最好方法。高效，簡潔，安全。 
但遺憾的是，經常見到的倒是第一種方法。因此從今以後得改變這個習慣了。 

3.4 select into不可乎視的問題 
咱們知道在pl/sql中要想從數據表中向變量賦值，須要使用select into 子句。 
可是它會帶動來一些問題，若是查詢沒有記錄時，會拋出no_data_found異常。 
若是有多條記錄時，會拋出too_many_rows異常。 
這個是比較糟糕的。一旦拋出了異常，就會讓過程當中斷。特別是no_data_found這種異常，沒有嚴重到要讓程序中斷的地步，能夠徹底交給由程序進行處理。 

1. create or replace procedure procexception(p varchar2)   
2. as    
3.   v_postype varchar2(20);   
4. begin   
5.    select pos_type into v_postype from pos_type_tbl where 1=0;   
6.     dbms_output.put_line(v_postype);   
7. end;   
8.       

執行這個過程 

1. SQL> exec procexception('a');   
2. 報錯   
3. ORA-01403: no data found   
4. ORA-06512: at "LIFEMAN.PROCEXCEPTION", line 6  
5. ORA-06512: at line 1  

處理這個有三個辦法 
1． 直接加上異常處理。 

1. create or replace procedure procexception(p varchar2)   
2. as    
3.   v_postype varchar2(20);   
4.      
5. begin   
6.    select pos_type into v_postype from pos_type_tbl where 1=0;   
7.     dbms_output.put_line(v_postype);   
8. exception    
9.   when no_data_found then   
10.     dbms_output.put_line('沒找到數據');   
11. end;  

這樣作換湯不換藥，程序仍然被中斷。可能這樣不是咱們所想要的。 
2. select into作爲一個獨立的塊，在這個塊中進行異常處理 

1. create or replace procedure procexception(p varchar2)   
2. as    
3.   v_postype varchar2(20);   
4.      
5. begin   
6.   begin   
7.    select pos_type into v_postype from pos_type_tbl where 1=0;   
8.     dbms_output.put_line(v_postype);   
9.  exception    
10.   when no_data_found then   
11.     v_postype := '';   
12.   end;   
13.   dbms_output.put_line(v_postype);   
14. end;  

這是一種比較好的處理方式了。不會由於這個異常而引發程序中斷。 
3.使用遊標 

1. create or replace procedure procexception(p varchar2)   
2. as    
3.   v_postype varchar2(20);   
4.   cursor c_postype is select pos_type  from pos_type_tbl where 1=0;   
5. begin   
6.   open c_postype;   
7.     fetch c_postype into v_postype;   
8.   close c_postype;   
9.   dbms_output.put_line(v_postype);   
10. end;  

這樣就徹底的避免了no_data_found異常。徹底交由程序員來進行控制了。 

第二種狀況是too_many_rows 異常的問題。 
Too_many_rows 這個問題比起no_data_found要複雜一些。 
給一個變量賦值時，可是查詢結果有多個記錄。 
處理這種問題也有兩種狀況： 
1． 多條數據是能夠接受的，也就是說從結果集中隨便取一個值就行。這種狀況應該很極端了吧，若是出現這種狀況，也說明了程序的嚴謹性存在問題。 
2． 多條數據是不能夠被接受的，在這種狀況確定是程序的邏輯出了問題，也說是說原來根本就不會想到它會產生多條記錄。 
對於第一種狀況，就必須採用遊標來處理，而對於第二種狀況就必須使用內部塊來處理，從新拋出異常。 
多條數據能夠接受,隨便取一條，這個跟no_data_found的處理方式同樣，使用遊標。 
我這裏僅說第二種狀況，不可接受多條數據，可是不要忘了處理no_data_found哦。這就不能使用遊標了，必須使用內部塊。 

1. create or replace procedure procexception2(p varchar2)   
2. as    
3.   v_postype varchar2(20);   
4.     
5. begin   
6.   begin   
7.     select pos_type into v_postype from pos_type_tbl where rownum < 5;   
8.   exception   
9.     when no_data_found then   
10.       v_postype :=null;   
11.     when too_many_rows then   
12.       raise_application_error(-20000,'對v_postype賦值時，找到多條數據');   
13.   end;   
14.  dbms_output.put_line(v_postype);   
15. end;  

須要注意的是必定要加上對no_data_found的處理，對出現多條記錄的狀況則繼續拋出異常，讓上一層來處理。 
總之對於select into的語句須要注意這兩種狀況了。須要穩當處理啊。 

3.5 在存儲過程當中返回結果集 
咱們使用存儲過程都是返回值都是單一的，有時咱們須要從過程當中返回一個集合。即多條數據。這有幾種解決方案。比較簡單的作法是寫臨時表，可是這種作法不靈活。並且維護麻煩。咱們可使用嵌套表來實現.沒有一個集合類型可以與java的jdbc類型匹配。這就是對象與關係數據庫的阻抗吧。數據庫的對象並不可以徹底轉換爲編程語言的對象，還必須使用關係數據庫的處理方式。 

1. create or replace package procpkg is   
2.    type refcursor is ref cursor;   
3.    procedure procrefcursor(p varchar2, p_ref_postypeList  out refcursor);   
4. end procpkg;   
5.   
6. create or replace package body procpkg is   
7.   procedure procrefcursor(p varchar2, p_ref_postypeList out  refcursor)   
8.   is   
9.     v_posTypeList PosTypeTable;   
10.   begin   
11.     v_posTypeList :=PosTypeTable();--初始化嵌套表   
12.     v_posTypeList.extend;   
13.     v_posTypeList(1) := PosType('A001','客戶資料變動');   
14.     v_posTypeList.extend;   
15.     v_posTypeList(2) := PosType('A002','團體資料變動');   
16.     v_posTypeList.extend;   
17.     v_posTypeList(3) := PosType('A003','受益人變動');   
18.     v_posTypeList.extend;   
19.     v_posTypeList(4) := PosType('A004','續期交費方式變動');   
20.     open p_ref_postypeList for  select * from table(cast (v_posTypeList as PosTypeTable));   
21.   end;   
22. end procpkg;  

在包頭中定義了一個遊標變量,並把它做爲存儲過程的參數類型。 
在存儲過程當中定義了一個嵌套表變量，對數據寫進嵌套表中，而後把嵌套表進行類型轉換爲table,遊標變量從這個嵌套表中進行查詢。外部程序調用這個遊標。 
因此這個過程須要定義兩個類型。 

1. create or replace type PosType as Object (   
2.   posType varchar2(20),   
3.   description varchar2(50)   
4. );  

create or replace type PosTypeTable is table of PosType; 
須要注意，這兩個類型不能定義在包頭中，必須單獨定義，這樣java層才能使用。 

在外部經過pl/sql來調用這個過程很是簡單。 

1. set serveroutput on;   
2. declare    
3.   type refcursor is ref cursor;   
4.   v_ref_postype refcursor;   
5.   v_postype varchar2(20);   
6.   v_desc varchar2(50);   
7. begin   
8.   procpkg.procrefcursor('a',v_ref_postype);   
9.   loop   
10.     fetch  v_ref_postype into v_postype,v_desc;   
11.     exit when v_ref_postype%notfound;   
12.     dbms_output.put_line('posType:'|| v_postype || ';description:' || v_desc);   
13.   end loop;   
14. end;  

注意：對於遊標變量，不能使用for循環來處理。由於for循環會隱式的執行open動做。而經過open for來打開的遊標%isopen是爲true的。也就是默認打開的。Open一個已經open的遊標是錯誤的。因此不能使用for循環來處理遊標變量。 

咱們主要討論的是如何經過jdbc調用來處理這個輸出參數。 

1. conn = this.getDataSource().getConnection();   
2. CallableStatement call = conn.prepareCall("{call procpkg.procrefcursor(?,?)}");   
3. call.setString(1, null);   
4. call.registerOutParameter(2, OracleTypes.CURSOR);   
5. call.execute();   
6. ResultSet rsResult = (ResultSet) call.getObject(2);   
7. while (rsResult.next()) {   
8.   String posType = rsResult.getString("posType");   
9.   String description = rsResult.getString("description");   
10.   ......   
11. }  

這就是jdbc的處理方法。 

Ibatis處理方法： 
1.參數配置 

1. <parameterMap id="PosTypeMAP" class="java.util.Map">    
2.  <parameter property="p" jdbcType="VARCHAR" javaType="java.lang.String" />    
3.  <parameter property="p_ref_postypeList" jdbcType="ORACLECURSOR" javaType="java.sql.ResultSet" mode="OUT" typeHandler="com.palic.elis.pos.dayprocset.integration.dao.impl.CursorHandlerCallBack" />    
4. </parameterMap>   
5.   
6. 2.調用過程   
7.   <procedure id ="procrefcursor" parameterMap ="PosTypeMAP">   
8.       {call procpkg.procrefcursor(?,?)}   
9.   </procedure>   
10.   
11. 3.定義本身的處理器   
12.   public class CursorHandlerCallBack implements TypeHandler{   
13.     public Object getResult(CallableStatement cs, int index) throws SQLException {   
14.         ResultSet rs = (ResultSet)cs.getObject(index);   
15.         List result = new ArrayList();   
16.         while(rs.next()) {   
17.             String postype =rs.getString(1);   
18.             String description = rs.getString(2);   
19.             CodeTableItemDTO posTypeItem = new CodeTableItemDTO();   
20.             posTypeItem.setCode(postype);   
21.             posTypeItem.setDescription(description);   
22.             result.add(posTypeItem);   
23.         }   
24.         return result;   
25.     }   
26.   
27.   
28.   
29. 4. dao方法   
30.     public List procPostype() {   
31.         String p = "";   
32.         Map para = new HashMap();   
33.         para.put("p",p);   
34.         para.put("p_ref_postypeList",null);   
35.          this.getSqlMapClientTemplate().queryForList("pos_dayprocset.procrefcursor",  para);   
36.          return (List)para.get("p_ref_postypeList");   
37.     }  

這個跟jdbc的方式很是的類似. 
咱們使用的是ibatis的2.0版本，比較麻煩。 
若是是使用2.2以上版本就很是簡單的。 
由於能夠在parameterMap中定義一個resultMap.這樣就無須要本身定義處理器了。 
能夠從分析2.0和2.0的dtd文件知道。 

上面的兩種方式都是很是的複雜，若是僅僅是須要返回一個結果集，那就徹底可使用函數來實現了。 

1. create or replace package procpkg is   
2.    type refcursor is ref cursor;   
3.    procedure procrefcursor(p varchar2, p_ref_postypeList  out refcursor);   
4.    function procpostype(p varchar2) return PosTypeTable;    
5. end procpkg;   
6.   
7. create or replace package body procpkg is   
8.   procedure procrefcursor(p varchar2, p_ref_postypeList out  refcursor)   
9.   is   
10.     v_posTypeList PosTypeTable;   
11.   begin   
12.     v_posTypeList :=PosTypeTable();--初始化嵌套表   
13.     v_posTypeList.extend;   
14.     v_posTypeList(1) := PosType('A001','客戶資料變動');   
15.     v_posTypeList.extend;   
16.     v_posTypeList(2) := PosType('A002','團體資料變動');   
17.     v_posTypeList.extend;   
18.     v_posTypeList(3) := PosType('A003','受益人變動');   
19.     v_posTypeList.extend;   
20.     v_posTypeList(4) := PosType('A004','續期交費方式變動');   
21.     open p_ref_postypeList for  select * from table(cast (v_posTypeList as PosTypeTable));   
22.   end;   
23.   
24.   function procpostype(p varchar2) return PosTypeTable   
25.   as   
26.    v_posTypeList PosTypeTable;   
27.   begin   
28.       v_posTypeList :=PosTypeTable();--初始化嵌套表   
29.     v_posTypeList.extend;   
30.     v_posTypeList(1) := PosType('A001','客戶資料變動');   
31.     v_posTypeList.extend;   
32.     v_posTypeList(2) := PosType('A002','團體資料變動');   
33.     v_posTypeList.extend;   
34.     v_posTypeList(3) := PosType('A003','受益人變動');   
35.     v_posTypeList.extend;   
36.     v_posTypeList(4) := PosType('A004','續期交費方式變動');   
37.     return  v_posTypeList;   
38.   end;   
39. end procpkg;  

ibatis配置 

1. <resultMap id="posTypeResultMap" class="com.palic.elis.pos.common.dto.CodeTableItemDTO">   
2.    <result property="code" column="posType"/>   
3.    <result property="description" column="description"/>   
4.  </resultMap>   
5.   
6.   <select id="procPostype" resultMap="posTypeResultMap">   
7.     select * from table(cast (procpkg.procpostype(#value#) as PosTypeTable))   
8.   </select>  

Dao的寫法跟普通查詢同樣 

1. public List queryPostype() {   
2.   return this.getSqlMapClientTemplate().queryForList("pos_dayprocset.procPostype", null);   
3. }  

有幾點須要注意，這裏不能使用索引表，而是嵌套表。 
另外就是把嵌套表強制轉換爲普通表。