SQL Server 觸發器

觸發器是一種特殊類型的存儲過程,它不一樣於以前的咱們介紹的存儲過程。觸發器主要是經過事件進行觸發被自動調用執行的。而存儲過程能夠經過存儲過程的名稱被調用。數據庫

Ø 什麼是觸發器服務器

    觸發器對錶進行插入、更新、刪除的時候會自動執行的特殊存儲過程。觸發器通常用在check約束更加複雜的約束上面。觸發器和普通的存儲過程的區別是:觸 發器是當對某一個表進行操做。諸如:update、insert、delete這些操做的時候,系統會自動調用執行該表上對應的觸發器。SQL Server 2005中觸發器能夠分爲兩類:DML觸發器和DDL觸發器,其中DDL觸發器它們會影響多種數據定義語言語句而激發,這些語句有create、 alter、drop語句。app

DML觸發器分爲:ide

    一、 after觸發器(以後觸發)測試

        a、 insert觸發器加密

        b、 update觸發器spa

        c、 delete觸發器rest

 

    二、 instead of 觸發器 (以前觸發)日誌

 

    其中after觸發器要求只有執行某一操做insert、update、delete以後觸發器才被觸發,且只能定義在表上。而instead of觸發器表示並不執行其定義的操做(insert、update、delete)而僅是執行觸發器自己。既能夠在表上定義instead of觸發器,也能夠在視圖上定義。code

觸發器有兩個特殊的表:插入表(instered表)和刪除表(deleted表)。這兩張是邏輯表也是虛表。有系統在內存中建立者兩張表,不會存儲在數 據庫中。並且兩張表的都是隻讀的,只能讀取數據而不能修改數據。這兩張表的結果老是與被改觸發器應用的表的結構相同。當觸發器完成工做後,這兩張表就會被 刪除。Inserted表的數據是插入或是修改後的數據,而deleted表的數據是更新前的或是刪除的數據。

 

 

對錶的操做

Inserted邏輯表

Deleted邏輯表

增長記錄(insert)

存放增長的記錄

刪除記錄(delete)

存放被刪除的記錄

修改記錄(update)

存放更新後的記錄

存放更新前的記錄

    Update數據的時候就是先刪除表記錄,而後增長一條記錄。這樣在inserted和deleted表就都有update後的數據記錄了。注意的是:觸 發器自己就是一個事務,因此在觸發器裏面能夠對修改數據進行一些特殊的檢查。若是不知足能夠利用事務回滾,撤銷操做。

Ø 建立觸發器

語法

create trigger tgr_name
on table_name
with encrypion –加密觸發器
for update...
as
Transact-SQL

    # 建立insert類型觸發器

--建立insert插入類型觸發器
if (object_id('tgr_classes_insert', 'tr') is not null)
drop trigger tgr_classes_insert
go
create trigger tgr_classes_insert
on classes
for insert --插入觸發
as
--定義變量
declare @id int, @name varchar(20), @temp int;
--在inserted表中查詢已經插入記錄信息
select @id = id, @name = name from inserted;
set @name = @name + convert(varchar, @id);
set @temp = @id / 2;
insert into student values(@name, 18 + @id, @temp, @id);
print '添加學生成功!';
go
--插入數據
insert into classes values('5班', getDate());
--查詢數據
select * from classes;
select * from student order by id;

     insert觸發器,會在inserted表中添加一條剛插入的記錄。

 

    # 建立delete類型觸發器

--delete刪除類型觸發器
if (object_id('tgr_classes_delete', 'TR') is not null)
drop trigger tgr_classes_delete
go
create trigger tgr_classes_delete
on classes
for delete --刪除觸發
as
print '備份數據中……';
if (object_id('classesBackup', 'U') is not null)
--存在classesBackup,直接插入數據
insert into classesBackup select name, createDate from deleted;
else
--不存在classesBackup建立再插入
select * into classesBackup from deleted;
print '備份數據成功!';
go
--
--不顯示影響行數
--set nocount on;
delete classes where name = '5班';
--查詢數據
select * from classes;
select * from classesBackup;

   delete觸發器會在刪除數據的時候,將剛纔刪除的數據保存在deleted表中。

 

    # 建立update類型觸發器

