x86彙編分頁模式實驗 --《ORANGE'S一個操做系統的實現》中 pmtest8.asm解析

　　序言(廢話) : 在看書的過程當中發現一開始不是很能理解pmtest8的目的,以及書上說得很抽象..因而在本身閱讀過源代碼後,將一些本身的心得寫在這裏。

　　正文 : 

　　講解順序依然按照書上貼代碼的順序來。可是是幾乎逐句解釋的。可能會稍微有點囉嗦。廢話就很少說了直接貼代碼。

LABEL_DESC_FLAT_C:  Descriptor 0,        0fffffh, DA_CR|DA_32|DA_LIMIT_4K; 0~4G
LABEL_DESC_FLAT_RW: Descriptor 0,        0fffffh, DA_DRW|DA_LIMIT_4K     ; 0~4G
SelectorFlatC 　　　　　　equ 　　 LABEL_DESC_FLAT_C - LABEL_GDT 　　　　　　　　　　　　　　　
SelectorFlatRW        equ    LABEL_DESC_FLAT_RW - LABEL_GDT

　　顯然,兩個分別是 FLAT_C 和  FLAT_RW 的描述符和選擇子。

　　問題 : 爲何要有這兩個東西?

　　解釋 : FLAT_C是用來執行的非一致性32位代碼段,粒度爲4k,也就是 limit(段限長) = (0xfffff + 1)  * 4k = 4G,FLAT_RW 是用來修改數據的,由於須要利用這個描述符的權限(可寫)來將代碼寫入到目的地(這個目的地容許在 0 - 4G區間內)。之因此要分兩個選擇符,是防止在執行的時候修改代碼(因此FLAT_C不能給寫的權限),可是又必須在執行以前進行復制,因此必定要有一個入口能提供寫入的方式,因而設置兩個描述符來進行。這樣既安全又有章法。

 

SetupPaging:
    ; 根據內存大小計算應初始化多少PDE以及多少頁表
    xor    edx, edx
    mov    eax, [dwMemSize]
    mov    ebx, 400000h    ; 400000h = 4M = 4096 * 1024, 一個頁表對應的內存大小
    div    ebx
    mov    ecx, eax    ; 此時 ecx 爲頁表的個數，也即 PDE 應該的個數
    test    edx, edx
    jz    .no_remainder
    inc    ecx        ; 若是餘數不爲 0 就需增長一個頁表
.no_remainder:
    mov    [PageTableNumber], ecx    ; 暫存頁表個數

    ; 爲簡化處理, 全部線性地址對應相等的物理地址. 而且不考慮內存空洞.

    ; 首先初始化頁目錄
    mov    ax, SelectorFlatRW
    mov    es, ax
    mov    edi, PageDirBase0    ; 此段首地址爲 PageDirBase0
    xor    eax, eax
    mov    eax, PageTblBase0 | PG_P  | PG_USU | PG_RWW
.1:    ; es:edi 初始等於 PageDirBase0 (當前頁目錄表項), eax 初始基地址等於 PageTblBase0
    stosd
    add    eax, 4096        ; 爲了簡化, 全部頁表在內存中是連續的.
    loop    .1

    ; 再初始化全部頁表
    mov    eax, [PageTableNumber]    ; 頁表個數
    mov    ebx, 1024        ; 每一個頁表 1024 個 PTE
    mul    ebx
    mov    ecx, eax        ; PTE個數 = 頁表個數 * 1024
    mov    edi, PageTblBase0    ; 此段首地址爲 PageTblBase0
    xor    eax, eax
    mov    eax, PG_P  | PG_USU | PG_RWW
.2:    ; es:edi 初始等於 PageTblBase0 (當前頁表項), eax = 0 (線性地址 = 物理地址)
    stosd
    add    eax, 4096        ; 每一頁指向 4K 的空間
    loop    .2

    mov    eax, PageDirBase0
    mov    cr3, eax
    mov    eax, cr0
    or    eax, 80000000h
    mov    cr0, eax
    jmp    short .3
.3:
    nop

    ret

 

　　這段代碼我加註了兩句註釋 分別在 .1 和 .2 這兩個標籤那行,其實這裏和以前的setPaging並無很大的區別,須要注意的就是 這裏的 頁目錄表 的地址是  PageDirBase0, 頁表的地址是PageTblBase0,強調這點的緣由在於以後的  PSwitch 這個函數中則是 PageDirBase1 和 PageTblBase1。也就是說實際上數據中有兩個頁面管理的數據結構(頁目錄表和頁表合起來至關於一個管理頁面的數據結構)。

 1 PagingDemo:
 2     mov    ax, cs
 3     mov    ds, ax
 4     mov    ax, SelectorFlatRW        ; 設置es爲基地址爲0的可讀寫的段(便於複製代碼)
 5     mov    es, ax
 6     
 7     push    LenFoo
 8     push    OffsetFoo
 9     push    ProcFoo            ; 00401000h
