Windows下MySQL自動備份的batch腳本

   在Unix系統環境中能夠經過各類Unix shell結合cron任務實現對MySQL的自動備份，那在Windows下要如何實現呢，其實很簡單隻要寫好自定義的batch腳本在結合taskschd.msc（任務計劃程序），就能夠實現，最近須要修改調優Windows環境下的MySQL就順便寫了一個使用mysqldump作邏輯備份的batch腳本，以下：

@echo off
::mysql_backup.bat
set hour=%time:~0,2%
if "%time:~0,1%"==" " set hour=0%time:~1,1%
set now=%Date:~0,4%%Date:~5,2%%Date:~8,2%%hour%%Time:~3,2%%Time:~6,2%
::主機ip
set host=127.0.0.1
::端口
set port=3306
::用戶
set username=root
::密碼
set password=youpassword
::要備份數據庫的名字，若是有多個庫請用空格分隔
set databasename=database1 database2
:: MySQL Bin 目錄
:: 若是在安裝配置時添加 MySQL Bin 目錄到了環境變量(PATH) ，此處能夠留空
set MYSQL=D:\mysql-5.5.57-winx64\bin\
::配置SQL備份路徑
set DIR=D:\backup\db\
:: 建立備份MySQL的備份目錄
if not exist %DIR% (
    mkdir %DIR% 2>nul
)

if not exist %DIR% (
    echo Backup path: %DIR% not exists, create dir failed.
    goto exit
)

echo start mysqldump ...

for %%i in (%databasename%) do (
    %MYSQL%mysqldump -h%host% -P%port% -u%username% -p%password% %%i > %DIR%%%i-%now%.sql 2>nul
)

echo end mysqldump
::記錄主庫狀態，且作日誌記錄
%MYSQL%mysql -h%host% -P%port% -u%username% -p%password% -Bse "select now();show master status\G" > %DIR%MySQL_status-%now%.log
echo delete files before 60 days
::刪除60天前的備份
forfiles /p "D:\backup\db" /m *.* /d -60 /c "cmd /c del @file /f"

:exit

在寫好batch腳本後最後再在taskschd.msc中添加天天定時觸發執行，具體的配置方法以下：

這裏須要注意的是，這裏必定要勾選上使用最高權限運行，以避免形成運行失敗

這裏觸發條件選擇天天一次，具體時間能夠視實際生產環境判斷，開始任務則爲按預約計劃

在這裏填上batch腳本的路徑以及初始目錄，其中須要注意的是必定須要配置初始目錄，否則沒有把batch腳本添加入PATH環境變量中該任務會找不到batch腳本從而執行失敗

條件這裏能夠根據實際狀況選擇

這裏必定須要勾選 容許按需運行任務，其餘的時間就實際狀況而定，最後在確認保存後輸入用戶密碼這樣天天系統就會自動作mysqldump邏輯備份。