--update更新類型觸發器
if (object_id('tgr_classes_update', 'TR') is not null)
drop trigger tgr_classes_update
go
create trigger tgr_classes_update
on classes
for update
as
declare @oldName varchar(20), @newName varchar(20);
--更新前的數據
select @oldName = name from deleted;
if (exists (select * from student where name like '%'+ @oldName + '%'))
begin
--更新後的數據
select @newName = name from inserted;
update student set name = replace(name, @oldName, @newName) where name like '%'+ @oldName + '%';
print '級聯修改數據成功!';
end
else
print '無需修改student表!';
go
--查詢數據
select * from student order by id;
select * from classes;
update classes set name = '五班' where name = '5班';

     update觸發器會在更新數據後,將更新前的數據保存在deleted表中,更新後的數據保存在inserted表中。

 

    # update更新列級觸發器

if (object_id('tgr_classes_update_column', 'TR') is not null)
drop trigger tgr_classes_update_column
go
create trigger tgr_classes_update_column
on classes
for update
as
--列級觸發器:是否更新了班級建立時間
if (update(createDate))
begin
raisError('系統提示:班級建立時間不能修改!', 16, 11);
rollback tran;
end
go
--測試
select * from student order by id;
select * from classes;
update classes set createDate = getDate() where id = 3;
update classes set name = '四班' where id = 7;

     更新列級觸發器能夠用update是否判斷更新列記錄;

 

    # instead of類型觸發器

       instead of觸發器表示並不執行其定義的操做(insert、update、delete)而僅是執行觸發器自己的內容。

       建立語法

create trigger tgr_name
on table_name
with encryption
instead of update...
as
T-SQL

   

      # 建立instead of觸發器

if (object_id('tgr_classes_inteadOf', 'TR') is not null)
drop trigger tgr_classes_inteadOf
go
create trigger tgr_classes_inteadOf
on classes
instead of delete/*, update, insert*/
as
declare @id int, @name varchar(20);
--查詢被刪除的信息,病賦值
select @id = id, @name = name from deleted;
print 'id: ' + convert(varchar, @id) + ', name: ' + @name;
--先刪除student的信息
delete student where cid = @id;
--再刪除classes的信息
delete classes where id = @id;
print '刪除[ id: ' + convert(varchar, @id) + ', name: ' + @name + ' ] 的信息成功!';
go
--test
select * from student order by id;
select * from classes;
delete classes where id = 7;

   

      # 顯示自定義消息raiserror

if (object_id('tgr_message', 'TR') is not null)
drop trigger tgr_message
go
create trigger tgr_message
on student
after insert, update
as raisError('tgr_message觸發器被觸發', 16, 10);
go
--test
insert into student values('lily', 22, 1, 7);
update student set sex = 0 where name = 'lucy';
select * from student order by id;

    # 修改觸發器

alter trigger tgr_message
on student
after delete
as raisError('tgr_message觸發器被觸發', 16, 10);
go
--test
delete from student where name = 'lucy';

    # 啓用、禁用觸發器

--禁用觸發器
disable trigger tgr_message on student;
--啓用觸發器
enable trigger tgr_message on student;

    # 查詢建立的觸發器信息

--查詢已存在的觸發器
select * from sys.triggers;
select * from sys.objects where type = 'TR';

--查看觸發器觸發事件
select te.* from sys.trigger_events te join sys.triggers t
on t.object_id = te.object_id
where t.parent_class = 0 and t.name = 'tgr_valid_data';

--查看建立觸發器語句
exec sp_helptext 'tgr_message';
 

    # 示例,驗證插入數據

if ((object_id('tgr_valid_data', 'TR') is not null))
drop trigger tgr_valid_data
go
create trigger tgr_valid_data
on student
after insert
as
declare @age int,
@name varchar(20);
select @name = s.name, @age = s.age from inserted s;
if (@age < 18)
begin
raisError('插入新數據的age有問題', 16, 1);
rollback tran;
end
go
--test
insert into student values('forest', 2, 0, 7);
insert into student values('forest', 22, 0, 7);
select * from student order by id;

    # 示例,操做日誌

if (object_id('log', 'U') is not null)
drop table log
go
create table log(
id int identity(1, 1) primary key,
action varchar(20),
createDate datetime default getDate()
)
go
if (exists (select * from sys.objects where name = 'tgr_student_log'))
drop trigger tgr_student_log
go
create trigger tgr_student_log
on student
after insert, update, delete
as
if ((exists (select 1 from inserted)) and (exists (select 1 from deleted)))
begin
insert into log(action) values('updated');
end
else if (exists (select 1 from inserted) and not exists (select 1 from deleted))
begin
insert into log(action) values('inserted');
end
else if (not exists (select 1 from inserted) and exists (select 1 from deleted))
begin
insert into log(action) values('deleted');
end
go
--test
insert into student values('king', 22, 1, 7);
update student set sex = 0 where name = 'king';
delete student where name = 'king';
select * from log;
select * from student order by id;

 

 

 

 

 

 

