批處理根據MAC修改計算機名等系統信息，XP/win7/win8下測試經過

       

 

這個批處理，是我在實際環境中用了幾年，不斷修改、完善測試，分享給你們。

 

1.在XP/win7/win8環境下測試經過。

1.隨着這幾年win7的普及，win8也開始應用，再加上微軟中止對XP系統的升級，企業中XP/Win7/win8混合使用的狀況比較很常見，舊電腦跑不動win7的就裝XP繼續用，配置還OK的，就裝win7,一些其它人士如IT人員，或者領導新買的筆記本等或者想嚐鮮的人士，裝win8的狀況比較常見，這些均可以是批處理的用武之地。

2.這個批處理須要以管理員權限運行，XP、win7一般都是管理員帳號，雙擊就好了，win8有點不一樣，win8運行這個批處理要右鍵選擇管理員權限運行，不然會報錯。

3.實際當中運行這個批處理，若是電腦上安裝有殺毒軟件或者安全衛士類軟件，一般會對批處理進行攔截，請容許運行或者暫停安全軟件保護。有的安全軟件，批處理運行起來會給個提示，很差的直接給你禁止運行，或者提示你是風險軟件提示刪除，對於某數字殺毒軟件，我一直恨之入骨，尼瑪跟個女人同樣囉嗦，只要是用批處理改點什麼系統信息，總會默認就攔截甚至是直接給你關了，一般我是見一個卸載一個，在實際工做中，面對用戶的疑問，不知道要費多少口水解釋，還得要人家把安全軟件退出。

2.支持多網卡環境。採用新的判別方法，能夠識別任意網卡名稱。

1.多網卡環境常見的狀況是電腦安裝了虛擬機的環境下。

2.在之前，我採用的判別方法是 本地鏈接，通常狀況可以適用，通常聯網的網卡一般都叫本地鏈接，但特殊狀況下，就不行了，如操做系統是win8.1，這個不叫本地鏈接，叫Ethernet0，win8.1系統的筆記本叫 以太網,英文版的XP/win7叫作 Local Area Connection，或者手動能夠修改本地鏈接，隨意字符只要系統支持，之前採購本地鏈接這個詞做判別，趕上這種狀況就歇菜了，更新判別方法後，就不受鏈接名稱限制。

3.具有簡單的錯誤信息判別和提示，在沒有收集到MAC的機器上會智能退出。

雖然只是加了一個簡單的判斷，可是我確實是走了很多彎路。

1.批處理中不存在預設的MAC項，常見的狀況就是在公司，批處理集成到一個ghost系統鏡像，一個鏡像打弄下，來一臺裝一臺，來兩臺裝兩臺，多點的能夠搞個網絡克隆，機器有多是現有的機器重裝系統MAC，統計在內，這還好，批處理正好發揮他的做用，要是是新買的或者員工私人的，或者是沒統計到MAC的，裝完系統進桌面要作的第一件事，就是趕忙的把批處理關了，當個技術人員或者網管，人家找你裝系統，是常有的事。公司的，私人的，一般都一個鏡像ghost過去。

2.本身在測試批處理的時候，遇到不少狀況，沒法成功運行，之前一運行下來，黑屏一閃，過了，成功沒有都不知道，還得一個步驟一個步驟去檢查，有了這些提示判別信息，本身看着也舒服點。

3.在網絡克隆批量裝系統的狀況下，若是你不能絕對保證你每臺機器信息修改都OK的話，有的時候，你信心滿滿的認爲沒問題，結果就恰恰出了問題，最靠譜的方法固然是對結果一一檢查。裝一臺機器還好，我之前遇到過給一個機房70多臺電腦網絡克隆的狀況，結果有部分機器就出了問題，一臺電腦檢查下要30秒，你也要半小時，還真是痛苦，若是屏幕有個提示，至少人就不用點了。

4.在企業環境，發給員工運行時，運行有沒有問題，他也能夠看出來，有沒有出錯，至少還能夠戴個圖給你，你也大體明白，問題出在哪一個步驟。

 

批處理、用戶模板、使用說明下載地址

http://pan.baidu.com/s/1pJwl9Ib

使用方法

1.按照本身實際狀況修改excel 用戶信息模板，全部的項都要填寫完整。
2.右鍵編輯 根據MAC修改計算機名v2.5.bat 把用戶信息直接從excel用戶信息模板表中複製到批處理後面，保存批處理再運行。

3.本批處理會自動提取批處理後面預設的值，根據MAC修改計算機名爲   拼音-設備類別  修改當前登陸用戶名爲 工號  修改計算機註釋爲。 子部門-姓名

下面爲批處理後面預設的值，批處理會根據當前機器的MAC自動提取相應的信息。

::部門-i   子部門-j      姓名-k    工號-l   拼音-m   設備類別-n   IP地址-o    標準MAC-p   標準MAC2-q
技術部      運維分部  小黑俠 SN000427  XiaoHeiXia    DT    192.168.102.129    00-0C-29-9A-5C-C3  000C298919F0

4.win8.1系統請右鍵選擇以管理員身份運行，不然會報錯。
5.若有什麼須要改善的意見或者建議，或者使用遇到什麼問題，歡迎加QQ羣:342116629交流。

 

 附：批處理源代碼

 

