Intellij IDEA 經過數據庫生成 POJO

時間 2019-11-08

標籤 intellij idea 經過數據庫生成 pojo 欄目 Eclipse 简体版

原文原文鏈接

前言

最近寫需求時須要新建許多新表，設計完表結構還要一一寫成對應的 POJO，很麻煩，就 Google 了一下。網上相關資料很少，借鑑了一篇博客，並在其基礎上進行了完善。java

前置步驟

使用 IDEA 自帶的插件 Database 鏈接數據庫
在數據庫的表上右鍵 Scripted Extensions -> Go to Scripts Directory
在打開的目錄下放入腳本文件

源碼

腳本用的 Groovy 語言，語法相似 Java，並能調用 Java 類庫，本身修改也很方便。惟一的麻煩是執行入口在 Intellij 內部，想 debug 很麻煩。數據庫

PO 的路徑通常都是統一的，若是要在新的模塊中使用須要改一下路徑。另外類註釋須要替換成本身的。api

還有一點須要注意的是枚舉類型，腳本中將 tinyint 統一映射成了 Boolean 類型，若是要映射成自定義枚舉類型，須要在實體類中自行修改。app

用於生成帶 Lombok 註釋的實體類的腳本

Generate Lombok POJOs.groovy:ide

import com.intellij.database.model.DasTable
import com.intellij.database.util.Case
import com.intellij.database.util.DasUtil

import java.time.LocalDate

/* * Available context bindings: * SELECTION Iterable<DasObject> * PROJECT project * FILES files helper */

// 此處指定包路徑，路徑須要自行維護;
packageName = "com.xxx.xxx.entity;"
// 此處指定對應的類型映射，可按需修改，目前tinyint若是要映射到自定義枚舉類型，只能手動修改
typeMapping = [
        (~/(?i)bigint/)                   : "Long",
        (~/(?i)int/)                      : "Integer",
        (~/(?i)tinyint/)                  : "Boolean",
        (~/(?i)float|double|decimal|real/): "BigDecimal",
        (~/(?i)time|datetime|timestamp/)  : "LocalDateTime",
        (~/(?i)date/)                     : "LocalDate",
        (~/(?i)/)                         : "String"
]

// 上面用到類和它的導入路徑的之間的映射
importMap = [
        "BigDecimal" : "java.math.BigDecimal",
        "LocalDate" : "java.time.LocalDate",
        "LocalDateTime" : "java.time.LocalDateTime",
]

// 導入路徑列表，下面引用的時候會去重，也能夠直接聲明成一個 HashSet
importList = []

// 彈出選擇文件的對話框
FILES.chooseDirectoryAndSave("Choose directory", "Choose where to store generated files") { dir ->
    SELECTION.filter { it instanceof DasTable }.each { generate(it, dir) }
}

def generate(table, dir) {
    def className = javaName(table.getName(), true) + "PO"
    def fields = calcFields(table)
    new PrintWriter(new OutputStreamWriter(new FileOutputStream(new File(dir, className + ".java")), "utf-8")).withPrintWriter { out -> generate(out, className, fields, table) }
}

// 從這裏開始，拼實體類的具體邏輯代碼
def generate(out, className, fields, table) {
    out.println "package $packageName"
    out.println ""
    out.println ""
    // 引入所需的包
    out.println "import lombok.Data;"
    out.println "import javax.persistence.Id;"
    out.println "import javax.persistence.Table;"
    out.println "import javax.persistence.GeneratedValue;"
    // 去重後導入列表
    importList.unique().each() { pkg ->
        out.println "import " + pkg + ";"
    }
    out.println ""
    // 添加類註釋
    out.println "/**"
    // 若是添加了表註釋，會加到類註釋上
    if (isNotEmpty(table.getComment())) {
        out.println " * " + table.getComment()
    }
    out.println " *"
    out.println " * @author xxx"
    out.println " * @date " + LocalDate.now()
    out.println " */"
    // 添加類註解
    out.println "@Data"
    out.println "@Table(name = \"${table.getName()}\")"
    out.println "public class $className {"
    out.println ""
    boolean isId = true
    // 遍歷字段，按下面的規則生成
    fields.each() {
        // 輸出註釋
        if (isNotEmpty(it.comment)) {
            out.println "\t/**"
            out.println "\t * ${it.comment}"
            out.println "\t */"
        }
        // 這邊默認第一個字段爲主鍵，實際狀況大多數如此，遇到特殊狀況可能須要手動修改
        if (isId) {
            out.println "\t@Id"
            out.println "\t@GeneratedValue(generator = \"JDBC\")"
            isId = false
        }
        out.println "\tprivate ${it.type} ${it.name};"
        out.println ""
    }
    out.println ""
    out.println "}"
}

def calcFields(table) {
    DasUtil.getColumns(table).reduce([]) { fields, col ->
        def spec = Case.LOWER.apply(col.getDataType().getSpecification())
        def typeStr = typeMapping.find { p, t -> p.matcher(spec).find() }.value
        if (importMap.containsKey(typeStr)) {
            importList.add(importMap.get(typeStr))
        }
        fields += [[
                           name : javaName(col.getName(), false),
                           type : typeStr,
 comment: col.getComment()
        ]]
    }
}

def isNotEmpty(content) {
    return content != null && content.toString().trim().length() > 0
}

def javaName(str, capitalize) {
    def s = com.intellij.psi.codeStyle.NameUtil.splitNameIntoWords(str)
            .collect { Case.LOWER.apply(it).capitalize() }
            .join("")
            .replaceAll(/[^\p{javaJavaIdentifierPart}[_]]/, "_")
    capitalize || s.length() == 1 ? s : Case.LOWER.apply(s[0]) + s[1..-1]
}