觸發器(trigger):是一種特殊的存儲過程,能夠用來對錶實施複雜的完整性約束,保持數據的一致性。當觸發器所保護的數據發生改變時,觸發器會自動被激活,並執行觸發器中所定義的相關操做,從而保證對數據的不完整性約束或不正確的修改。

  在SQL SERVER 2008中,有三種類型的觸發器:

(1)DML觸發器:是指觸發器在數據庫中發生數據操做語言(DML)事件時將啓用。DML事件即指在表或視圖中修改數據的insert、update、delete語句也。

(2)DDL觸發器:是指當服務器或數據庫中發生數據定義語言(DDL)事件時將啓用。DDL事件即指在表或索引中的create、alter、drop語句也。

(3)登錄觸發器:是指當用戶登陸SQL SERVER實例創建會話時觸發。

  不過根據DML觸發器觸發的方式不一樣又分爲如下兩種狀況:

(1)AFTER觸發器:它是在執行INSERT、UPDATE、DELETE語句操做以後執行觸發器操做。它主要是用於記錄變動後的處理或檢查,一旦發生錯誤,能夠用Rollback Transaction語句來回滾本次扣件,不過不能對視圖定義AFTER觸發器。

(2)INSTEAD OF觸發器:它在執行INSERT、UPDATE、DELETE語句操做以前執行觸發器自己所定義的操做。而INSTEAD OF觸發器是能夠定義在視圖上的。

   在SQL SERVER 2008中,DML觸發器的實現使用兩個邏輯表DELETED和INSERTED。這兩個表是創建在數據庫服務器的內存中,由系統管理的邏輯表,咱們對於 它只有只讀的權限。DELETED和INSERED表的結構和觸發器所在的數據表的結構是同樣的。當觸發器執行完成後,它們也就會被自動刪除。

INSERED表用於存放你在操件insert、update、delete語句後,更新的記錄。好比你插入一條數據,那麼就會把這條記錄插入到INSERTED表。

DELETED表用於存放你在操做 insert、update、delete語句前,你建立觸發器表中數據庫。好比你原來的表中有三條數據,那麼他也有三條數據。

下面咱們就開始建立觸發器吧!

觸發器定義的格式我就不打一遍,你打開幫助裏有的事。

咱們先建立一張以下的表吧!而後以它爲例吧。

create table table1 
(
user_id int primary key identity(1,1),
user_name varchar(3) not null
)

下面就是建立一個簡單的after觸發器:

create trigger trigMessageList 
on table1
after insert,update
as raiserror('數據一致性驗證',16,1)

此時若是咱們手動打開table1,輸入一條,根本就插入不了,咱們只能寫一條以下的SQL語句插入一條數據

insert into table1(user_name)values('23')

結果數據是插入成功了,可是會出顯以下圖所示的提示:

下面我再建立一個稍微有點複雜的after觸發器:

複製代碼
--該觸發器做用是:若是向table1中插入數據時,
--先檢查要向table1插入的這條的USER_ID是否USERS(我建立的另外一個表)表中的USER_ID字段中有,若是不存在則不容許插入
create trigger trigInsertedMessages
on table1
after insert
as
if exists (select * from inserted a where a.user_id not in (select USER_ID from USERS))
begin
raiserror('數據一致性驗證',16,1)
rollback transaction
end
複製代碼

 

inserted of觸發器和after觸發器寫法差很少,在此就很少寫了。

下面建立一個簡單的DDL觸發器:

複製代碼
--它的做用是:防止數據庫Test(我建立的一個實驗數據庫)中的任一表被修改或刪除
create trigger trigDB
on database
for drop_table,alter_table
as
print '你必定要禁用觸發器「trigDB"才能刪除或修改這個數據庫的表'
rollback
複製代碼

刪除觸發器:

drop trigger trigDB 
ON DATABASE

必定要記得加上ON DATABASE這條,不然就刪除不了。
最後再來條開啓和禁用觸發器的語句:

disable trigger trigDB on database --禁用觸發器
enable trigger trigDB on database --開啓觸發器
相關文章
相關標籤/搜索