@echo off
title 根據MAC地址修改計算機名批處理,支持XP/Win7/Win8.1操做系統，Edit by foreverlx427
echo **************************************************************************** 
echo     舒適提示1：請根據本身的實際狀況，按指定格式編輯本批處理後面的用戶信息。 
echo     舒適提示2：若有安全類軟件攔截，請容許運行。
echo     舒適提示3: win8.1系統請右鍵選擇以管理員身份運行，不然會報錯。
echo ****************************************************************************  
@ping 127.1 -n  4  >nul
::*************** 1.獲取本機MAC地址，並在外置文本信息中找匹配項 ***************
cd /d %~dp0
for /f "tokens=1-4 delims=," %%i in ('getmac /v /fo csv') do find /i %%k %0 >nul &&set Ethernet=%%i&&set Adapter=%%j&&set MAC=%%k &&goto true 
echo 未找到匹配MAC項，本程序在5秒後退出&del a.txt   >nul&@ping 127.0.0.1 -n  5 >nul &exit
:true
::*************** 2.去掉MAC地址的空格和引號 ***************
set "MAC=%MAC: =%"
set MAC=%MAC:"=%
set Ethernet=%Ethernet:"=%
set Adapter=%Adapter:"=%
::  3MAC -%MAC%- Ethernet -%Ethernet%- Adapter -%Adapter%-
:: *************** 3.信息彙總 ***************
for /f "tokens=1-8" %%i in ('find /i "%mac%" %0') do set "name=%%m-%%n"&set "p=%%j%%k"&set "user=%%l" 
echo ****************************************************************************
echo  本機預設信息，5秒後自動應用修改，若有錯誤，請關閉本窗口手動修改    
echo ****************************************************************************                              
echo          計算機名：       %name% (當前名稱：%computername%)
echo          計算機註釋：     %p%
echo          用戶名：         %user% (當前名稱：%username%)
echo          網絡名稱         %Ethernet%
echo          適配器名稱       %Adapter%
echo          本機MAC地址      %mac%
echo ****************************************************************************
:: *************** 4.修改配置 ***************
@ping 127.1 -n  5  >nul
echo 1.正在修改計算機註釋……
reg add "HKEY_LOCAL_MACHINE\SYSTEM\ControlSet001\services\LanmanServer\Parameters" /v "srvcomment" /t reg_sz /d %p% /f >nul &&echo 修改計算機註釋1/2成功|| echo 修改計算機註釋1/2失敗 
reg add "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\services\LanmanServer\Parameters" /v "srvcomment" /t reg_sz /d %p% /f >nul  &&echo 修改計算機註釋2/2 成功|| echo 修改計算機註釋2/2失敗 
echo 2.正在修改計算機名……
reg add "HKEY_LOCAL_MACHINE\SYSTEM\ControlSet001\Control\ComputerName\ComputerName" /v "ComputerName" /t reg_sz /d %name% /f >nul  &&echo 修改計算機名1/4 成功|| echo 修改計算機名1/4 失敗 
reg add "HKEY_LOCAL_MACHINE\SYSTEM\ControlSet001\services\Tcpip\Parameters" /v "NV Hostname" /t reg_sz /d %name% /f  >nul  &&echo 修改計算機名2/4 成功|| echo 修改計算機名2/4  失敗 
reg add "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\ComputerName\ComputerName" /v "ComputerName" /t reg_sz /d %name% /f    >nul  &&echo 修改計算機名3/4  成功|| echo 修改計算機名3/4 失敗 
reg add "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\services\Tcpip\Parameters" /v "NV Hostname" /t reg_sz /d %name% /f >nul  &&echo 修改計算機名4/4  成功|| echo 警告：修改計算機名4/4 失敗 &&echo 修改系統信息失敗，請檢查當前用戶權限是否爲管理員，若不是，請嘗試以管理員身份運行;或者是否有安全程序阻止本批處理運行，若是是win8系統，記得在右鍵選擇以管理員身份運行，請按任意鍵退出  &&pause>nul&&exit
echo 3.正在修改當前用戶名%username%爲預設用戶名%user%……
wmic useraccount where name='%username%' call Rename %user%  >nul &&echo 修改用戶名1/1 成功|| echo 修改用戶名1/1 失敗 
echo 4.正在修改當前用戶名%user%的全名爲%p%……
wmic useraccount where name='%user%' set FullName="%p%"   >nul &&echo 修改用戶名全名1/1 成功|| echo 修改用戶名全名1/1 失敗 
echo 全部操做已經完成,10秒後自動退出，感謝你的使用，若有問題，請反饋至QQ羣:342116629
@ping 127.1 -n  10 >nul&exit
::部門-i 子部門-j 姓名-k 工號-l 拼音-m 設備類別-n IP地址-o 標準MAC-p         標準MAC2-q
技術部 運維分部 小黑俠 SN000427 XiaoHeiXia DT 192.168.102.129 00-0C-29-9A-5C-C3 000C298919F0
技術部 運維分部 張三 SN000428 ZhangSan DT 192.168.102.130 00-0C-29-5B-E7-99 000C295BE799
技術部 運維分部 李四 SN000429 LiSi         DT 192.168.102.131 00-0C-29-97-F0-4A 000C2997F04A