用VBS將PPT轉爲圖片

'使用方法：把ppt文件拖放到該文件上。   
'機器上要安裝Powerpoint程序   
On Error Resume Next  
Set ArgObj = WScript.Arguments   
pptfilepath = ArgObj(0)   
imgType = InputBox("輸入導出文件的格式，能夠是jpg,png,bmp,gif","輸入導出文件的格式","png")   
If imgType = "" Or (LCase(imgType)<>"jpg" And LCase(imgType)<>"png" And LCase(imgType)<>"bmp" And LCase(imgType)<>"gif") Then  
    imgType = "png"  
    MsgBox "輸入不正確，以png格式輸出"  
End If  
imgW = InputBox("輸入導出圖像的寬度","輸入導出圖像的寬度","640")    
If imgW = "" Or IsNumeric(imgW)=False Then  
    imgW = 640   
    MsgBox "輸入不正確,程序使用默認值:640"  
End If  
imgH = InputBox("輸入導出圖像的高度","輸入導出圖像的高度","480")    
If imgH = "" Or IsNumeric(imgH)=False Then  
    imgH = imgW*0.75   
    MsgBox "輸入不正確,程序使用默認值:"&imgH   
End If 

Call Form_Load(pptfilepath,imgType)   
Private Sub Form_Load(Filepath,format)   
    If format = "" Then  
        format = "gif"  
    End If  
    Folderpath = Left(Filepath,Len(Filepath)-4)   
    If LCase(Right(Filepath,4))<>".ppt" Then  
        Call ConvertPPT(Filepath,Folderpath&".ppt")   
    End If  
    Filepath = Folderpath&".ppt"  
    CreateFolder(Folderpath)   
    Set ppApp = CreateObject("PowerPoint.Application")   
    Set ppPresentations = ppApp.Presentations   
    Set ppPres = ppPresentations.Open(Filepath, -1, 0, 0)   
    Set ppSlides = ppPres.Slides   
  
    For i = 1 To ppSlides.Count   
  
        iname = "000000"&i   
        iname = Right(iname,4)'取四位數   
        Call ppSlides.Item(i).Export(Folderpath&"\"&iname&"."&format, format, imgW, imgH)   
    Next  
  
    Set ppApp = Nothing  
    Set ppPres = Nothing  
End Sub  
  
Function CreateFolder(Filepath)   
    Dim fso, f   
    On Error Resume Next  
    Set fso = CreateObject("Scripting.FileSystemObject")   
    If Not fso.FolderExists(Filepath) Then  
        Set f = fso.CreateFolder(Filepath)   
    End If  
    CreateFolder = f.Path   
    Set fso = Nothing  
    Set f = Nothing  
End Function  
  
Sub ConvertPPT(FileName1, FileName2)   
    Dim PPT   
    Dim Pres   
    Set PPT = CreateObject("PowerPoint.Application")   
    Set Pres = PPT.Presentations.Open(FileName1, False, False, False)   
    Pres.SaveAs FileName2, , True  
     Pres.Close   
    PPT.Quit   
     Set Pres = Nothing  
    Set PPT = Nothing  
End Sub