複製代碼

用於生成帶 Lombok 註釋並繼承基類的實體類的腳本

Generate Lombok POJOs extend BaseEntity.groovy:idea

import com.intellij.database.model.DasTable
import com.intellij.database.util.Case
import com.intellij.database.util.DasUtil

import java.time.LocalDate

/* * Available context bindings: * SELECTION Iterable<DasObject> * PROJECT project * FILES files helper */

// 此處指定包路徑，路徑須要自行維護;
packageName = "com.xxx.xxx.entity;"
// 此處指定對應的類型映射，可按需修改，目前tinyint若是要映射到自定義枚舉類型，只能手動修改
typeMapping = [
        (~/(?i)bigint/)                   : "Long",
        (~/(?i)int/)                      : "Integer",
        (~/(?i)tinyint/)                  : "Boolean",
        (~/(?i)float|double|decimal|real/): "BigDecimal",
        (~/(?i)time|datetime|timestamp/)  : "LocalDateTime",
        (~/(?i)date/)                     : "LocalDate",
        (~/(?i)/)                         : "String"
]

// 上面用到類和它的導入路徑的之間的映射
importMap = [
        "BigDecimal" : "java.math.BigDecimal",
        "LocalDate" : "java.time.LocalDate",
        "LocalDateTime" : "java.time.LocalDateTime",
]

// 導入路徑列表，下面引用的時候會去重，也能夠直接聲明成一個 HashSet
importList = []

// 基類中已經有的屬性，就無需在新生成的類中聲明瞭
userTimeList = [
        "create_user_id",
        "update_user_id",
        "create_time",
        "update_time"
]

// 彈出選擇文件的對話框
FILES.chooseDirectoryAndSave("Choose directory", "Choose where to store generated files") { dir ->
    SELECTION.filter { it instanceof DasTable }.each { generate(it, dir) }
}

def generate(table, dir) {
    def className = javaName(table.getName(), true) + "PO"
    def writer = new PrintWriter(new OutputStreamWriter(new FileOutputStream(new File(dir, className + ".java")), "utf-8"))
    def fields = calcFields(table)
    writer.withPrintWriter { out -> generate(out, className, fields, table) }
}

// 從這裏開始，拼實體類的具體邏輯代碼
def generate(out, className, fields, table) {
    out.println "package $packageName"
    out.println ""
    out.println ""
    // 引入所需的包
    out.println "import com.xxx.xxx.entity.BaseEntity;"
    out.println "import lombok.Data;"
    out.println "import lombok.EqualsAndHashCode;"
    out.println "import java.io.Serializable;"
    out.println "import javax.persistence.Id;"
    out.println "import javax.persistence.Table;"
    out.println "import javax.persistence.GeneratedValue;"
    // 去重後導入列表
    importList.unique().each() { pkg ->
        out.println "import " + pkg + ";"
    }
    out.println ""
    // 添加類註釋
    out.println "/**"
    // 若是添加了表註釋，會加到類註釋上
    if (isNotEmpty(table.getComment())) {
        out.println " * " + table.getComment()
    }
    out.println " *"
    out.println " * @author xxx"
    out.println " * @date " + LocalDate.now()
    out.println " */"
    // 添加類註解
    out.println "@Data"
    out.println "@EqualsAndHashCode(callSuper = false)"
    out.println "@Table(name = \"${table.getName()}\")"
    out.println "public class $className extends BaseEntity implements Serializable {"
    out.println ""
    boolean isId = true
    // 遍歷字段，按下面的規則生成
    fields.each() {
        // 輸出註釋
        if (isNotEmpty(it.comment)) {
            out.println "\t/**"
            out.println "\t * ${it.comment}"
            out.println "\t */"
        }
        // 這邊默認第一個字段爲主鍵，實際狀況大多數如此，遇到特殊狀況可能須要手動修改
        if (isId) {
            out.println "\t@Id"
            out.println "\t@GeneratedValue(generator = \"JDBC\")"
            isId = false
        }
        out.println "\tprivate ${it.type} ${it.name};"
        out.println ""
    }
    out.println "}"
}

def calcFields(table) {
    DasUtil.getColumns(table).reduce([]) { fields, col ->
        def spec = Case.LOWER.apply(col.getDataType().getSpecification())
        def typeStr = typeMapping.find { p, t -> p.matcher(spec).find() }.value
        // 若是是BaseTimeUserIdPO中已有的字段，則再也不添加
        if (!userTimeList.contains(col.getName())) {
            // 若是是須要導入的類型，則往list裏面添加
            if (importMap.containsKey(typeStr)) {
                importList.add(importMap.get(typeStr))
            }
            fields += [[
                               name : javaName(col.getName(), false),
                               type : typeStr,
                               dbType : col.getDataType(),
 comment: col.getComment()
                       ]]
        } else {
            fields += []
        }
    }
}

def isNotEmpty(content) {
    return content != null && content.toString().trim().length() > 0
}

def javaName(str, capitalize) {
    def s = com.intellij.psi.codeStyle.NameUtil.splitNameIntoWords(str)
            .collect { Case.LOWER.apply(it).capitalize() }
            .join("")
            .replaceAll(/[^\p{javaJavaIdentifierPart}[_]]/, "_")
    capitalize || s.length() == 1 ? s : Case.LOWER.apply(s[0]) + s[1..-1]
}

複製代碼