10     call    MemCpy        
11     add    esp, 12
12 
13     push    LenBar            ; 被複制代碼段(可是以ds爲段基址)的長度 
14     push    OffsetBar        ; 被複制代碼段(可是以ds爲段基址)的段偏移量
15     push    ProcBar            ; 目的代碼段的物理空間地址 00501000h
16     call    MemCpy
17     add    esp, 12
18 
19     push    LenPagingDemoAll
20     push    OffsetPagingDemoProc    
21     push    ProcPagingDemo            ; [es:ProcPagingDemo] = ProcPagingDemo = 00301000h
22     call    MemCpy
23     add    esp, 12
24 
25     mov    ax, SelectorData
26     mov    ds, ax            ; 數據段選擇子
27     mov    es, ax
28 
29     call    SetupPaging        ; 啓動分頁
30     ; 當前線性地址依然等於物理地址
31     call    SelectorFlatC:ProcPagingDemo    ; 訪問的線性地址爲 00301000h,物理地址也是 00301000h
32     call    PSwitch            ; 切換頁目錄，改變地址映射關係
33     call    SelectorFlatC:ProcPagingDemo    ; 訪問的線性地址爲 00301000h
34 
35     ret

　　在這裏首先要說明的是 MemCpy函數,這個函數有三個參數分別表示 : 

　　　1）被複制段(可是以ds爲段基址)的 長度 
　　　2）被複制段(可是以ds爲段基址)的 段偏移量
　　　3）目的地的物理空間地址(之因此說是物理空間是由於當前線性地址等於物理地址,以es爲段基址,可是es的段基址爲0)
功能則是 將被複制段 的數據複製 參數1)的長度字節 去目的地去(簡單說就是利用三個參數複製數據)
咱們能夠知道的是在上面代碼中三次調用 MemCpy 都沒有進入分頁模式,也就是說當下線性地址等於物理地址。那麼根據我上面的註釋就能夠知道三個代碼分別複製到哪裏去了。
以後就是恢復數據段(以前將ds = cs,是爲了複製代碼),而後啓動分頁(上面已經講了),而後啓動分頁後當前線性地址依然等於物理地址。
這個時候第一次調用 call SelectorFlatC:ProcPagingDemo,也就是訪問的線性地址爲 00301000h,物理地址也是 00301000h的代碼(以前移動過去的)。
　下面這段代碼就是被移動到00301000h的代碼,這段代碼只作了一件事那就是調用 [cs:LinearAddrDemo]的代碼,但請注意,因爲 call SelectorFlatC:ProcPagingDemo 
因此此時的 cs = SelectorFlatC,也就是說段基址等於0,因而實際上這段代碼的功能就是訪問 物理地址爲00401000h處的代碼。

PagingDemoProc:
OffsetPagingDemoProc    equ    PagingDemoProc - $$
    mov    eax, LinearAddrDemo
    call    eax        ; 未開始PSwitch前, eax = ProcFoo = 00401000h (cs 的段基址 = 0)
    retf
LenPagingDemoAll    equ    $ - PagingDemoProc

　　而物理地址00401000h處就是ProcFoo的代碼(第一次調用MemCpy拷貝的代碼)。被拷貝的代碼以下

foo:
OffsetFoo        equ    foo - $$
    mov    ah, 0Ch            ; 0000: 黑底    1100: 紅字
    mov    al, 'F'
    mov    [gs:((80 * 17 + 0) * 2)], ax    ; 屏幕第 17 行, 第 0 列。
    mov    al, 'o'
    mov    [gs:((80 * 17 + 1) * 2)], ax    ; 屏幕第 17 行, 第 1 列。
    mov    [gs:((80 * 17 + 2) * 2)], ax    ; 屏幕第 17 行, 第 2 列。
    ret
LenFoo            equ    $ - foo

　　功能很明顯就是現實一個字符串 Foo而已。

總結第一次分頁後的動做:

　　就是拷貝三份代碼分別到ProcFoo, ProcBar, ProcPagingDemo 處(這四個都是物理內存哦,而且後面由於段基址是0(FLAT_C 段基址)因而很容易地就訪問到了物理地址)。而後開啓分頁模式(其實幾乎沒什麼影響 由於仍然和分段同樣 線性地址 = 物理地址)。而後調用 被拷貝的函數 ProcPagingDemo ,ProcPagingDemo 函數調用 ProcFoo函數,顯示字符 "Foo"而後兩次返回。

第二次分頁 : call PSwitch

被調用代碼以下 :

 1 PSwitch:
 2     ; 初始化頁目錄
 3     mov    ax, SelectorFlatRW
 4     mov    es, ax
 5     mov    edi, PageDirBase1    ; 此段首地址爲 PageDirBase1
 6     xor    eax, eax
 7     mov    eax, PageTblBase1 | PG_P  | PG_USU | PG_RWW
 8     mov    ecx, [PageTableNumber]
 9 .1:    ; es:edi 初始等於 PageDirBase1 (當前頁目錄表項), eax 初始基地址等於 PageTblBase1
10     stosd
11     add    eax, 4096        ; 爲了簡化, 全部頁表在內存中是連續的.
12     loop    .1
13 
14     ; 再初始化全部頁表
15     mov    eax, [PageTableNumber]    ; 頁表個數
16     mov    ebx, 1024        ; 每一個頁表 1024 個 PTE
17     mul    ebx
18     mov    ecx, eax        ; PTE個數 = 頁表個數 * 1024
19     mov    edi, PageTblBase1    ; 此段首地址爲 PageTblBase1
20     xor    eax, eax
21     mov    eax, PG_P  | PG_USU | PG_RWW
22 .2: ; es:edi 初始等於 PageTblBase1 (當前頁表項), eax 初始基地址等於 0(線性地址等於物理地址)
23     stosd
24     add    eax, 4096        ; 每一頁指向 4K 的空間
25     loop    .2
26 
27     ; 在此假設內存是大於 8M 的
28     ; 下列代碼將LinearAddrDemo所處的頁表的相對第一個頁表的偏移地址放入ecx中
29     mov    eax, LinearAddrDemo
30     shr    eax, 22
31     mov    ebx, 4096        ; (LinearAddrDemo / 4M)表示第幾個頁表
32     mul    ebx                ; 第幾個頁表 * 4k (1024(一個頁表項的數量) * 4(一個頁表項的字節))
33     mov    ecx, eax        ; 也就是對應頁表的偏移地址
34     
35     ; 下列代碼將LinearAddrDemo所處的頁表項相對第一個頁表項的偏移地址放入eax中
36     mov    eax, LinearAddrDemo
37     shr    eax, 12            ; LinearAddrDemo / 4k,表示第幾個頁表項
38     and    eax, 03FFh    ; 1111111111b (10 bits)    ; 取低10位,也就是餘下的零散頁表項(一個頁表有2^10個頁表項)
39     mov    ebx, 4                                
40     mul    ebx                                    ; * 4 表示的是具體偏移字節數
41     add    eax, ecx                            ; eax = (((LinearAddrDemo / 2^12) & 03FFh) * 4) + (4k * (LinearAddrDemo / 2^22))
42     
43     
44     add    eax, PageTblBase1                    ; 第一個頁表的第一個頁表項
45     mov    dword [es:eax], ProcBar | PG_P | PG_USU | PG_RWW
46 
47     mov    eax, PageDirBase1
48     mov    cr3, eax
49     jmp    short .3
50 .3:
51     nop
52 
53     ret

　　在這裏我加了幾個比較重要的註釋分別在第 9, 22, 28,35處。

　　這段代碼作了什麼?

　　首先是設置頁面管理的數據結構(頁表和頁目錄表),可是須要注意的是,這裏設置頁表和頁目錄表除了不是以前的頁面管理結構以外,其實內容是差很少的,也就是說當前(第25行)這裏的狀態也是 線性地址 = 物理地址 ！！！

　可是在第27行作了一個操做,就是將LinearAddrDemo對應的 頁表項的地址 換成了 ProcBar(00501000h) 的地址。(具體如何實現的請看27-45行我寫的註釋)。
　 在作完這些以後就返回第二次執行 call SelectorFlatC:ProcPagingDemo 了,在這個時候 cs = SelectorFlatC (段基址等於0), eip = ProcPagingDemo = 00301000h,也就是說訪問了 
線性地址 = 00301000h處,可是這裏已經被修改,除了這個頁面以外,其餘頁面都是 線性地址 = 物理地址,可是這裏 線性地址 = 00301000h ,映射的物理地址是 ProcBar(00501000h)
因而便調用了 ProcBar 段的代碼,而這段的代碼是第二次調用MemCpy時候複製過去的。被複制的具體代碼是:

bar:
OffsetBar        equ    bar - $$
    mov    ah, 0Ch            ; 0000: 黑底    1100: 紅字
    mov    al, 'B'
    mov    [gs:((80 * 18 + 0) * 2)], ax    ; 屏幕第 18 行, 第 0 列。
    mov    al, 'a'
    mov    [gs:((80 * 18 + 1) * 2)], ax    ; 屏幕第 18 行, 第 1 列。
    mov    al, 'r'
    mov    [gs:((80 * 18 + 2) * 2)], ax    ; 屏幕第 18 行, 第 2 列。
    ret
LenBar            equ    $ - bar

也就是顯示一個字符串 "Bar", 而後返回到PagingDemo的最後一句 ret,再次返回。因而這段代碼也就結束了。第二次代碼是如何實現調用 ProcBar的？　　經過將線性地址 = ProcPaging(00301000h)對應的頁表項的地址值給修改爲了 PaocBar(00501000h)的物理地址,因而從 00301000h 的線性地址 映射到 00501000h的物理地址上去了,可是其實其餘地方(除了這個頁以外)的線性地址 = 物理地址依然成立。也是上面這段代碼很小,必定是小於 4k(一頁的大小)，因而只須要修改一個頁表項就能夠了！